質問
この本が何であるかわからない場合は、「ゼロからプログラミング」を読んでいますが、それでも私を助けることができます。
この本(第4章)には、私が理解していない2つのことがあります。
- 何
movl %ebx, -4(%ebp) #store current result
為に。 - そして、「現在の結果」とはどういう意味ですか
以下のコードのマークされたセクションには、次のとおりです。
movl 8(%ebp), %ebx
それは保存することを意味します 8(%ebp)
に %ebx
, 、しかし、私が理解していない理由は、プログラマーが望んでいる場合です 8(%ebp)
に保存する -4(%ebp)
, 、 どうして〜しなきゃいけない 8(%ebp)
通り抜けられます %ebx
?は "movl 8(%ebp), -4(%ebp)
「Akward?またはタイプミスはありますか movl 8(%ebp), %ebx #put first argument in %eax
? (おもう %ebx
あるべきです %eax
またはその逆)
#PURPOSE: Program to illustrate how functions work
# This program will compute the value of
# 2^3 + 5^2
#Everything in the main program is stored in registers,
#so the data section doesn’t have anything.
.section .data
.section .text
.globl _start
_start:
pushl $3 #push second argument
pushl $2 #push first argument
call power #call the function
addl $8, %esp #move the stack pointer back
pushl %eax #save the first answer before
#calling the next function
pushl $2 #push second argument
pushl $5 #push first argument
call power #call the function
addl $8, %esp #move the stack pointer back
popl %ebx #The second answer is already
#in %eax. We saved the
#first answer onto the stack,
#so now we can just pop it
#out into %ebx
addl %eax, %ebx #add them together
#the result is in %ebx
movl $1, %eax #exit (%ebx is returned)
int $0x80
#PURPOSE: This function is used to compute
# the value of a number raised to
# a power.
#INPUT: First argument - the base number
# Second argument - the power to
# raise it to
#
#OUTPUT: Will give the result as a return value
#
#NOTES: The power must be 1 or greater
#
#VARIABLES:
# %ebx - holds the base number
# %ecx - holds the power
#
# -4(%ebp) - holds the current result
#
# %eax is used for temporary storage
#
.type power, @function
power:
pushl %ebp #save old base pointer
movl %esp, %ebp #make stack pointer the base pointer
subl $4, %esp #get room for our local storage
##########################################
movl 8(%ebp), %ebx #put first argument in %eax
movl 12(%ebp), %ecx #put second argument in %ecx
movl %ebx, -4(%ebp) #store current result
##########################################
power_loop_start:
cmpl $1, %ecx #if the power is 1, we are done
je end_power
movl -4(%ebp), %eax #move the current result into %eax
imull %ebx, %eax #multiply the current result by
#the base number
movl %eax, -4(%ebp) #store the current result
decl %ecx #decrease the power
jmp power_loop_start #run for the next power
end_power:
movl -4(%ebp), %eax #return value goes in %eax
movl %ebp, %esp #restore the stack pointer
popl %ebp #restore the base pointer
ret
解決
私はこれを信じています:
movl 8(%ebp), %ebx #put first argument in %eax
タイプミスでしたが、それは本当にそうあるべきです:
movl 8(%ebp), %ebx #put first argument in %ebx
そして、あなたが気づいた場合、後でコードは正しいです:
movl %ebx, -4(%ebp) #store current result
最終的に、著者は使用できたかもしれません %eax
この操作も(ではなく %ebx
)、プログラムをまったく変更しないので、彼がすべきではない理由はありません。
しかし、コメントははるかに明確になる可能性があり、これもタイプミスだと思います。この時点で、それが言った方が良いでしょう: #storing 1st argument on the local stack frame
.
Label Power_loop_start その変数を使用し、一時的に保存します %eax
迅速な操作のために、次のループのためにスタックの同じ場所に戻します。
movl %eax, -4(%ebp) #store the current result
decl %ecx #decrease the power
jmp power_loop_start #run for the next power
他のヒント
多くのアセンブリオペコードは受け入れます 1 メモリオペランド(ソースまたは宛先のいずれか)。これはおそらく、記憶からメモリへの移動が%EBXを通じて行われる理由を説明しています。
として グレッグ ヒントされたX86は、ほとんどの主流のアーキテクチャと同様に、メモリからメモリへのデータをコピーする命令を持っていません[1]。したがって、個別のものを使用してデータをコピーする必要があります ロード と お店. 。最初に、ソースメモリからデータをレジスタにロードし、次にそのレジスタから宛先メモリにデータを保存します。ここで起こっているのはそれだけです。
1]私は知っている、私は知っているが、去ろう rep movs
これから、物事をシンプルに保ちます。