كيف يمكنني العثور على الصف الأخير الذي يحتوي على بيانات في عمود معين؟

Question

كيف يمكنني العثور على الصف الأخير الذي يحتوي على بيانات في عمود معين وفي ورقة محددة؟

Answer 1

ماذا عن:

Function GetLastRow(strSheet, strColumn) As Long
    Dim MyRange As Range

    Set MyRange = Worksheets(strSheet).Range(strColumn & "1")
    GetLastRow = Cells(Rows.Count, MyRange.Column).End(xlUp).Row
End Function

فيما يتعلق بالتعليق، سيؤدي هذا إلى إرجاع رقم صف الخلية الأخيرة حتى عندما تحتوي خلية واحدة فقط في الصف الأخير على بيانات:

Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

Answer 2

يجب عليك استخدام .End(xlup) ولكن بدلاً من استخدام 65536 قد ترغب في استخدام:

sheetvar.Rows.Count

وبهذه الطريقة تعمل مع Excel 2007 الذي أعتقد أنه يحتوي على أكثر من 65536 صفًا

Answer 3

function LastRowIndex(byval w as worksheet, byval col as variant) as long
  dim r as range

  set r = application.intersect(w.usedrange, w.columns(col))
  if not r is nothing then
    set r = r.cells(r.cells.count)

    if isempty(r.value) then
      LastRowIndex = r.end(xlup).row
    else
      LastRowIndex = r.row
    end if
  end if
end function

الاستخدام:

? LastRowIndex(ActiveSheet, 5)
? LastRowIndex(ActiveSheet, "AI")

Answer 4

بسيطة وسريعة:

Dim lastRow as long
Range("A1").select
lastRow = Cells.Find("*",SearchOrder:=xlByRows,SearchDirection:=xlPrevious).Row

مثال على الاستخدام:

cells(lastRow,1)="Ultima Linha, Last Row. Youpi!!!!"

'or 

Range("A" & lastRow).Value = "FIM, THE END"

Answer 5

إليك الحل للعثور على الصف الأخير أو العمود الأخير أو الخلية الأخيرة.وهو يعالج معضلة النمط المرجعي A1 R1C1 للعمود الذي يجده.أتمنى أن أعطي الفضل ، لكن لا يمكنني العثور/تذكر من أين حصلت عليه ، "شكرًا!" إلى أيا كان ذلك نشر الكود الأصلي في مكان ما هناك.

Sub Macro1
    Sheets("Sheet1").Select
    MsgBox "The last row found is: " & Last(1, ActiveSheet.Cells)
    MsgBox "The last column (R1C1) found is: " & Last(2, ActiveSheet.Cells)
    MsgBox "The last cell found is: " & Last(3, ActiveSheet.Cells)
    MsgBox "The last column (A1) found is: " & Last(4, ActiveSheet.Cells)
End Sub

Function Last(choice As Integer, rng As Range)
' 1 = last row
' 2 = last column (R1C1)
' 3 = last cell
' 4 = last column (A1)
    Dim lrw As Long
    Dim lcol As Integer

    Select Case choice
    Case 1:
        On Error Resume Next
        Last = rng.Find(What:="*", _
                        After:=rng.Cells(1), _
                        LookAt:=xlPart, _
                        LookIn:=xlFormulas, _
                        SearchOrder:=xlByRows, _
                        SearchDirection:=xlPrevious, _
                        MatchCase:=False).Row
        On Error GoTo 0

    Case 2:
        On Error Resume Next
        Last = rng.Find(What:="*", _
                        After:=rng.Cells(1), _
                        LookAt:=xlPart, _
                        LookIn:=xlFormulas, _
                        SearchOrder:=xlByColumns, _
                        SearchDirection:=xlPrevious, _
                        MatchCase:=False).Column
        On Error GoTo 0

    Case 3:
        On Error Resume Next
        lrw = rng.Find(What:="*", _
                       After:=rng.Cells(1), _
                       LookAt:=xlPart, _
                       LookIn:=xlFormulas, _
                       SearchOrder:=xlByRows, _
                       SearchDirection:=xlPrevious, _
                       MatchCase:=False).Row
        lcol = rng.Find(What:="*", _
                        After:=rng.Cells(1), _
                        LookAt:=xlPart, _
                        LookIn:=xlFormulas, _
                        SearchOrder:=xlByColumns, _
                        SearchDirection:=xlPrevious, _
                        MatchCase:=False).Column
        Last = Cells(lrw, lcol).Address(False, False)
        If Err.Number > 0 Then
            Last = rng.Cells(1).Address(False, False)
            Err.Clear
        End If
        On Error GoTo 0
    Case 4:
        On Error Resume Next
        Last = rng.Find(What:="*", _
                        After:=rng.Cells(1), _
                        LookAt:=xlPart, _
                        LookIn:=xlFormulas, _
                        SearchOrder:=xlByColumns, _
                        SearchDirection:=xlPrevious, _
                        MatchCase:=False).Column
        On Error GoTo 0
        Last = R1C1converter("R1C" & Last, 1)
        For i = 1 To Len(Last)
            s = Mid(Last, i, 1)
            If Not s Like "#" Then s1 = s1 & s
        Next i
        Last = s1

    End Select

End Function

Function R1C1converter(Address As String, Optional R1C1_output As Integer, Optional RefCell As Range) As String
    'Converts input address to either A1 or R1C1 style reference relative to RefCell
    'If R1C1_output is xlR1C1, then result is R1C1 style reference.
    'If R1C1_output is xlA1 (or missing), then return A1 style reference.
    'If RefCell is missing, then the address is relative to the active cell
    'If there is an error in conversion, the function returns the input Address string
    Dim x As Variant
    If RefCell Is Nothing Then Set RefCell = ActiveCell
    If R1C1_output = xlR1C1 Then
        x = Application.ConvertFormula(Address, xlA1, xlR1C1, , RefCell) 'Convert A1 to R1C1
    Else
        x = Application.ConvertFormula(Address, xlR1C1, xlA1, , RefCell) 'Convert R1C1 to A1
    End If
    If IsError(x) Then
        R1C1converter = Address
    Else
        'If input address is A1 reference and A1 is requested output, then Application.ConvertFormula
        'surrounds the address in single quotes.
        If Right(x, 1) = "'" Then
            R1C1converter = Mid(x, 2, Len(x) - 2)
        Else
            x = Application.Substitute(x, "$", "")
            R1C1converter = x
        End If
    End If
End Function

Answer 6

Public Function LastData(rCol As Range) As Range    
    Set LastData = rCol.Find("*", rCol.Cells(1), , , , xlPrevious)    
End Function

الاستخدام: ?lastdata(activecell.EntireColumn).Address

Answer 7

تعتمد جميع الحلول على السلوكيات المضمنة (مثل .Find و .End) لها قيود غير موثقة جيدًا (انظر إجابتي الأخرى للتفاصيل).

كنت بحاجة إلى شيء:

• يجد الأخير غير فارغ خلية (أيالتي لديها أي صيغة أو قيمة, ، حتى لو كانت سلسلة فارغة) في أ عمود محدد
• يعتمد على البدائيين بسلوك محدد جيدًا
• يعمل بشكل موثوق مع المرشحات التلقائية وتعديلات المستخدم
• يعمل بأسرع ما يمكن على 10000 صف (يتم تشغيله في ملف Worksheet_Change معالج دون الشعور بالبطء)
• ...مع عدم سقوط الأداء من منحدر مع البيانات العرضية أو التنسيق الذي تم وضعه في نهاية الورقة (في ~ 1 مليون صف)

الحل أدناه:

• الاستخدامات UsedRange للعثور على الحد الأعلى لرقم الصف (لجعل البحث عن "الصف الأخير" الحقيقي سريعًا في الحالة الشائعة حيث يكون قريبًا من نهاية النطاق المستخدم)؛
• للرجوع للخلف للعثور على الصف الذي يحتوي على بيانات في العمود المحدد؛
• ...استخدام صفائف VBA لتجنب الوصول إلى كل صف على حدة (في حالة وجود العديد من الصفوف في الملف UsedRange نحن بحاجة إلى تخطي)

(لا توجد اختبارات، آسف)

' Returns the 1-based row number of the last row having a non-empty value in the given column (0 if the whole column is empty)
Private Function getLastNonblankRowInColumn(ws As Worksheet, colNo As Integer) As Long
    ' Force Excel to recalculate the "last cell" (the one you land on after CTRL+END) / "used range"
    ' and get the index of the row containing the "last cell". This is reasonably fast (~1 ms/10000 rows of a used range)
    Dim lastRow As Long: lastRow = ws.UsedRange.Rows(ws.UsedRange.Rows.Count).Row - 1 ' 0-based

    ' Since the "last cell" is not necessarily the one we're looking for (it may be in a different column, have some
    ' formatting applied but no value, etc), we loop backward from the last row towards the top of the sheet).
    Dim wholeRng As Range: Set wholeRng = ws.Columns(colNo)

    ' Since accessing cells one by one is slower than reading a block of cells into a VBA array and looping through the array,
    ' we process in chunks of increasing size, starting with 1 cell and doubling the size on each iteration, until MAX_CHUNK_SIZE is reached.
    ' In pathological cases where Excel thinks all the ~1M rows are in the used range, this will take around 100ms.
    ' Yet in a normal case where one of the few last rows contains the cell we're looking for, we don't read too many cells.
    Const MAX_CHUNK_SIZE = 2 ^ 10 ' (using large chunks gives no performance advantage, but uses more memory)
    Dim chunkSize As Long: chunkSize = 1
    Dim startOffset As Long: startOffset = lastRow + 1 ' 0-based
    Do ' Loop invariant: startOffset>=0 and all rows after startOffset are blank (i.e. wholeRng.Rows(i+1) for i>=startOffset)
        startOffset = IIf(startOffset - chunkSize >= 0, startOffset - chunkSize, 0)
        ' Fill `vals(1 To chunkSize, 1 To 1)` with column's rows indexed `[startOffset+1 .. startOffset+chunkSize]` (1-based, inclusive)
        Dim chunkRng As Range: Set chunkRng = wholeRng.Resize(chunkSize).Offset(startOffset)
        Dim vals() As Variant
        If chunkSize > 1 Then
            vals = chunkRng.Value2
        Else ' reading a 1-cell range requires special handling <http://www.cpearson.com/excel/ArraysAndRanges.aspx>
            ReDim vals(1 To 1, 1 To 1)
            vals(1, 1) = chunkRng.Value2
        End If

        Dim i As Long
        For i = UBound(vals, 1) To LBound(vals, 1) Step -1
            If Not IsEmpty(vals(i, 1)) Then
                getLastNonblankRowInColumn = startOffset + i
                Exit Function
            End If
        Next i

        If chunkSize < MAX_CHUNK_SIZE Then chunkSize = chunkSize * 2
    Loop While startOffset > 0

    getLastNonblankRowInColumn = 0
End Function

Answer 8

أود أن أضيف طريقة أخرى أكثر موثوقية باستخدام UsedRange للعثور على آخر صف مستخدم:

lastRow = Sheet1.UsedRange.Row + Sheet1.UsedRange.Rows.Count - 1

بالمثل يمكنك العثور على آخر عمود مستخدم انظر الى هذا

النتيجة في النافذة الفورية:

?Sheet1.UsedRange.Row+Sheet1.UsedRange.Rows.Count-1
 21 

Answer 9

Public Function GetLastRow(ByVal SheetName As String) As Integer
    Dim sht As Worksheet
    Dim FirstUsedRow As Integer     'the first row of UsedRange
    Dim UsedRows As Integer         ' number of rows used

    Set sht = Sheets(SheetName)
    ''UsedRange.Rows.Count for the empty sheet is 1
    UsedRows = sht.UsedRange.Rows.Count
    FirstUsedRow = sht.UsedRange.Row
    GetLastRow = FirstUsedRow + UsedRows - 1

    Set sht = Nothing
End Function

Sheet.UsedRange.Rows.Count:إعادة عدد الصفوف المستخدمة، ولا تشمل الصف الفارغ أعلى الصف الأول المستخدم

إذا كان الصف 1 فارغًا، وكان آخر صف مستخدم هو 10، فسوف يُرجع UsedRange.Rows.Count 9، وليس 10.

تقوم هذه الوظيفة بحساب رقم الصف الأول من UsedRange بالإضافة إلى عدد صفوف UsedRange.

Answer 10

Last_Row = Range("A1").End(xlDown).Row

فقط للتحقق، لنفترض أنك تريد طباعة رقم الصف من الصف الأخير مع البيانات الموجودة في الخلية C1.

Range("C1").Select
Last_Row = Range("A1").End(xlDown).Row
ActiveCell.FormulaR1C1 = Last_Row

Answer 11

Sub test()
    MsgBox Worksheets("sheet_name").Range("A65536").End(xlUp).Row
End Sub

هذا يبحث عن قيمة في العمود A بسبب "A65536".

Answer 12

يقوم السطر الأول بنقل المؤشر إلى الصف الأخير غير الفارغ في العمود.يطبع السطر الثاني صف الأعمدة هذا.

Selection.End(xlDown).Select
MsgBox(ActiveCell.Row)

Answer 13

Function LastRow(rng As Range) As Long
    Dim iRowN As Long
    Dim iRowI As Long
    Dim iColN As Integer
    Dim iColI As Integer
    iRowN = 0
    iColN = rng.Columns.count
    For iColI = 1 To iColN
        iRowI = rng.Columns(iColI).Offset(65536 - rng.Row, 0).End(xlUp).Row
        If iRowI > iRowN Then iRowN = iRowI
    Next
    LastRow = iRowN
End Function