Regex لمطابقة بناء الجملة المخصص

Question

أحاول كتابة تعبير منتظم لمطابقة وتقسيم بناء جملة متغير مخصص في C#. الفكرة هنا هي تنسيق مخصص لقيم السلسلة المشابهة إلى حد كبير مع .net string.format/{0} نمط تنسيق السلسلة.

على سبيل المثال ، يحدد المستخدم تنسيق سلسلة ليتم تقييمه في وقت التشغيل مثل SO:

D:\Path\{LanguageId}\{PersonId}\ 

تتطابق القيمة "LanguageId" لحقل كائن البيانات ، واستبدال قيمته الحالية.

تصبح الأمور صعبة عندما تكون هناك حاجة لتمرير الحجج إلى مجال التنسيق. فمثلا:

{LanguageId:English|Spanish|French}

هذا سيكون له معنى تنفيذ بعض المنطق الشرطي إذا كانت قيمة "languageid" مساوية لأحد الحجج.

أخيرًا ، سأحتاج إلى دعم حجج الخريطة مثل هذا:

{LanguageId:English=>D:\path\english.xml|Spanish=>D:\path\spansih.xml}

فيما يلي تعداد لجميع القيم الممكنة:

أمر لا حجة: افعل شيئًا مميزًا

{@Date}

الوسيطة المفردة:

{@Date:yyyy-mm-dd}

لا جدال:

{LanguageId}

قائمة حجة واحدة:

{LanguageId:English}

قائمة الحجج المتعددة:

{LanguageId:English|Spanish}

خريطة حجة واحدة:

{LanguageId:English=>D:\path\english.xml}

خريطة متعددة الحجة:

{LanguageId:English=>D:\path\english.xml|Spanish=>D:\path\spansih.xml}

ملخص: يمكن غلي بناء الجملة إلى مفتاح مع قائمة أو خريطة نوع المعلمة الاختيارية (وليس كلاهما).

فيما يلي regex لدي حتى الآن والتي لديها بعض المشكلات ، أي أنها لا تتعامل مع كل المسافة البيضاء بشكل صحيح ، في .NET لا أحصل على الانقسامات التي أتوقعها. على سبيل المثال ، في المثال الأول ، عُادت مباراة واحدة من '{languageId} {personId}' بدلاً من تطهيرين متميزين. أنا متأكد أيضًا من أنه لا يتعامل مع مسار نظام الملفات ، أو الأوتار المقتبسة. أي مساعدة في الحصول علي على الحدبة سيكون موضع تقدير. أو أي توصيات.

    private const string RegexMatch = @"
        \{                              # opening curly brace
        [\s]*                           # whitespace before command
        @?                              # command indicator
        (.[^\}\|])+                       # string characters represening command or metadata
        (                               # begin grouping of params
        :                               # required param separater 
        (                               # begin select list param type

        (                               # begin group of list param type
        .+[^\}\|]                       # string of characters for the list item
        (\|.+[^\}\|])*                  # optional multiple list items with separator
        )                               # end select list param type

        |                               # or select map param type

        (                               # begin group of map param type
        .+[^\}\|]=>.+[^\}\|]            # string of characters for map key=>value pair
        (\|.+[^\}\|]=>.+[^\}\|])*       # optional multiple param map items
        )                               # end group map param type

        )                               # end select map param type
        )                               # end grouping of params
        ?                               # allow at most 1 param group
        \s*
        \}                              # closing curly brace
        ";

Answer 1

أنت تحاول أن تفعل الكثير مع regex واحد. أقترح عليك تقسيم المهمة إلى خطوات ، الأول هو تطابق بسيط على شيء يبدو وكأنه متغير. يمكن أن يكون هذا Regex بسيطًا مثل:

\{\s*([^{}]+?)\s*\}

هذا يحفظ سلسلة المتغير/الأوامر بالكامل في المجموعة رقم 1 ، ناقص الأقواس والمساحة البيضاء المحيطة. بعد ذلك يمكنك الانقسام على كولونز ، ثم الأنابيب ، ثم "=>" تسلسل حسب الاقتضاء. لا تضغط على كل التعقيد في regex وحش واحد ؛ إذا تمكنت من الحصول على مكتوبة Regex ، فستجد أنه من المستحيل الحفاظ على متطلباتك في وقت لاحق.

وشيء آخر: الآن ، أنت تركز على الحصول على الكود للعمل عندما تكون الإدخال صحيحة ، ولكن ماذا عن عندما يخطئ المستخدمون؟ ألا ترغب في منحهم ملاحظات مفيدة؟ regexes تمتص في ذلك ؛ إنهم يمرون/يفشلون بدقة. يمكن أن تكون regexes مفيدة بشكل مثير للدهشة ، ولكن مثل أي أداة أخرى ، عليك أن تتعلم حدودها قبل أن تتمكن من تسخير قوتها الكاملة.

Answer 2

قد ترغب في إلقاء نظرة على تنفيذ هذا كآلة الحالة للدولة بدلاً من regex ، وخاصةً لسرعة السرعة. http://en.wikipedia.org/wiki/finite-state_machine

تحرير: في الواقع ، أن تكون دقيقًا ، فأنت تريد أن تنظر إلى آلات الحالة المحدودة الحتمية: http://en.wikipedia.org/wiki/deterministic_finite-state_machine

Answer 3

هذا يجب أن يتم تحليله حقًا.

على سبيل المثال ، أردت تحليل هذا باستخدام Regexp::Grammars.

يرجى عذر الطول.

#! /opt/perl/bin/perl
use strict;
use warnings;
use 5.10.1;

use Regexp::Grammars;

my $grammar = qr{
  ^<Path>$

  <objtoken: My::Path>
    <drive=([a-zA-Z])>:\\ <[elements=PathElement]> ** (\\) \\?

  <rule: PathElement>
    (?:
      <MATCH=BlockPathElement>
    |
      <MATCH=SimplePathElement>
    )

  <token: SimplePathElement>
    (?<= \\ ) <MATCH=([^\\]+)>

  <rule: My::BlockPathElement>
    (?<=\\){ \s*
    (?|
      <MATCH=Command>
    |
      <MATCH=Variable>
    )
    \s* }

  <objrule: My::Variable>
    <name=(\w++)> <options=VariableOptionList>?

  <rule: VariableOptionList>
      :
      <[MATCH=VariableOptionItem]> ** ([|])

  <token: VariableOptionItem>
    (?:
      <MATCH=VariableOptionMap>
    |
      <MATCH=( [^{}|]+? )>
    )

  <objrule: My::VariableOptionMap>
    \s*
    <name=(\w++)> => <value=([^{}|]+?)>
    \s*

  <objrule: My::Command>
    @ <name=(\w++)>
    (?:
      : <[arg=CommandArg]> ** ([|])
    )?

  <token: CommandArg>
    <MATCH=([^{}|]+?)> \s*

}x;

الاختبار مع:

use YAML;
while( my $line = <> ){
  chomp $line;
  local %/;

  if( $line =~ $grammar ){
    say Dump \%/;
  }else{
    die "Error: $line\n";
  }
}

مع بيانات العينة:

D:\Path\{LanguageId}\{PersonId}
E:\{ LanguageId : English | Spanish | French }
F:\Some Thing\{ LanguageId : English => D:\path\english.xml | Spanish => D:\path\spanish.xml }
C:\{@command}
c:\{@command :arg}
c:\{ @command : arg1 | arg2 }

النتائج في:

---
'': 'D:\Path\{LanguageId}\{PersonId}'
Path: !!perl/hash:My::Path
  '': 'D:\Path\{LanguageId}\{PersonId}'
  drive: D
  elements:
    - Path
    - !!perl/hash:My::Variable
      '': LanguageId
      name: LanguageId
    - !!perl/hash:My::Variable
      '': PersonId
      name: PersonId

---
'': 'E:\{ LanguageId : English | Spanish | French }'
Path: !!perl/hash:My::Path
  '': 'E:\{ LanguageId : English | Spanish | French }'
  drive: E
  elements:
    - !!perl/hash:My::Variable
      '': 'LanguageId : English | Spanish | French'
      name: LanguageId
      options:
        - English
        - Spanish
        - French

---
'': 'F:\Some Thing\{ LanguageId : English => D:\path\english.xml | Spanish => D:\path\spanish.xml }'
Path: !!perl/hash:My::Path
  '': 'F:\Some Thing\{ LanguageId : English => D:\path\english.xml | Spanish => D:\path\spanish.xml }'
  drive: F
  elements:
    - Some Thing
    - !!perl/hash:My::Variable
      '': 'LanguageId : English => D:\path\english.xml | Spanish => D:\path\spanish.xml '
      name: LanguageId
      options:
        - !!perl/hash:My::VariableOptionMap
          '': 'English => D:\path\english.xml '
          name: English
          value: D:\path\english.xml
        - !!perl/hash:My::VariableOptionMap
          '': 'Spanish => D:\path\spanish.xml '
          name: Spanish
          value: D:\path\spanish.xml

---
'': 'C:\{@command}'
Path: !!perl/hash:My::Path
  '': 'C:\{@command}'
  drive: C
  elements:
    - !!perl/hash:My::Command
      '': '@command'
      name: command

---
'': 'c:\{@command :arg}'
Path: !!perl/hash:My::Path
  '': 'c:\{@command :arg}'
  drive: c
  elements:
    - !!perl/hash:My::Command
      '': '@command :arg'
      arg:
        - arg
      name: command

---
'': 'c:\{ @command : arg1 | arg2 }'
Path: !!perl/hash:My::Path
  '': 'c:\{ @command : arg1 | arg2 }'
  drive: c
  elements:
    - !!perl/hash:My::Command
      '': '@command : arg1 | arg2 '
      arg:
        - arg1
        - arg2
      name: command

برنامج العينة:

my %ARGS = qw'
  LanguageId  English
  PersonId    someone
';

while( my $line = <> ){
  chomp $line;
  local %/;

  if( $line =~ $grammar ){
    say $/{Path}->fill( %ARGS );
  }else{
    say 'Error: ', $line;
  }
}

{
  package My::Path;

  sub fill{
    my($self,%args) = @_;

    my $out = $self->{drive}.':';

    for my $element ( @{ $self->{elements} } ){
      if( ref $element ){
        $out .= '\\' . $element->fill(%args);
      }else{
        $out .= "\\$element";
      }
    }

    return $out;
  }
}
{
  package My::Variable;

  sub fill{
    my($self,%args) = @_;

    my $name = $self->{name};

    if( exists $args{$name} ){
      $self->_fill( $args{$name} );
    }else{
      my $lc_name = lc $name;

      my @possible = grep {
        lc $_ eq $lc_name
      } keys %args;

      die qq'Cannot find argument for variable "$name"\n' unless @possible;
      if( @possible > 1 ){
        my $die = qq'Cannot determine which argument matches "$name" closer:\n';
        for my $possible( @possible ){
          $die .= qq'  "$possible"\n';
        }
        die $die;
      }

      $self->_fill( $args{$possible[1]} );
    }
  }
  sub _fill{
    my($self,$opt) = @_;

    # This is just an example.
    unless( exists $self->{options} ){
      return $opt;
    }

    for my $element ( @{$self->{options}} ){
      if( ref $element ){
        return '['.$element->value.']' if lc $element->name eq lc $opt;
      }elsif( lc $element eq lc $opt ){
        return $opt;
      }
    }

    my $name = $self->{name};
    my $die = qq'Invalid argument "$opt" for "$name" :\n';
    for my $valid ( @{$self->{options}} ){
      $die .= qq'  "$valid"\n';
    }
    die $die;
  }
}
{
  package My::VariableOptionMap;

  sub name{
    my($self) = @_;

    return $self->{name};
  }
}
{
  package My::Command;

  sub fill{
    my($self,%args) = @_;

    return '['.$self->{''}.']';
  }
}
{
  package My::VariableOptionMap;

  sub name{
    my($self) = @_;
    return $self->{name};
  }

  sub value{
    my($self) = @_;
    return $self->{value};
  }
}

الإخراج باستخدام بيانات المثال:

D:\Path\English\someone
E:\English
F:\Some Thing\[D:\path\english.xml]
C:\[@command]
c:\[@command :arg]
c:\[@command : arg1 | arg2 ]