إضافة البيانات إلى سلفرليغت HTTP POST عدم التزامن

Question

وأنا أحاول أن ترسل بعض البيانات باستخدام HTTP POST بسيط في Silverlight 3.0 ولكن لسبب ما لا أستطيع العثور على ما يبدو مثال جيد على كيفية القيام بذلك.

وحتى الآن هذا يعمل، ولكن كيف أقوم بإرسال بعض البيانات على طول ث / طلب؟

Public Sub SubmitMessage()
    request = WebRequestCreator.ClientHttp.Create(New System.Uri("http://localhost:27856/Home.aspx/PostUpdate/"))
    request.Method = "POST"

    Dim result As IAsyncResult = request.BeginGetResponse(New AsyncCallback(AddressOf UpdateDone), Nothing)
End Sub

Public Sub UpdateDone(ByVal ar As IAsyncResult)
    Dim response As HttpWebResponse = request.EndGetResponse(ar)

    Using reader As StreamReader = New StreamReader(response.GetResponseStream())
        Dim valid As String = reader.ReadToEnd()
    End Using
End Sub

Answer 1

وتحتاج طريقة BeginGetRequestStream قبل الحصول على استجابة (لاحظ VB.NET ليس لغتي الرئيسية).

Public Sub SubmitMessage()
    request = WebRequestCreator.ClientHttp.Create(New System.Uri("http://localhost:27856/Home.aspx/PostUpdate/"))
    request.Method = "POST"

    request.BeginGetRequestStream(New AsyncCallback(AddressOf SendData), Nothing)
End Sub

Public Sub SendData(ByVal ar As IAsyncResult)
    Dim stream as Stream = state.Request.EndGetRequestStream(ar)
    '' # Pump your data as bytes into the stream.
    stream.Close()
    request.BeingGetResponse(New AsyncCallback(AddressOf UpdateDone), Nothing)
End Sub

Public Sub UpdateDone(ByVal ar As IAsyncResult)
    Dim response As HttpWebResponse = request.EndGetResponse(ar)

    Using reader As StreamReader = New StreamReader(response.GetResponseStream())
        Dim valid As String = reader.ReadToEnd()
    End Using
End Sub

ويبدو من إجابتك أن تنشر بيانات النموذج HTML. هنا هي الطريقة الصحيحة لإنشاء هيئة كيان (C # آسف): -

    public static string GetUrlEncodedData(Dictionary<string, string> data)
    {
        var sb = new StringBuilder();
        foreach (var kvp in data)
        {
            if (sb.Length > 0) sb.Append("&");
            sb.Append(kvp.Key);
            sb.Append("=");
            sb.Append(Uri.EscapeDataString(kvp.Value));
        }
        return sb.ToString();
    }

ملحوظة ولا سيما استخدام Uri.EscapeDataString، هذه هي الطريقة الصحيحة لترميز قيم البيانات لهذا نوع المحتوى. ويفترض أن الملقم يتوقع ترميز UTF-8 أحرف.

عند تحويل نتيجة هذا إلى صفيف بايت جاهزة للنشر تحتاج فقط استخدام الترميز ASCII منذ سلسلة عاد سيحتوي فقط من أي وقت مضى الأحرف ضمن نطاق ASCII.

Answer 2

والحل النهائي هو مبين أدناه التي عملت. بفضل @ AnthonyWJones للحصول على جوابه السريعة التي حصلت لي نسير في الاتجاه الصحيح!

Public Sub SubmitMessage()
    Dim request As HttpWebRequest = WebRequestCreator.ClientHttp.Create(New System.Uri("http://localhost:27856/Home.aspx/PostUpdate/"))
    request.Method = "POST"
    request.ContentType = "application/x-www-form-urlencoded"

    request.BeginGetRequestStream(New AsyncCallback(AddressOf SendStatusUpdate), request)
End Sub

Public Sub SendStatusUpdate(ByVal ar As IAsyncResult)
    Dim request As HttpWebRequest = DirectCast(ar.AsyncState, HttpWebRequest)

    Dim stream As Stream = request.EndGetRequestStream(ar)

    Dim data As New System.Text.UTF8Encoding
    Dim byteArray As Byte() = data.GetBytes("status=test")

    stream.Write(byteArray, 0, byteArray.Length)
    stream.Close()
    stream.Dispose()

    request.BeginGetResponse(New AsyncCallback(AddressOf StatusUpdateCompleted), request)
End Sub

Public Sub StatusUpdateCompleted(ByVal ar As IAsyncResult)
    Dim request As HttpWebRequest = DirectCast(ar.AsyncState, HttpWebRequest)

    Dim response As HttpWebResponse = request.EndGetResponse(ar)

    Using reader As StreamReader = New StreamReader(response.GetResponseStream())
        Dim valid As String = reader.ReadToEnd()
    End Using
End Sub