تغيير المسار لحفظ mysettings - vb.net 2008
-
27-09-2019 - |
سؤال
أنا أستخدم MySettings لحفظ إعدادات المستخدم.
يتم حفظ ملف التكوين هذا في هذا المسار:
C: المستندات والإعدادات [الإعدادات المحلية] بيانات التطبيق\
هل من الممكن تغيير هذا المسار؟ على سبيل المثال ، في حالتي أقوم بحفظ بيانات التطبيق في مجلد "ProgramData" (Vista & W7) وأود حفظ ملف التكوين هذا في نفس المجلد. ممكن؟
شكرا لك مقدما
المحلول
من تجربتي ، إذا قلت أنك ستنقل الإعداد من Win XP إلى Vista أو W7 ، فلا يمكن إصلاح مسار المجلد.
ومع ذلك ، في جهاز كمبيوتر واحد ، يمكنك إصلاح مسار المجلد إلى ApplicationData ApplicationName anuglycode عن طريق التوقيع على .exe باستخدام أدوات SN. (سوف يتغير رمز Uglu في كل مرة تقوم فيها بإعادة البناء وستمنع هذا).
ولكن إذا كنت تعتقد أن إصدار نسخة متقاطعة وين ، أقترح عليك عدم استخدام الإعدادات الخاصة بي ولكن لاستخدام تسلسل XML. قم بإنشاء فئة لتحديد الإعداد الخاص بك وتحميله وحفظه باستخدام XML Serialize و Deserialize. يمكنك وضع في مستند أو نفس المجلد مع *.exe.
ها هي العينة:
Imports System.Xml.Serialization
<XmlRoot("FTPSender")> _
Public Class FTPSenderConfig
' default file path relative to the current .exe file path.
Const fDefaultCFGFile As String = "FTPSender.cfg"
Public Shared ReadOnly Property DefaultFilePath() As String
Get
Return IO.Path.GetDirectoryName(System.Windows.Forms.Application.ExecutablePath) & "\" & fDefaultCFGFile
End Get
End Property
Public Shared Function Load(Optional ByVal FilePath As String = Nothing) As FTPSenderConfig
If FilePath Is Nothing Then FilePath = DefaultFilePath()
If Not IO.File.Exists(FilePath) Then Return New FTPSenderConfig() ' load default settings
Using sr As New IO.StreamReader(FilePath)
Try
Dim x As New XmlSerializer(GetType(FTPSenderConfig))
Load = CType(x.Deserialize(sr), FTPSenderConfig)
'MyLog.WriteLog("FTPSender settings loaded.")
Finally
If sr IsNot Nothing Then
sr.Close()
sr.Dispose()
End If
End Try
End Using
End Function
Public Shared Sub Save(ByVal FTPSenderConfig As FTPSenderConfig, Optional ByVal FilePath As String = Nothing)
If FilePath Is Nothing Then FilePath = DefaultFilePath()
If FTPSenderConfig Is Nothing Then Return
Using sw As New IO.StreamWriter(FilePath)
Try
Dim x As New XmlSerializer(FTPSenderConfig.GetType())
x.Serialize(sw, FTPSenderConfig)
'MyLog.WriteLog("FTPSender settings saved.")
Finally
If sw IsNot Nothing Then
sw.Close()
sw.Dispose()
End If
End Try
End Using
End Sub
Dim fHost As String = "127.0.0.1"
<XmlElement("Host")> _
Public Property Host() As String
Get
Return fHost
End Get
Set(ByVal value As String)
fHost = value
End Set
End Property
Dim fUser As String = "guess"
<XmlElement("User")> _
Public Property User() As String
Get
Return fUser
End Get
Set(ByVal value As String)
fUser = value
End Set
End Property
Dim fPassEncrypted As String = EncDec.Encrypt("guess")
<XmlElement("PassEncrypted")> _
Public Property PassEncrypted() As String
Get
Return fPassEncrypted
End Get
Set(ByVal value As String)
fPassEncrypted = value
End Set
End Property
<XmlIgnore()> _
Public Property Pass() As String
Get
Return EncDec.Decrypt(fPassEncrypted)
End Get
Set(ByVal value As String)
fPassEncrypted = EncDec.Encrypt(value)
End Set
End Property
Dim fTransferMode As String = MyFTPClient.TransferModeEnum.Passive.ToString()
<XmlElement("TransferMode")> _
Public Property TransferMode() As MyFTPClient.TransferModeEnum
Get
Return [Enum].Parse(GetType(MyFTPClient.TransferModeEnum), fTransferMode)
End Get
Set(ByVal value As MyFTPClient.TransferModeEnum)
fTransferMode = value.ToString()
End Set
End Property
End Class
لاستخدامه ببساطة على النحو التالي:
Dim cfg As FTPSenderConfig
cfg = FTPSenderConfig.Load() ' In Form_Load
Dim h as String = cfg.Host
cfg.Host = h
FTPSenderConfig.Save(cfg) ' In Form_FormClosed