taint-Modus perl:suid beibehalten, wenn externes Programm über system () ausgeführt wird
Frage
Ich versuche, einem Legacy-Skript eine Funktion hinzuzufügen.Das Skript ist suid und verwendet perl -T (Taint-Modus:man perlsec), für zusätzliche Sicherheit.Die Funktion, die ich hinzufügen muss, ist in Python implementiert.
Mein Problem ist, dass ich perlsec nicht davon überzeugen kann, die suid-Berechtigungen beizubehalten, egal wie sehr ich die Umgebung und meine Befehlszeilen wasche.
Dies ist frustrierend, da die SUID für andere Binärdateien (z. B. /bin / id) beibehalten wird.Gibt es einen undokumentierten Sonderfall für / usr / bin / perl?Das scheint unwahrscheinlich.
Kennt jemand einen Weg, wie das funktioniert?(Ist-Zustand:Wir haben nicht die Ressourcen, um das Ganze neu zu gestalten.)
Lösung: (gemäß @gbacon)
# use the -p option to bash
system('/bin/bash', '-p', '-c', '/usr/bin/id -un');
# or set real user and group ids
$< = $>;
$( = $);
system('/usr/bin/python', '-c', 'import os; os.system("/usr/bin/id -un")');
Gibt die gewünschten Ergebnisse!
Hier ist eine abgespeckte Version meines Skripts, die immer noch mein Problem zeigt.
#!/usr/bin/perl -T
## This is an SUID script: man perlsec
%ENV = ( "PATH" => "" );
##### PERLSEC HELPERS #####
sub tainted (@) {
# Prevent errors, stringifying
local(@_, $@, $^W) = @_;
#let eval catch the DIE signal
$SIG{__DIE__} = '';
my $retval = not eval { join("",@_), kill 0; 1 };
$SIG{__DIE__} = 'myexit';
return $retval
}
sub show_taint {
foreach (@_) {
my $arg = $_; #prevent "read-only variable" nonsense
chomp $arg;
if ( tainted($arg) ) {
print "TAINT:'$arg'";
} else {
print "ok:'$arg'";
}
print ", ";
}
print "\n";
}
### END PERLSEC HELPERS ###
# Are we SUID ? man perlsec
my $uid = `/usr/bin/id --user` ;
chomp $uid;
my $reluser = "dt-pdrel";
my $reluid = `/usr/bin/id --user $reluser 2> /dev/null`;
chomp $reluid;
if ( $uid ne $reluid ) {
# what ? we are not anymore SUID ? somebody must do a chmod u+s $current_script
print STDERR "chmod 4555 $myname\n";
exit(14);
}
# comment this line if you don't want to autoflush after every print
$| = 1;
# now, we're safe, single & SUID
# - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
# BEGIN of main code itself
print "\nENVIRON UNDER BASH:\n";
run('/bin/bash', '-c', '/bin/env');
print "\nTAINT DEMO:\n";
print "\@ARGV: ";
show_taint(@ARGV);
print "\%ENV: ";
show_taint(values %ENV);
print "`cat`: ";
show_taint(`/bin/cat /etc/host.conf`);
print "\nworks:\n";
run('/usr/bin/id', '-un');
run('/usr/bin/id -un');
print "\ndoesn't work:\n";
run('/bin/bash', '-c', '/usr/bin/id -un');
run('/bin/bash', '-c', '/bin/date >> /home/dt-pdrel/date');
run('/bin/date >> /home/dt-pdrel/date');
run('/usr/bin/python', '-c', 'import os; os.system("/usr/bin/id -un")');
run('/usr/bin/python', '-c', 'import os; os.system("/usr/bin/id -un")');
sub run {
my @cmd = @_;
print "\tCMD: '@cmd'\n";
print "\tSEC: ";
show_taint(@cmd);
print "\tOUT: ";
system @cmd ;
print "\n";
}
Und hier ist die Ausgabe:
$ id -un
bukzor
$ ls -l /proj/test/test.pl
-rwsr-xr-x 1 testrel asic 1976 Jul 22 14:34 /proj/test/test.pl*
$ /proj/test/test.pl foo bar
ENVIRON UNDER BASH:
CMD: '/bin/bash -c /bin/env'
SEC: ok:'/bin/bash', ok:'-c', ok:'/bin/env',
OUT: PATH=
PWD=/proj/test2/bukzor/test_dir/
SHLVL=1
_=/bin/env
TAINT DEMO:
@ARGV: TAINT:'foo', TAINT:'bar',
%ENV: ok:'',
`cat`: TAINT:'order hosts,bind',
works:
CMD: '/usr/bin/id -un'
SEC: ok:'/usr/bin/id', ok:'-un',
OUT: testrel
CMD: '/usr/bin/id -un'
SEC: ok:'/usr/bin/id -un',
OUT: testrel
doesn't work:
CMD: '/bin/bash -c /usr/bin/id -un'
SEC: ok:'/bin/bash', ok:'-c', ok:'/usr/bin/id -un',
OUT: bukzor
CMD: '/bin/bash -c /bin/date >> /home/testrel/date'
SEC: ok:'/bin/bash', ok:'-c', ok:'/bin/date >> /home/testrel/date',
OUT: /bin/bash: /home/testrel/date: Permission denied
CMD: '/bin/date >> /home/testrel/date'
SEC: ok:'/bin/date >> /home/testrel/date',
OUT: sh: /home/testrel/date: Permission denied
CMD: '/usr/bin/python -c import os; os.system("/usr/bin/id -un")'
SEC: ok:'/usr/bin/python', ok:'-c', ok:'import os; os.system("/usr/bin/id -un")',
OUT: bukzor
CMD: '/usr/bin/python -c import os; os.system("/usr/bin/id -un")'
SEC: ok:'/usr/bin/python', ok:'-c', ok:'import os; os.system("/usr/bin/id -un")',
OUT: bukzor
Lösung
Sie müssen Ihre echte Benutzer-ID auf die effektive (suid-ed) setzen.Wahrscheinlich möchten Sie dasselbe für Ihre echte Gruppen-ID tun:
#! /usr/bin/perl -T
use warnings;
use strict;
$ENV{PATH} = "/bin:/usr/bin";
system "id -un";
system "/bin/bash", "-c", "id -un";
# set real user and group ids
$< = $>;
$( = $);
system "/bin/bash", "-c", "id -un";
Probelauf:
$ ls -l suid.pl -rwsr-sr-x 1 nobody nogroup 177 2010-07-22 20:33 suid.pl $ ./suid.pl nobody gbacon nobody
Was Sie sehen, ist dokumentiert bash
Verhalten:
-p
Aktivieren Sie den privilegierten Modus.In diesem Modus wird die
$BASH_ENV
und$ENV
dateien werden nicht verarbeitet, Shell-Funktionen werden nicht von der Umgebung geerbt und dieSHELLOPTS
,BASHOPTS
,CDPATH
undGLOBIGNORE
variablen werden ignoriert, wenn sie in der Umgebung vorkommen.Wenn die Shell mit der effektiven Benutzer-(Gruppen-) ID gestartet wird, die nicht der realen Benutzer-(Gruppen-)ID entspricht, und die-p
option nicht angegeben ist, werden diese Aktionen ausgeführt und die effektive Benutzer-ID wird auf die reale Benutzer-ID gesetzt.Wenn die-p
option wird beim Start bereitgestellt, die effektive Benutzer-ID wird nicht zurückgesetzt.Wenn Sie diese Option deaktivieren, werden die effektiven Benutzer- und Gruppen-IDs auf die realen Benutzer- und Gruppen-IDs gesetzt.
Das heißt, Sie könnten auch
#! /usr/bin/perl -T
use warnings;
use strict;
$ENV{PATH} = "/bin:/usr/bin";
system "/bin/bash", "-p", "-c", "id -un";
bekommen
nobody
Erinnern Sie sich daran, dass mehrere Argumente an übergeben werden system
umgeht die Shell.Ein einzelnes Argument geht an die Shell, aber wahrscheinlich nicht bash
- schau dir die Ausgabe von an perl -MConfig -le 'print $Config{sh}'
.