Batch-Datei, die eine Verbindung zum Server basierend auf VLAN herstellt

Question

Dies ist ein Ausschnitt meines Automatisierungsskripts für das Imaging von einem bestimmten Server basierend auf VLAN.Das Skript überprüft seine IP und welches VLAN es verwendet, um dann eine Verbindung zu einem bestimmten Server herzustellen.Mein Problem ist, dass ich die Fehlermeldung „Wenn es zu diesem Zeitpunkt unerwartet ist“ erhalte.Bitte helfen Sie.

:getvlan
for /f "tokens=2 delims=:" %%a in ('ipconfig ^| find "IPv4 Address"') do set IP=%%a
for /f "tokens=3 delims=." %%j in ('echo %IP%') do set vlan=%%j

if %vlan% GEQ 100 (if %vlan% LEQ 119 (
   set servernowack=server1
   set seshtype=M
) if %vlan% GEQ 130 (if %vlan% LEQ 139 (
   set servernowack=server2
   set seshtype=D
) if %vlan% GEQ 140 (if %vlan% LEQ 149 (
   set servernowack=server3
   set seshtype=D
) if %vlan% GEQ 150 (if %vlan% LEQ 159 (
   set servernowack=server4
   set seshtype=M
) if %vlan% GEQ 160 (if %vlan% LEQ 169 (
   set servernowack=server5
   set seshtype=D
) else (
   goto fail
)
goto getserverip

Answer 1

Es gibt viel mehr öffnende als schließende Klammern.daher cmd.exe Es gelingt nicht, den Block für jeden zu bestimmen if in Ihrem Batch-Code ein einfacher Syntaxfehler, der leicht zu beheben ist.

@echo off
:getvlan
for /f "tokens=2 delims=:" %%a in ('%windir%\system32\ipconfig.exe ^| %windir%\system32\find.exe "IPv4 Address"') do set IP=%%a
for /f "tokens=3 delims=." %%j in ('echo %IP%') do set vlan=%%j

if %vlan% GEQ 100 (
   if %vlan% LEQ 119 (
      set servernowack=server1
      set seshtype=M
      goto getserverip
   )
)
if %vlan% GEQ 130 (
   if %vlan% LEQ 139 (
      set servernowack=server2
      set seshtype=D
      goto getserverip
   )
)
if %vlan% GEQ 140 (
   if %vlan% LEQ 149 (
      set servernowack=server3
      set seshtype=D
      goto getserverip
   )
)
if %vlan% GEQ 150 (
   if %vlan% LEQ 159 (
      set servernowack=server4
      set seshtype=M
      goto getserverip
   )
)
if %vlan% GEQ 160 (
   if %vlan% LEQ 169 (
      set servernowack=server5
      set seshtype=D
      goto getserverip
   )
)
echo Error: Failed to determine vlan!
goto :EOF

:getserverip