Compilation Boost Library pour Windows Embedded Compact 7

Question

Je programmer pour un appareil intégré avec un Nvidia Tegra 2 exécutant Windows Embedded Compact 7. Mon environnement de développement est Microsoft Visual Studio 2008. La bibliothèque Boost et en particulier le package Boost-ASIO semble être très utile pour mes besoins. Malheureusement, je n'ai pas pu trouver un bon guide sur la façon de faire fonctionner Boost sur Windows Embedded Compact 7. Je préfère obtenir .lib Fichiers que je peux lier statiquement à mon application.

Answer 1

Il semble que la documentation sur ce processus soit clairsemée, car elle nécessite des mises à jour non triviales du processus de construction pour travailler avec Windows CE. Le tutoriel le plus complet de ce problème semble être ici.

Puisque vous avez explicitement marqué cela boost-asio, J'ai également examiné ce composant de Boost spécifiquement. Voici un fil de la liste de diffusion Boost qui couvre en détail cette bibliothèque, y compris les cas de défaillance potentiels que vous pouvez ressentir, Modifications de fichiers JAM, et un fichier batch pour vous aider avec la construction.*

Pour ceux qui lisent ceci: s'il vous plaît Partagez vos expériences une fois que vous avez fonctionné. Malgré diverses préoccupations qui Boost est trop lourd pour la mémoire pour les applications intégrées, Boost offre la possibilité d'utiliser des packages séparés pour répondre à vos besoins. Je m'attends à ce que d'autres utilisateurs soient donc très intéressé par vos expériences pour que cela fonctionne.

---

* Parce que les gens ont exprimé des problèmes avec le fichier de lots référencé disparaissant lorsque les liens de nabsal expirent, voici un col de la postérité:

@SET VCINSTALLDIR=%VS9INSTALLDIR%\VC 
@if "%VS9INSTALLDIR%"=="" goto error_no_VSINSTALLDIR 
@if "%VCINSTALLDIR%"=="" goto error_no_VCINSTALLDIR 

@echo Setting environment for using Microsoft Visual Studio 2008 tools for WM5. 
@set TARGETCPU=X86 

@call :GetWindowsSdkDir 

@if not "%WindowsSdkDir%" == "" ( 
        set "PATH=%WindowsSdkDir%bin;%PATH%" 
) 

@rem 
@rem Root of Visual Studio IDE installed files. 
@rem 
@set DevEnvDir=%VS9INSTALLDIR%\Common7\IDE 

@set PATH=%VCINSTALLDIR%\CE\bin\x86_arm;%VCINSTALLDIR%\bin;%VS9INSTALLDIR%\Common7\Tools;%DevEnvDir%;%VS9INSTALLDIR%\Common\Tools;%VS9INSTALLDIR%\Common\IDE;%VS9INSTALLDIR%;%PATH% 
@set INCLUDE=%STLPORT_PATH%\STLPort-5.2.1\stlport;%VCINSTALLDIR%\ce\include;%CETOOLS%\Windows Mobile 5.0 Pocket PC SDK\include\ARMV4I;%CETOOLS%\Windows Mobile 5.0 Pocket PC SDK\include;%VCINSTALLDIR%\ce\atlmfc\include 
@set LIB=%STLPORT_PATH%\STLPort-5.2.1\lib\evc9-arm;%CETOOLS%\Windows Mobile 5.0 Pocket PC SDK\lib\ARMV4I;%VCINSTALLDIR%\ce\ATLMFC\LIB\ARMV4I;%VCINSTALLDIR%\ce\LIB\ARMV4I 
@set LIBPATH= 

@goto end 

:GetWindowsSdkDir 
@call :GetWindowsSdkDirHelper HKLM > nul 2>&1 
@if errorlevel 1 call :GetWindowsSdkDirHelper HKCU > nul 2>&1 
@if errorlevel 1 set WindowsSdkDir=%VCINSTALLDIR%\PlatformSDK\ 
@exit /B 0 

:GetWindowsSdkDirHelper 
@for /F "tokens=1,2*" %%i in ('reg query "%1\SOFTWARE\Microsoft\Microsoft SDKs\Windows" /v "CurrentInstallFolder"') DO ( 
        if "%%i"=="CurrentInstallFolder" ( 
                SET "WindowsSdkDir=%%k" 
        ) 
) 
@if "%WindowsSdkDir%"=="" exit /B 1 
@exit /B 0 


:error_no_VSINSTALLDIR 
@echo ERROR: VS9INSTALLDIR variable is not set. 
@goto end 

:error_no_VCINSTALLDIR 
@echo ERROR: VCINSTALLDIR variable is not set. 
@goto end 

:end 

@SET VCINSTALLDIR=%VS9INSTALLDIR%\VC 
@SET FrameworkDir=C:\WINDOWS\Microsoft.NET\Framework 
@SET FrameworkVersion=v2.0.50727 
@SET Framework35Version=v3.5 
@if "%VS9INSTALLDIR%"=="" goto error_no_VSINSTALLDIR 
@if "%VCINSTALLDIR%"=="" goto error_no_VCINSTALLDIR 

@echo Setting environment for using Microsoft Visual Studio 2008 x86 tools with STLport-5.2.1. 

@call :GetWindowsSdkDir 

@if not "%WindowsSdkDir%" == "" ( 
        set "PATH=%WindowsSdkDir%bin;%PATH%" 
        set "INCLUDE=%WindowsSdkDir%include;%INCLUDE%" 
        set "LIB=%WindowsSdkDir%lib;%LIB%" 
) 


@rem 
@rem Root of Visual Studio IDE installed files. 
@rem 
@set DevEnvDir=%VS9INSTALLDIR%\Common7\IDE 

@set PATH=%DevEnvDir%;%VCINSTALLDIR%\BIN;%VS9INSTALLDIR%\Common7\Tools;%FrameworkDir%\%Framework35Version%;%FrameworkDir%\%FrameworkVersion%;%VCINSTALLDIR%\VCPackages;%PATH% 
@set INCLUDE=%STLPORT_PATH%\STLport-5.2.1\stlport;%VCINSTALLDIR%\ATLMFC\INCLUDE;%VCINSTALLDIR%\INCLUDE;%INCLUDE% 
@set LIB=%STLPORT_PATH%\STLport-5.2.1\lib\vc9;%VCINSTALLDIR%\ATLMFC\LIB;%VCINSTALLDIR%\LIB;%LIB% 
@set LIBPATH=%FrameworkDir%\%Framework35Version%;%FrameworkDir%\%FrameworkVersion%;%VCINSTALLDIR%\ATLMFC\LIB;%VCINSTALLDIR%\LIB;%LIBPATH% 

@goto end 

:GetWindowsSdkDir 
@call :GetWindowsSdkDirHelper HKLM > nul 2>&1 
@if errorlevel 1 call :GetWindowsSdkDirHelper HKCU > nul 2>&1 
@if errorlevel 1 set WindowsSdkDir=%VCINSTALLDIR%\PlatformSDK\ 
@exit /B 0 

:GetWindowsSdkDirHelper 
@for /F "tokens=1,2*" %%i in ('reg query "%1\SOFTWARE\Microsoft\Microsoft SDKs\Windows" /v "CurrentInstallFolder"') DO ( 
        if "%%i"=="CurrentInstallFolder" ( 
                SET "WindowsSdkDir=%%k" 
        ) 
) 
@if "%WindowsSdkDir%"=="" exit /B 1 
@exit /B 0 

:error_no_VSINSTALLDIR 
@echo ERROR: VSINSTALLDIR variable is not set. 
@goto end 

:error_no_VCINSTALLDIR 
@echo ERROR: VCINSTALLDIR variable is not set. 
@goto end 

:end