Restringir los tipos de archivos en la gotita

Question

Esta pregunta no se limita a las personas que conocen AppleScript, si lo hace de cacao, etc., usted debe saber la respuesta a esta:

  

Estoy haciendo una gota en AppleScript que comprime los archivos JavaScript, por lo que, obviamente, sólo quiero archivos JavaScript para ser admitidos en los guiones. ¿Alguna idea?

Muchas gracias.

Answer 1

property kJavascriptExtension : "js"
property pValidFileList : {}

on open of theFiles -- Executed when files are dropped on the script

    set fileCount to (get count of items in theFiles)

    repeat with thisFile from 1 to fileCount
        set theFile to item thisFile of theFiles
        set theFileAlias to theFile as alias

        tell application "Finder"
            set fileInfo to info for theFileAlias
            set fileName to name of fileInfo
        end tell

        set javascriptFileFound to isJavascriptFile(fileName) of me

        if (javascriptFileFound) then
            set end of pValidFileList to theFile
        end if
    end repeat

    display dialog "pValidFileList = " & pValidFileList
    -- do something with your files here
end open

on isJavascriptFile(theFilename) -- (theFilename as string) as boolean
    set AppleScript's text item delimiters to "."
    set fileNameList to every text item of theFilename
    set AppleScript's text item delimiters to ""

    try
        set theFileExtension to item 2 of fileNameList as string
    on error
        return false
    end try

    if theFileExtension is kJavascriptExtension then
        return true
    end if

    return false
end isJavascriptFile