如何将参数传递给批处理文件？
https://stackoverflow.com/questions/26551
-
09-06-2019 - |
italiano
english
français
española
中国
日本の
العربية
Deutsch
한국어
Português
Russian题
我需要在运行时将 ID 和密码传递给批处理文件，而不是将它们硬编码到文件中。
命令行如下所示：
test.cmd admin P@55w0rd > test-log.txt
解决方案 2
我是这样做的：
@fake-command /u %1 /p %2
该命令如下所示：
test.cmd admin P@55w0rd > test-log.txt
这 %1 适用于第一个参数 %2 （这是棘手的部分）适用于第二个。通过这种方式最多可以传递 9 个参数。
其他提示
另一个有用的技巧是使用 %* 意为“全部”。例如：
echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*
当你跑步时：
test-command admin password foo bar
上面的批处理文件将运行：
fake-command /u admin /p password admin password foo bar
我的语法可能略有错误，但这是总体思路。
如果您想智能地处理丢失的参数，您可以执行以下操作：
IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1
:No1
ECHO No param 1
GOTO End1
:No2
ECHO No param 2
GOTO End1
:End1
使用 %1、%2、... 可以轻松访问批处理参数%9 或 %*,
但前提是内容简单。
对于像这样复杂的内容没有简单的方法 "&"^&, ，因为不可能在不产生错误的情况下访问 %1。
set var=%1
set "var=%1"
set var=%~1
set "var=%~1"
这些行扩展到
set var="&"&
set "var="&"&"
set var="&"&
set "var="&"&"
每行都会失败，作为其中之一 & 是在引号之外。
可以通过读取临时文件来解决 评论过 参数的版本。
@echo off
SETLOCAL DisableDelayedExpansion
SETLOCAL
for %%a in (1) do (
set "prompt="
echo on
for %%b in (1) do rem * #%1#
@echo off
) > param.txt
ENDLOCAL
for /F "delims=" %%L in (param.txt) do (
set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'
诀窍是启用 echo on 并在 a 之后展开 %1 rem 声明（也适用于 %2 .. %*).
所以即使 "&"& 正如所指出的，可以在不产生错误的情况下进行回显。
但能够重定向输出 echo on, ，您需要两个 for 循环。
额外的字符 * # 用于安全防范类似内容 /? （将显示帮助 REM).
或者，行尾的插入符号 ^ 可以用作多行字符，即使在 rem.
然后阅读 雷姆参数 从文件中输出，但要小心。
for /f应该与延迟扩展合作，否则内容与“！”一起使用。会被摧毁。
删除多余的字符后 param1, ， 你说对了。
并使用 param1 以安全的方式启用延迟扩展。
是的，只是不要忘记使用像这样的变量 %%1 使用时 if 和 for 和那帮人。
如果你忘记了双 %, ，那么您将替换（可能为空）命令行参数，并且您将收到一些非常令人困惑的错误消息。
没有必要让它复杂化。它只是命令%1 %2 参数，例如，
@echo off
xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z
echo copied %1 to %2
pause
“暂停”显示批处理文件已完成的操作，并等待您按 ANY 键。将其另存为 Windows 文件夹中的 xx.bat。
要使用它，请键入：
xx c:\f\30\*.* f:\sites\30
该批处理文件负责处理所有必要的参数，例如仅复制较新的文件等。我从 Windows 之前就开始使用它了。如果您喜欢在复制文件时查看文件名，请省略 Q 范围。
@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue
笔记：如果 "%1"=="" 会引起问题，如果 %1 本身用引号引起来。
在这种情况下，使用 IF [%1]==[] 或者，仅在 NT 4 (SP6) 及更高版本中， IF "%~1"=="" 反而。
最近一位朋友问我这个主题，所以我想我应该发布如何处理批处理文件中的命令行参数。
正如您将看到的，这种技术有一点开销，但它使我的批处理文件非常容易理解并快速实现。以及支持以下结构：
>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]
它的要点是拥有 :init, :parse, ， 和 :main 功能。
用法示例
>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
USAGE:
test.bat [flags] "required argument" "optional argument"
/?, --help shows this help
/v, --version shows the version
/e, --verbose shows detailed output
-f, --flag value specifies a named parameter value
>template.bat <- throws missing argument error
(same as /?, plus..)
**** ****
**** MISSING "REQUIRED ARGUMENT" ****
**** ****
>template.bat -v
1.23
>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument: "arg1"
UnNamedOptionalArg: not provided
NamedFlag: not provided
>template.bat --flag "my flag" arg1 arg2
UnNamedArgument: "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag: "my flag"
>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument: "argument #1"
UnNamedOptionalArg: "second"
NamedFlag: "my flag"
模板.bat
@::!/dos/rocks
@echo off
goto :init
:header
echo %__NAME% v%__VERSION%
echo This is a sample batch file template,
echo providing command-line arguments and flags.
echo.
goto :eof
:usage
echo USAGE:
echo %__BAT_NAME% [flags] "required argument" "optional argument"
echo.
echo. /?, --help shows this help
echo. /v, --version shows the version
echo. /e, --verbose shows detailed output
echo. -f, --flag value specifies a named parameter value
goto :eof
:version
if "%~1"=="full" call :header & goto :eof
echo %__VERSION%
goto :eof
:missing_argument
call :header
call :usage
echo.
echo **** ****
echo **** MISSING "REQUIRED ARGUMENT" ****
echo **** ****
echo.
goto :eof
:init
set "__NAME=%~n0"
set "__VERSION=1.23"
set "__YEAR=2017"
set "__BAT_FILE=%~0"
set "__BAT_PATH=%~dp0"
set "__BAT_NAME=%~nx0"
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedOptionalArg="
set "NamedFlag="
:parse
if "%~1"=="" goto :validate
if /i "%~1"=="/?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="-?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="--help" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="/v" call :version & goto :end
if /i "%~1"=="-v" call :version & goto :end
if /i "%~1"=="--version" call :version full & goto :end
if /i "%~1"=="/e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="-e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--verbose" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--flag" set "NamedFlag=%~2" & shift & shift & goto :parse
if not defined UnNamedArgument set "UnNamedArgument=%~1" & shift & goto :parse
if not defined UnNamedOptionalArg set "UnNamedOptionalArg=%~1" & shift & goto :parse
shift
goto :parse
:validate
if not defined UnNamedArgument call :missing_argument & goto :end
:main
if defined OptVerbose (
echo **** DEBUG IS ON
)
echo UnNamedArgument: "%UnNamedArgument%"
if defined UnNamedOptionalArg echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
if not defined UnNamedOptionalArg echo UnNamedOptionalArg: not provided
if defined NamedFlag echo NamedFlag: "%NamedFlag%"
if not defined NamedFlag echo NamedFlag: not provided
:end
call :cleanup
exit /B
:cleanup
REM The cleanup function is only really necessary if you
REM are _not_ using SETLOCAL.
set "__NAME="
set "__VERSION="
set "__YEAR="
set "__BAT_FILE="
set "__BAT_PATH="
set "__BAT_NAME="
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedArgument2="
set "NamedFlag="
goto :eof
让我们保持简单。
这是 .cmd 文件。
@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%
以下是来自命令行的 3 个调用。
C:\Users\joeco>echo_3params 1abc 2 def 3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def
C:\Users\joeco>echo_3params 1abc "2 def" "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"
C:\Users\joeco>echo_3params 1abc '2 def' "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'
C:\Users\joeco>
FOR %%A IN (%*) DO (
REM Now your batch file handles %%A instead of %1
REM No need to use SHIFT anymore.
ECHO %%A
)
这将循环遍历批处理参数 (%*)，无论它们是否被引用，然后回显每个参数。
我编写了一个简单的 read_params 脚本，可以将其作为函数（或外部函数）调用 .bat）并将所有变量放入当前环境中。它不会修改原始参数，因为该函数正在被修改 call编辑原始参数的副本。
例如，给出以下命令：
myscript.bat some -random=43 extra -greeting="hello world" fluff
myscript.bat 调用函数后就可以使用变量：
call :read_params %*
echo %random%
echo %greeting%
这是函数：
:read_params
if not %1/==/ (
if not "%__var%"=="" (
if not "%__var:~0,1%"=="-" (
endlocal
goto read_params
)
endlocal & set %__var:~1%=%~1
) else (
setlocal & set __var=%~1
)
shift
goto read_params
)
exit /B
局限性
- 无法加载没有值的参数，例如
-force. 。你可以使用-force=true但我想不出一种方法可以在不提前知道没有值的参数列表的情况下允许空白值。
变更日志
- 2/18/2016
- 不再需要延迟扩展
- 现在通过查找与其他命令行参数一起使用
-参数之前。
要在命令行中引用设置变量，您需要使用 %a% 例如：
set a=100
echo %a%
rem output = 100
笔记：这适用于 Windows 7 专业版。
新建一个批处理文件（例如：openclass.bat）并在文件中写入这一行：
java %~n1
然后将批处理文件放入 system32 文件夹中，转到 Java 类文件，右键单击“属性”，打开方式...，然后找到批处理文件，选择它，就是这样...
这个对我有用。
附：当我关闭Java类时，我找不到关闭cmd窗口的方法。目前...
灵感来自于 在别处回答 通过@Jon，我设计了一个更通用的算法来提取命名参数、可选值和开关。
假设我们想要实现一个实用程序 foobar. 。它需要一个初始命令。它有一个可选参数 --foo 这需要一个 选修的 value（当然不能是另一个参数）；如果该值缺失，则默认为 default. 。它还有一个可选参数 --bar 这需要一个 必需的 价值。最后它可以带一个标志 --baz 没有允许的值。哦，这些参数可以按任何顺序出现。
换句话说，它看起来像这样：
foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]
这是一个解决方案：
@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson
SET CMD=%~1
IF "%CMD%" == "" (
GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=
SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
SHIFT
IF NOT "%ARG%" == "" (
IF NOT "%ARG:~0,2%" == "--" (
SET FOO=%ARG%
SHIFT
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE IF "%PARAM%" == "--bar" (
SHIFT
IF NOT "%ARG%" == "" (
SET BAR=%ARG%
SHIFT
) ELSE (
ECHO Missing bar value. 1>&2
ECHO:
GOTO usage
)
) ELSE IF "%PARAM%" == "--baz" (
SHIFT
SET BAZ=true
) ELSE IF "%PARAM%" == "" (
GOTO endargs
) ELSE (
ECHO Unrecognized option %1. 1>&2
ECHO:
GOTO usage
)
GOTO args
:endargs
ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
ECHO Baz
)
REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof
:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1
- 使用
SETLOCAL以便变量不会逃逸到调用环境中。 - 不要忘记初始化变量
SET FOO=, ， ETC。以防有人在调用环境中定义它们。 - 使用
%~1删除引号。 - 使用
IF "%ARG%" == ""并不是IF [%ARG%] == []因为[和]根本不要玩弄以空格结尾的值。 - 即使你
SHIFT里面一个IF块，当前参数例如%~1不会更新，因为它们是在IF被解析。你可以使用%~1和%~2在 - 的里面IF块，但这会令人困惑，因为你有一个SHIFT. 。你可以把SHIFT为了清楚起见，在块的末尾，但这也可能会丢失和/或使人们感到困惑。就这样“捕捉”%~1和%~1街区外似乎是最好的。 - 您不想使用一个参数来代替另一个参数的可选值，因此您必须检查
IF NOT "%ARG:~0,2%" == "--". - 仅要小心
SHIFT当你 使用 参数之一。 - 重复的代码
SET FOO=%DEFAULT_FOO%令人遗憾的是，但另一种选择是添加一个IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%之外的IF NOT "%ARG%" == ""堵塞。然而，因为这仍然在IF "%PARAM%" == "--foo"块，%FOO%值将在您进入块之前进行评估和设置，因此您永远不会检测到该值 两个都 这--foo参数存在 并且 认为%FOO%值缺失。 - 注意
ECHO Missing bar value. 1>&2将错误消息发送到 stderr。 - 想要在 Windows 批处理文件中添加一个空行吗？你必须使用
ECHO:或变体之一。
简单的解决方案（即使问题很旧）
测试1.bat
echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause
呼叫测试1.bat
call "C:\Temp\Test1.bat" pass123
输出
YourLocalPath>call "C:\Temp\test.bat" pass123
YourLocalPath>echo off
"Batch started"
"arg1 is pass123"
YourLocalPath>pause
Press any key to continue . . .
其中 YourLocalPath 是当前目录路径。
为了简单起见，将命令参数存储在变量中并使用变量进行比较。
它不仅编写简单，而且维护也简单，因此，如果其他人或您在很长一段时间后阅读您的脚本，它将很容易理解和维护。
内联编写代码：查看其他答案。
要使用循环获取所有参数并以纯批处理方式：
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
)
goto :eof
您的代码已准备好在需要时使用参数编号执行某些操作，例如...
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift
)
fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt
不隶属于 StackOverflow
