在 Delphi 中解析一行的最快方法是什么?
题
我有一个巨大的文件,我必须逐行解析它。速度至关重要。
一行的示例:
Token-1 Here-is-the-Next-Token Last-Token-on-Line ^ ^ Current Position Position after GetToken
调用 GetToken,返回“Here-is-the-Next-Token”并将 CurrentPosition 设置为令牌最后一个字符的位置,以便为下一次调用 GetToken 做好准备。令牌由一个或多个空格分隔。
假设该文件已位于内存中的 StringList 中。它很容易装入内存,例如 200 MB。
我只担心解析的执行时间。在 Delphi (Pascal) 中什么代码会产生绝对最快的执行速度?
解决方案
- 使用 PChar 递增来提高处理速度
- 如果不需要某些token,只按需复制token数据
- 实际扫描字符时将 PChar 复制到局部变量
- 将源数据保留在单个缓冲区中,除非您必须逐行处理,即使如此,也请考虑将行处理作为词法分析器识别器中的单独标记进行处理
- 如果您确实知道编码,请考虑处理直接来自文件的字节数组缓冲区;如果使用 Delphi 2009,请使用 PAnsiChar 而不是 PChar,除非您知道编码是 UTF16-LE。
- 如果您知道唯一的空白是 #32(ASCII 空格),或类似的有限字符集,则可能有一些巧妙的位操作技巧,可以让您使用整数扫描一次处理 4 个字节。不过,我不希望在这里取得重大胜利,而且代码会像泥一样清晰。
这是一个示例词法分析器,应该非常高效,但它假设所有源数据都在单个字符串中。由于令牌很长,重新处理它来处理缓冲区是相当棘手的。
type
TLexer = class
private
FData: string;
FTokenStart: PChar;
FCurrPos: PChar;
function GetCurrentToken: string;
public
constructor Create(const AData: string);
function GetNextToken: Boolean;
property CurrentToken: string read GetCurrentToken;
end;
{ TLexer }
constructor TLexer.Create(const AData: string);
begin
FData := AData;
FCurrPos := PChar(FData);
end;
function TLexer.GetCurrentToken: string;
begin
SetString(Result, FTokenStart, FCurrPos - FTokenStart);
end;
function TLexer.GetNextToken: Boolean;
var
cp: PChar;
begin
cp := FCurrPos; // copy to local to permit register allocation
// skip whitespace; this test could be converted to an unsigned int
// subtraction and compare for only a single branch
while (cp^ > #0) and (cp^ <= #32) do
Inc(cp);
// using null terminater for end of file
Result := cp^ <> #0;
if Result then
begin
FTokenStart := cp;
Inc(cp);
while cp^ > #32 do
Inc(cp);
end;
FCurrPos := cp;
end;
其他提示
这是一个非常简单的词法分析器的蹩脚屁股实现。这可能会给你一个想法。
请注意此示例的限制 - 不涉及缓冲,没有Unicode(这是Delphi 7项目的摘录)。你可能需要那些认真实施的东西。
{ Implements a simpe lexer class. }
unit Simplelexer;
interface
uses Classes, Sysutils, Types, dialogs;
type
ESimpleLexerFinished = class(Exception) end;
TProcTableProc = procedure of object;
// A very simple lexer that can handle numbers, words, symbols - no comment handling
TSimpleLexer = class(TObject)
private
FLineNo: Integer;
Run: Integer;
fOffset: Integer;
fRunOffset: Integer; // helper for fOffset
fTokenPos: Integer;
pSource: PChar;
fProcTable: array[#0..#255] of TProcTableProc;
fUseSimpleStrings: Boolean;
fIgnoreSpaces: Boolean;
procedure MakeMethodTables;
procedure IdentProc;
procedure NewLineProc;
procedure NullProc;
procedure NumberProc;
procedure SpaceProc;
procedure SymbolProc;
procedure UnknownProc;
public
constructor Create;
destructor Destroy; override;
procedure Feed(const S: string);
procedure Next;
function GetToken: string;
function GetLineNo: Integer;
function GetOffset: Integer;
property IgnoreSpaces: boolean read fIgnoreSpaces write fIgnoreSpaces;
property UseSimpleStrings: boolean read fUseSimpleStrings write fUseSimpleStrings;
end;
implementation
{ TSimpleLexer }
constructor TSimpleLexer.Create;
begin
makeMethodTables;
fUseSimpleStrings := false;
fIgnoreSpaces := false;
end;
destructor TSimpleLexer.Destroy;
begin
inherited;
end;
procedure TSimpleLexer.Feed(const S: string);
begin
Run := 0;
FLineNo := 1;
FOffset := 1;
pSource := PChar(S);
end;
procedure TSimpleLexer.Next;
begin
fTokenPos := Run;
foffset := Run - frunOffset + 1;
fProcTable[pSource[Run]];
end;
function TSimpleLexer.GetToken: string;
begin
SetString(Result, (pSource + fTokenPos), Run - fTokenPos);
end;
function TSimpleLexer.GetLineNo: Integer;
begin
Result := FLineNo;
end;
function TSimpleLexer.GetOffset: Integer;
begin
Result := foffset;
end;
procedure TSimpleLexer.MakeMethodTables;
var
I: Char;
begin
for I := #0 to #255 do
case I of
'@', '&', '}', '{', ':', ',', ']', '[', '*',
'^', ')', '(', ';', '/', '=', '-', '+', '#', '>', '<', ',
'.', '"', #39:
fProcTable[I] := SymbolProc;
#13, #10: fProcTable[I] := NewLineProc;
'A'..'Z', 'a'..'z', '_': fProcTable[I] := IdentProc;
#0: fProcTable[I] := NullProc;
'0'..'9': fProcTable[I] := NumberProc;
#1..#9, #11, #12, #14..#32: fProcTable[I] := SpaceProc;
else
fProcTable[I] := UnknownProc;
end;
end;
procedure TSimpleLexer.UnknownProc;
begin
inc(run);
end;
procedure TSimpleLexer.SymbolProc;
begin
if fUseSimpleStrings then
begin
if pSource[run] = '"' then
begin
Inc(run);
while pSource[run] <> '"' do
begin
Inc(run);
if pSource[run] = #0 then
begin
NullProc;
end;
end;
end;
Inc(run);
end
else
inc(run);
end;
procedure TSimpleLexer.IdentProc;
begin
while pSource[Run] in ['_', 'A'..'Z', 'a'..'z', '0'..'9'] do
Inc(run);
end;
procedure TSimpleLexer.NumberProc;
begin
while pSource[run] in ['0'..'9'] do
inc(run);
end;
procedure TSimpleLexer.SpaceProc;
begin
while pSource[run] in [#1..#9, #11, #12, #14..#32] do
inc(run);
if fIgnoreSpaces then Next;
end;
procedure TSimpleLexer.NewLineProc;
begin
inc(FLineNo);
inc(run);
case pSource[run - 1] of
#13:
if pSource[run] = #10 then inc(run);
end;
foffset := 1;
fRunOffset := run;
end;
procedure TSimpleLexer.NullProc;
begin
raise ESimpleLexerFinished.Create('');
end;
end.
我根据状态引擎(DFA)制作了一个词法分析器。它适用于桌子并且非常快。但有可能更快的选择。
这也取决于语言。一种简单的语言可能有一个智能算法。
该表是一个记录数组,每个记录包含2个字符和1个整数。对于每个标记,词法分析器遍历表格,从位置0开始:
state := 0;
result := tkNoToken;
while (result = tkNoToken) do begin
if table[state].c1 > table[state].c2 then
result := table[state].value
else if (table[state].c1 <= c) and (c <= table[state].c2) then begin
c := GetNextChar();
state := table[state].value;
end else
Inc(state);
end;
它很简单,就像一个魅力。
如果速度至关重要,那么自定义代码就是答案。查看将您的文件映射到内存的Windows API。然后,您可以使用指向下一个字符的指针来执行您的令牌,并根据需要进行操作。
这是我进行映射的代码:
procedure TMyReader.InitialiseMapping(szFilename : string);
var
// nError : DWORD;
bGood : boolean;
begin
bGood := False;
m_hFile := CreateFile(PChar(szFilename), GENERIC_READ, 0, nil, OPEN_EXISTING, 0, 0);
if m_hFile <> INVALID_HANDLE_VALUE then
begin
m_hMap := CreateFileMapping(m_hFile, nil, PAGE_READONLY, 0, 0, nil);
if m_hMap <> 0 then
begin
m_pMemory := MapViewOfFile(m_hMap, FILE_MAP_READ, 0, 0, 0);
if m_pMemory <> nil then
begin
htlArray := Pointer(Integer(m_pMemory) + m_dwDataPosition);
bGood := True;
end
else
begin
// nError := GetLastError;
end;
end;
end;
if not bGood then
raise Exception.Create('Unable to map token file into memory');
end;
我认为最大的瓶颈始终是将文件存入内存。一旦你把它放在内存中(显然不是一次全部,但我会使用缓冲区,如果我是你),实际的解析应该是无关紧要的。
这引出了另一个问题 - 有多大? 给我们一个像线条或#或Mb(Gb)的线索? 然后我们将知道它是否适合内存,需要基于磁盘等。
第一遍我会使用我的WordList(S:String; AList:TStringlist);
然后您可以访问每个令牌Alist [n] ... 或者他们或其他什么。
滚动自己是最快的方式。有关此主题的更多信息,您可以看到 Synedit的源代码,其中包含词法分析器(在项目的上下文中称为“荧光笔”)对于市场上的任何语言。我建议你把其中一个lexers作为基础并根据自己的用途进行修改。
编写代码的最快方法可能是创建TStringList并将文本文件中的每一行分配给CommaText属性。默认情况下,空格是分隔符,因此每个标记将获得一个StringList项。
MyStringList.CommaText := s;
for i := 0 to MyStringList.Count - 1 do
begin
// process each token here
end;
但是,通过自己解析每一行,你可能会获得更好的性能。