スレッド読み込み（待機）画面

Question

長時間の操作中に待機画面を実装するための汎用メソッドを探しています。スレッドを数回使用したことがありますが、実装が非常に貧弱であるか、手間がかかりすぎます（そしてコピー/貼り付け-恐ろしいことです！）。

これを可能な限り汎用的かつシンプルに保ちたいので、あらゆる種類のがらくたを処理する BackgroundWorker を大量に実装する必要がなく、保守が難しくなります。

ここで私がしたいことです-これは実際に可能な/ベストプラクティス/何でも異なる場合があることに注意してください-VB.NET、Framework 2.0を使用して（匿名メソッドはありません）：

  Private Sub HandleBtnClick(sender as Object, e as EventArgs) Handles Button.Click
      LoadingScreen.Show()

      'Do stuff here, this takes a while!'
      Dim Result as Object = DoSomethingTakingALongTime(SomeControl.SelectedObject)

      LoadingScreen.Hide()

      ProcessResults(Result)
  End Sub

アプリケーションは完全にシングルスレッドになったため、すべてがGUIスレッドで実行されます。クロススレッド例外を取得せずに、 DoSomethingTakingALongTime（）のオブジェクトにアクセスできる必要があります。 GUIスレッドは、（長い時間がかかる）メソッドの完了を待機しますが、 LoadingScreen フォームは応答性を維持する必要があります（アニメーション化されている/プログレスバーなどがあります）。

これは実行可能/適切なアプローチですか？または、この方法はあまりにも単純すぎますか？この問題に関するベストプラクティスは何ですか？そして最も重要なのは、そのようなシステムをどのように実装できるのでしょうか？すでに述べたように、スレッド化の経験はほとんどないので、気をつけてください：-）

Answer 1

問題は、ワーカースレッドデータをUIスレッドに渡そうとすると、クロススレッド例外が発生することです。あなたがする必要があるのは、UIのコントロールを設定する前にInvokeRequiredとbegininvokeをチェックして、そのようなエラーが出ないようにすることです：

Private Sub work_CrossThreadEvent(ByVal sender As Object, ByVal e As System.EventArgs) Handles work.CrossThreadEvent

       If Me.InvokeRequired Then
           Me.BeginInvoke(New EventHandler(AddressOf work_CrossThreadEvent), New Object() {sender, e})
           Return
       End If

      Me.Text = "Cross Thread"

End Sub

新しいEventHandler 部分を、使用しているイベントハンドラーに変更するだけです。

また、バックグラウンドワーカーを使用することは、ワーカークラスにとって悪い方法ではないと思います。 作業用のクラスを作成し、バックグラウンドワーカーを使用して、次のようなスレッド処理を行います。

Public MustInherit Class Worker

    Protected WithEvents worker As BackgroundWorker

    Public Sub New()

        worker = New BackgroundWorker()
        worker.WorkerReportsProgress = True
        worker.WorkerSupportsCancellation = True

    End Sub

    Public Sub Start()

        If (Not worker.IsBusy AndAlso Not worker.CancellationPending) Then
            worker.RunWorkerAsync()
        End If

    End Sub

    Public Sub Cancel()
        If (worker.IsBusy AndAlso Not worker.CancellationPending) Then
            worker.CancelAsync()
        End If
    End Sub

    Protected MustOverride Sub Work()

    Private Sub OnDoWork(ByVal sender As Object, ByVal e As System.ComponentModel.DoWorkEventArgs) Handles worker.DoWork
        Work()
    End Sub

    Public Event WorkCompelted As RunWorkerCompletedEventHandler
    Private Sub OnRunWorkerCompleted(ByVal sender As Object, ByVal e As RunWorkerCompletedEventArgs) Handles worker.RunWorkerCompleted
        OnRunWorkerCompleted(e)
    End Sub
    Protected Overridable Sub OnRunWorkerCompleted(ByVal e As RunWorkerCompletedEventArgs)
        RaiseEvent WorkCompelted(Me, e)
    End Sub

    Public Event ProgressChanged As ProgressChangedEventHandler
    Private Sub OnProgressChanged(ByVal sender As Object, ByVal e As ProgressChangedEventArgs) Handles worker.ProgressChanged
        OnProgressChanged(e)
    End Sub
    Protected Overridable Sub OnProgressChanged(ByVal e As ProgressChangedEventArgs)
        RaiseEvent ProgressChanged(Me, e)
    End Sub

End Class

Public Class ActualWork
    Inherits Worker

    Public Event CrossThreadEvent As EventHandler

    Protected Overrides Sub Work()

        'do work here'
        WorkABit()
        worker.ReportProgress(25)

        WorkABit()
        worker.ReportProgress(50)

        WorkABit()
        worker.ReportProgress(75)

        WorkABit()
        worker.ReportProgress(100)

    End Sub

    Private Sub WorkABit()

        If worker.CancellationPending Then Return
        Thread.Sleep(1000)
        RaiseEvent CrossThreadEvent(Me, EventArgs.Empty)

    End Sub

End Class

免責事項.. vbで少し錆びていますが、アイデアを得る必要があります。

Answer 2

スレッドで、Application.Run（yourform）を使用して必要なものを取得します。

フォームを閉じて何らかの形で閉じるように信号を送る必要があることに注意してください。

Answer 3

これが役に立たないことを望んでいないことを願っていますが、なぜスレッド化された待機画面が必要なのでしょうか？そもそもスレッド化を使用する理由は、UIの応答性を維持し、長時間の操作をバックグラウンドで行うためです。

それ以外の場合は、FormLoadingコントロールにProgressBarを配置し、DoSomethingTakingALongTimeを使用して定期的に更新することもできます。これにはスレッドはまったく必要ありません。