做一个N维走在纯粹的功能ML？

Question

我们的想法是多个维度走过去，每一个定义为范围

(* lower_bound, upper_bound, number_of_steps *)
type range = real * real * int

所以类似功能的 fun foo y x 或 fun foo z y x 可以应用于整个正方形X Y或立方体X ý* Z。

SML / NJ不喜欢低于我实现：

test2.sml:7.5-22.6 Error: right-hand-side of clause doesn't agree with function result type [circularity]
  expression:  (real -> 'Z) -> unit
  result type:  'Z -> 'Y
  in declaration:
    walk = (fn arg => (fn <pat> => <exp>))

下面的代码：

fun walk []      _ = ()
  | walk (r::rs) f =
  let
    val (k0, k1, n) = r
    val delta = k1 - k0
    val step = delta / real n

    fun loop 0 _ = ()
      | loop i k = 
        let in
          walk rs (f k) ;          (* Note (f k) "eats" the first argument.
                                      I guess SML doesn't like having the
                                      type of walk change in the middle of its
                                      definition *)
          loop (i - 1) (k + step)
        end
  in
    loop n k0
  end

fun do2D y x = (* ... *) ()
fun do3D z y x = (* ... *) ()

val x_axis = (0.0, 1.0, 10)
val y_axis = (0.0, 1.0, 10)
val z_axis = (0.0, 1.0, 10)

val _ = walk [y_axis, x_axis] do2D
val _ = walk [z_axis, y_axis, x_axis] do3D

就是这种结构的可能？

任何指针欢迎。

Answer 1

在ML的类型系统是walk表达

val walk : range list -> (real -> real -> unit) -> unit
val walk : range list -> (real -> real -> real -> unit) -> unit

在相同的一个值不可能与两个在ML那些类型存在。

---

我们可以很容易地产生的值的每个所期望的类型的，虽然。

type range = real * real * int

signature WALK =
  sig
    type apply
    val walk : range list -> apply -> unit
  end

structure Walk0 : WALK =
  struct
    type apply = unit
    fun walk _ _ = ()
  end

functor WALKF (Walk : WALK) : WALK =
  struct
    type apply = real -> Walk.apply
    fun walk ((low, high, steps)::rs) f =
          let fun loop i =
                if i > steps then () else
                  let val x = low + (high - low) * real i / real steps
                  in (Walk.walk rs (f x); loop (i + 1)) end
          in loop 0 end
  end

struture Walk1 = WALKF(Walk0)
struture Walk2 = WALKF(Walk1)
struture Walk3 = WALKF(Walk2)

通过此，将具有期望类型存在以下的值。

val Walk0.walk : range list -> unit -> unit
val Walk1.walk : range list -> (real -> unit) -> unit
val Walk2.walk : range list -> (real -> real -> unit) -> unit
val Walk3.walk : range list -> (real -> real -> real -> unit) -> unit

然后你只需要编写

val _ = Walk2.walk [y_axis, x_axis] do2D
val _ = Walk3.walk [z_axis, y_axis, x_axis] do3D

---

要使用相同的walk每一个维度，您需要使用相同的类型，为每个维度。

fun walk nil f = f nil
  | walk ((low, high, steps)::rs) f =
      let fun loop i =
            if i > steps then () else
              let val x = low + (high - low) * real i / real steps
              in (walk rs (fn xs -> f (x::xs)); loop (i + 1)) end
      in loop 0 end

由于该类型被改变成

val walk : range list -> (real list -> unit) -> unit

您的使用情况也有可能改变到

fun do2D [y,x] = (* ... *) ()
fun do3D [z,y,x] = (* ... *) ()

Answer 2

fun walk lst f = let
  fun aux rev_prefix [] = f (rev rev_prefix)
    | aux rev_prefix (r::rs) = let
        val (k0, k1, n) = r
        val delta = k1 - k0
        val step = delta / real n

        fun loop 0 _ = ()
          | loop i k = (
              aux (k+step :: rev_prefix) rs;
              loop (i - 1) (k + step)
            )
      in
        loop n k0
      end
in
  aux [] lst
end

fun do2D [x,y] = print (Real.toString x ^ "\t" ^
                        Real.toString y ^ "\n")
fun do3D [x,y,z] = print (Real.toString x ^ "\t" ^
                          Real.toString y ^ "\t" ^
                          Real.toString z ^ "\n")

val x_axis = (0.0, 1.0, 10)
val y_axis = (0.0, 1.0, 10)
val z_axis = (0.0, 1.0, 10)

val () = walk [y_axis, x_axis] do2D
val () = walk [z_axis, y_axis, x_axis] do3D

Answer 3

找到的参数可变数目此实施的。不知道它适用，但它看起来很丑陋。