如何最好地修改 /安装组件库路径，而无需手动进行Delphi IDE？

Question

我正在准备安装程序（Inno设置）将我的组件软件包安装到Delphi Xe中，而无需手动摆弄IDE。

我需要修改delphi库路径，例如删除其中的一部分（例如， xxx;MyOldPath;yyy）并插入一条新路径， xxxx;MyNewPath;yyyy. 。是否有一种首选的方法来执行此操作，或者我必须写一个实用程序才能做到这一点？

谢谢

Answer 1

修改路径是基本的字符串操作：您读取注册表中的当前路径，对其进行操作以适合您的需求，然后写回。

您可能可以编写一个Inno设置脚本函数，这样您就没有任何外部依赖项。或编写来自Inno Setup脚本的Delphi DLL，以便更容易调试。

---

编辑

这是我在生产中实际使用的例程的修改版。它将读取从任一的路径列表 Search Path 注册表值或 Browsing Path （有关此问题的任何其他路径），可能会删除某些路径，并添加一些路径，如果它们尚不存在。

procedure UpdateDelphiPaths(const RegistryKey, RegistryValue: string; PathsToRemove, PathsToAdd: TStrings);
var R:TRegistry;
      SKeys:TStringList;
      Found:Boolean;
      Updated:Boolean;
      i,j:Integer;
      s:string;
      R_Globals:TRegistry;

  // This function normalises paths in comparasions
  function PrepPathForComparasion(const Path:string):string;
  begin
    if Path = '' then Result := '\'
    else
      if Path[Length(Path)] = '\' then
        Result := LowerCase(Path)
      else
        Result := LowerCase(Path) + '\';
  end;

  function PathMatchesRemoveCriteria(const Path:string): Boolean;
  var i:Integer;
  begin
    // This needs to be addapted to match your criteria!
    for i:=0 to PathsToRemove.Count-1 do
      if AnsiPos(PathsToRemove[i], Path) <> 0 then
        Exit(True);
    Result := False;
  end;

begin
  R := TRegistry.Create;
  try
    R.RootKey := HKEY_CURRENT_USER;
    if R.OpenKey(RegistryKey + '\Library', False) then
      if R.ValueExists(RegistryValue) then
      begin
        SKeys := TStringList.Create;
        try
          SKeys.Delimiter := ';';
          SKeys.StrictDelimiter := True;
          SKeys.DelimitedText := R.ReadString(RegistryValue);

          Updated := False;

          // Look at all the paths in the PathsToAdd list, if any one's missing add it to the list and mark
          // "Updated".
          for i:=0 to PathsToAdd.Count-1 do
          begin
            Found := False;
            for j:=0 to SKeys.Count-1 do
              if LowerCase(Trim(SKeys[j])) = LowerCase(Trim(PathsToAdd[i])) then
                Found := True;
            if not Found then
            begin
              SKeys.Add(PathsToAdd[i]);
              Updated := True;
            end;
          end;

          // Look at every single path in the current list, if it's not in the "PathsToAdd" and it matches
          // a name in "PathsToRemove", drop it and mark "Updated"
          i := 0;
          while i < SKeys.Count do
          begin
            if PathMatchesRemoveCriteria(SKeys[i]) then
              begin
                // Path matches remove criteria! It only gets removed if it's not actually present in
                // PathsToAdd
                Found := False;
                for j:=0 to PathsToAdd.Count-1 do
                begin
                  if PrepPathForComparasion(SKeys[i]) = PrepPathForComparasion(PathsToAdd[j]) then
                    Found := True;
                end;
                if not Found then
                  begin
                    SKeys.Delete(i);
                    Updated := True;
                  end
                else
                  Inc(i);
              end
            else
              Inc(i);
          end;

          // If I've updated the SKeys in any way, push changes back to registry and force updates
          if Updated then
          begin
            s := SKeys[0];
            for i:=1 to SKeys.Count-1 do
              if SKeys[i] <> '' then
              begin
                s := s + ';' + SKeys[i];
              end;
            R.WriteString(RegistryValue, s);

            // Force delphi to re-load it's paths.
            R_Globals := TRegistry.Create;
            try
              R_Globals.OpenKey(RegistryKey + '\Globals', True);
              R_Globals.WriteString('ForceEnvOptionsUpdate', '1');
            finally R_Globals.Free;
            end;

          end;

        finally SKeys.Free;
        end;
      end;
  finally R.Free;
  end;
end;

从Delphi代码我可以这样称呼该例程，以确保安装了给定库的最新搜索路径：

var ToRemove, ToAdd: TStringList;
begin
  ToRemove := TStringList.Create;
  try
    ToAdd := TStringList.Create;
    try
      ToRemove.Add('LibraryName\Source');
      ToAdd.Add('C:\LibraryName\Source');
      UpdateDelphiPaths('Software\CodeGear\BDS\7.0', 'Test Path', ToRemove, ToAdd);
    finally ToAdd.Free;
    end;
  finally ToRemove.Free;
  end;
end;

注意两者 ToRemove 和 ToAdd. 。我可以在删除和添加列表中安全地指定一个搜索路径：仅当路径匹配“删除”标准时才删除路径，但也不在“ toadd”列表中。还要注意 PathMatchesRemoveCriteria 功能。

您可能可以修改代码以直接从Innoscript本身工作，也可以将代码放入DLL中并使用安装程序中的DLL。 DLL变体具有在Delphi中轻松调试的优点，并且在Inno本身中非常容易。 Inno变体具有没有外部依赖性的优点，但是该代码需要进行调整和调试。