Write character to video buffer MASM

Question

I am trying to write the letter 'D' in blue on a white background by moving it to the video buffer. What is wrong with this code?

INCLUDE Irvine16.inc

.code
main PROC

mov ax,@data
mov ds,ax

mov si, 0b800h
mov word ptr [si], 44h
mov word ptr [si+2] 0701h

mov ah, 08h
int 21h

exit

main ENDP

Made the changes to above. It now assembles, but displays nothing.

Answer 1

Sample example:

name "hello-world"
org 100h

; set video mode     
mov ax, 3     ; text mode 80x25, 16 colors, 8 pages (ah=0, al=3) 
int 10h       ; do it! 

; cancel blinking and enable all 16 colors: 
mov ax, 1003h
mov bx, 0
int 10h


; set segment register: 
mov     ax, 0b800h
mov     ds, ax

; print "hello world" 
; first byte is ascii code, second byte is color code. 

mov [02h], 'h'

mov [04h], 'e'

mov [06h], 'l'

mov [08h], 'l'

mov [0ah], 'o'

mov [0ch], ','

mov [0eh], 'w'

mov [10h], 'o'

mov [12h], 'r'

mov [14h], 'l'

mov [16h], 'd'

mov [18h], '!'




; color all characters: 
mov cx, 12  ; number of characters. 
mov di, 03h ; start from byte after 'h' 

c:  mov [di], 11101100b   ; light red(1100) on yellow(1110) 
    add di, 2 ; skip over next ascii code in vga memory. 
    loop c

; wait for any key press: 
mov ah, 0
int 16h

ret

Hope this sample helps you

Answer 2

1) 0b800h is the segment address of the video buffer. mov word ptr [si], 44h addresses just the offset (here: 0b800h) of the segment address in DS - and DSdoesn't point to the video buffer. I suggest to load the video segment into ES and to use a segment override (ES:).

2) Letter plus color form together a word. In the video buffer first comes the letter then the color. Background and foreground color use each a nibble (4 bit). Due to "little endianness" (google for it) a word should have the format color/letter, e.g. white/blue/'D' = 7144h

This is an Irvine16 compatible example:

INCLUDE Irvine16.inc
INCLUDELIB Irvine16.lib

.CODE
main PROC
;   mov ax,@data                ; No .DATA in this example
;   mov ds,ax

    mov si, 0b800h              ; Initialize ES with video buffer
    mov es, si

    xor si, si                  ; Position 0 is top left
    mov word ptr es:[si], 7144h ; White background ('7'), blue foreground (1), letter 'D' (44)

    mov ah, 08h                 ; Wait for key - http://www.ctyme.com/intr/rb-2561.htm
    int 21h

    exit                        ; Irvine16: end of program
main ENDP

END main

Answer 3

Have a look at Listing 15 here:

http://stuff.pypt.lt/ggt80x86a/asm8.htm