バッチファイルに引数を渡すにはどうすればよいですか?
https://stackoverflow.com/questions/26551
-
09-06-2019 - |
italiano
english
français
española
中国
日本の
العربية
Deutsch
한국어
Português
Russian質問
ID とパスワードをファイルにハードコーディングするのではなく、実行時にバッチ ファイルに渡す必要があります。
コマンドラインは次のようになります。
test.cmd admin P@55w0rd > test-log.txt
解決 2
私がやった方法は次のとおりです。
@fake-command /u %1 /p %2
コマンドは次のようになります。
test.cmd admin P@55w0rd > test-log.txt
の %1 最初のパラメータに適用されます %2 (そしてここが難しい部分です) は 2 番目に当てはまります。この方法では、最大 9 個のパラメータを渡すことができます。
他のヒント
もう 1 つの便利なヒントは、次のとおりです。 %* 「すべて」という意味。例えば：
echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*
実行時:
test-command admin password foo bar
上記のバッチ ファイルが実行されます。
fake-command /u admin /p password admin password foo bar
構文が少し間違っているかもしれませんが、これが一般的な考え方です。
不足しているパラメータをインテリジェントに処理したい場合は、次のようなことができます。
IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1
:No1
ECHO No param 1
GOTO End1
:No2
ECHO No param 2
GOTO End1
:End1
%1、%2、... を使用すると、バッチ パラメータに簡単にアクセスできます。%9 または %*、
ただし内容が簡単な場合に限ります。
次のような複雑なコンテンツを簡単に処理する方法はありません。 "&"^&, エラーが発生せずに %1 にアクセスすることは不可能であるためです。
set var=%1
set "var=%1"
set var=%~1
set "var=%~1"
行は次のように展開されます
set var="&"&
set "var="&"&"
set var="&"&
set "var="&"&"
そして、各行は次のいずれかとして失敗します。 & は引用符の範囲外です。
一時ファイルから読み込むことで解決できます と述べた パラメータのバージョン。
@echo off
SETLOCAL DisableDelayedExpansion
SETLOCAL
for %%a in (1) do (
set "prompt="
echo on
for %%b in (1) do rem * #%1#
@echo off
) > param.txt
ENDLOCAL
for /F "delims=" %%L in (param.txt) do (
set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'
秘訣は有効にすることです echo on の後の %1 を展開します。 rem ステートメント (次のステートメントでも機能します) %2 .. %*).
そうであっても "&"& 指摘されているように、エラーを生成せずにエコーできます。
ただし、の出力をリダイレクトできるようにするには、 echo on, 、2 つの for ループが必要です。
追加の文字 * # のようなコンテンツに対して安全であるために使用されます。 /? (ヘルプを表示します REM).
または、行末のキャレット ^ は、 rem.
それから、 レムパラメータ ファイルからの出力は慎重に行ってください。
for /fは、遅延拡張オフ、その他のコンテンツ「！」で動作するはずです。破壊されます。
余分な文字を削除した後、 param1, 、 了解しました。
そして使用するには param1 安全な方法で、遅延拡張を有効にします。
はい、次のような変数を使用することを忘れないでください。 %%1 使用するとき if そして for そしてギャング。
ダブルを忘れたら %, その場合、コマンド ライン引数 (null の可能性があります) を代入することになり、かなりわかりにくいエラー メッセージが表示されます。
複雑にする必要はありません。これは単なるコマンド %1 %2 パラメータです。たとえば、
@echo off
xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z
echo copied %1 to %2
pause
「一時停止」では、バッチ ファイルが実行した内容が表示され、ANY キーが押されるのを待ちます。それを Windows フォルダーに xx.bat という名前で保存します。
これを使用するには、たとえば次のように入力します。
xx c:\f\30\*.* f:\sites\30
このバッチ ファイルは、新しいファイルのみをコピーするなど、必要なパラメータをすべて処理します。Windows以前から使ってます。コピー中のファイルの名前を確認したい場合は、 Q パラメータ。
@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue
注記：もし "%1"=="" 問題が発生する場合 %1 自体は引用符で囲まれています。
その場合には、 IF [%1]==[] または、NT 4 (SP6) 以降のみ、 IF "%~1"=="" その代わり。
最近、友人がこの件について質問してきたので、バッチ ファイルでコマンド ライン引数を処理する方法を投稿しようと思いました。
ご覧のとおり、この手法には多少のオーバーヘッドがありますが、バッチ ファイルが非常に理解しやすく、迅速に実装できるようになります。次の構造もサポートしています。
>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]
その要点は、 :init, :parse, 、 そして :main 機能。
使用例
>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
USAGE:
test.bat [flags] "required argument" "optional argument"
/?, --help shows this help
/v, --version shows the version
/e, --verbose shows detailed output
-f, --flag value specifies a named parameter value
>template.bat <- throws missing argument error
(same as /?, plus..)
**** ****
**** MISSING "REQUIRED ARGUMENT" ****
**** ****
>template.bat -v
1.23
>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument: "arg1"
UnNamedOptionalArg: not provided
NamedFlag: not provided
>template.bat --flag "my flag" arg1 arg2
UnNamedArgument: "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag: "my flag"
>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument: "argument #1"
UnNamedOptionalArg: "second"
NamedFlag: "my flag"
テンプレート.bat
@::!/dos/rocks
@echo off
goto :init
:header
echo %__NAME% v%__VERSION%
echo This is a sample batch file template,
echo providing command-line arguments and flags.
echo.
goto :eof
:usage
echo USAGE:
echo %__BAT_NAME% [flags] "required argument" "optional argument"
echo.
echo. /?, --help shows this help
echo. /v, --version shows the version
echo. /e, --verbose shows detailed output
echo. -f, --flag value specifies a named parameter value
goto :eof
:version
if "%~1"=="full" call :header & goto :eof
echo %__VERSION%
goto :eof
:missing_argument
call :header
call :usage
echo.
echo **** ****
echo **** MISSING "REQUIRED ARGUMENT" ****
echo **** ****
echo.
goto :eof
:init
set "__NAME=%~n0"
set "__VERSION=1.23"
set "__YEAR=2017"
set "__BAT_FILE=%~0"
set "__BAT_PATH=%~dp0"
set "__BAT_NAME=%~nx0"
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedOptionalArg="
set "NamedFlag="
:parse
if "%~1"=="" goto :validate
if /i "%~1"=="/?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="-?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="--help" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="/v" call :version & goto :end
if /i "%~1"=="-v" call :version & goto :end
if /i "%~1"=="--version" call :version full & goto :end
if /i "%~1"=="/e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="-e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--verbose" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--flag" set "NamedFlag=%~2" & shift & shift & goto :parse
if not defined UnNamedArgument set "UnNamedArgument=%~1" & shift & goto :parse
if not defined UnNamedOptionalArg set "UnNamedOptionalArg=%~1" & shift & goto :parse
shift
goto :parse
:validate
if not defined UnNamedArgument call :missing_argument & goto :end
:main
if defined OptVerbose (
echo **** DEBUG IS ON
)
echo UnNamedArgument: "%UnNamedArgument%"
if defined UnNamedOptionalArg echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
if not defined UnNamedOptionalArg echo UnNamedOptionalArg: not provided
if defined NamedFlag echo NamedFlag: "%NamedFlag%"
if not defined NamedFlag echo NamedFlag: not provided
:end
call :cleanup
exit /B
:cleanup
REM The cleanup function is only really necessary if you
REM are _not_ using SETLOCAL.
set "__NAME="
set "__VERSION="
set "__YEAR="
set "__BAT_FILE="
set "__BAT_PATH="
set "__BAT_NAME="
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedArgument2="
set "NamedFlag="
goto :eof
簡単にしておきましょう。
これが .cmd ファイルです。
@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%
コマンドラインからの 3 つの呼び出しを次に示します。
C:\Users\joeco>echo_3params 1abc 2 def 3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def
C:\Users\joeco>echo_3params 1abc "2 def" "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"
C:\Users\joeco>echo_3params 1abc '2 def' "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'
C:\Users\joeco>
FOR %%A IN (%*) DO (
REM Now your batch file handles %%A instead of %1
REM No need to use SHIFT anymore.
ECHO %%A
)
これは、引用符で囲まれているかどうかに関係なく、バッチ パラメーター (%*) をループし、各パラメーターをエコーします。
関数 (または外部) として呼び出すことができる、単純な read_params スクリプトを作成しました。 .bat) すべての変数を現在の環境に置きます。関数は実行されているため、元のパラメーターは変更されません。 call元のパラメータのコピーを使用して編集されます。
たとえば、次のコマンドがあるとします。
myscript.bat some -random=43 extra -greeting="hello world" fluff
myscript.bat 関数を呼び出した後に変数を使用できるようになります。
call :read_params %*
echo %random%
echo %greeting%
関数は次のとおりです。
:read_params
if not %1/==/ (
if not "%__var%"=="" (
if not "%__var:~0,1%"=="-" (
endlocal
goto read_params
)
endlocal & set %__var:~1%=%~1
) else (
setlocal & set __var=%~1
)
shift
goto read_params
)
exit /B
制限事項
- 値のない引数はロードできません。
-force. 。使用できます-force=trueしかし、値を持たないパラメータのリストを事前に知らなければ、空白の値を許可する方法は思いつきません。
変更履歴
- 2/18/2016
- 拡張を遅らせる必要がなくなりました
- を検索することで、他のコマンドライン引数でも動作するようになりました。
-パラメータの前に。
コマンドラインで設定された変数を参照するには、次のようにする必要があります。 %a% たとえば:
set a=100
echo %a%
rem output = 100
注記：これは Windows 7 pro で動作します。
新しいバッチ ファイルを作成します (例:openclass.bat) を開き、ファイルに次の行を書き込みます。
java %~n1
次に、バッチ ファイルを、たとえば system32 フォルダーに置き、Java クラス ファイルに移動し、右クリックして、[プロパティ]、[アプリケーションから開く...] の順にクリックし、バッチ ファイルを見つけて選択します。
わたしにはできる。
追伸：Java クラスを閉じるときに cmd ウィンドウを閉じる方法が見つかりません。今のところ...
に触発されて 別の場所で答えてください @Jon によって、名前付きパラメータ、オプションの値、スイッチを抽出するためのより一般的なアルゴリズムを作成しました。
ユーティリティを実装したいとします。 foobar. 。初期コマンドが必要です。オプションのパラメータがあります --foo それは オプション 値 (もちろん、別のパラメータにすることはできません);値が欠落している場合はデフォルトで default. 。オプションのパラメータもあります --bar それは 必須 価値。最後にフラグを取ることができます --baz 値は許可されません。ああ、これらのパラメータは任意の順序で指定できます。
つまり、次のようになります。
foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]
解決策は次のとおりです。
@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson
SET CMD=%~1
IF "%CMD%" == "" (
GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=
SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
SHIFT
IF NOT "%ARG%" == "" (
IF NOT "%ARG:~0,2%" == "--" (
SET FOO=%ARG%
SHIFT
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE IF "%PARAM%" == "--bar" (
SHIFT
IF NOT "%ARG%" == "" (
SET BAR=%ARG%
SHIFT
) ELSE (
ECHO Missing bar value. 1>&2
ECHO:
GOTO usage
)
) ELSE IF "%PARAM%" == "--baz" (
SHIFT
SET BAZ=true
) ELSE IF "%PARAM%" == "" (
GOTO endargs
) ELSE (
ECHO Unrecognized option %1. 1>&2
ECHO:
GOTO usage
)
GOTO args
:endargs
ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
ECHO Baz
)
REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof
:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1
- 使用
SETLOCAL変数が呼び出し環境に逃げ込まないようにします。 - 変数の初期化を忘れないでください
SET FOO=, 、など。誰かが呼び出し環境でそれらを定義した場合に備えて。 - 使用
%~1引用符を削除するには。 - 使用
IF "%ARG%" == ""そしてそうではありませんIF [%ARG%] == []なぜなら[そして]スペースで終わる値を使用して will をまったく再生しないでください。 - たとえあなたが
SHIFTの中でIFブロック、現在の引数など%~1いつ更新されるかが決定されるため、更新されません。IF解析されます。使用できます%~1そして%~2の中でIFブロックですが、SHIFT. 。を置くことができますSHIFTわかりやすくするためにブロックの最後に付けていますが、これは迷ったり、人々を混乱させたりする可能性があります。それで「捕獲」%~1そして%~1ブロックの外が最適のようです。 - 別のパラメータのオプション値の代わりにパラメータを使用したくないので、次のことを確認する必要があります。
IF NOT "%ARG:~0,2%" == "--". - それだけに注意してください
SHIFTあなたが 使用 パラメータの一つ。 - 重複したコード
SET FOO=%DEFAULT_FOO%残念ですが、別の方法として、IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%外IF NOT "%ARG%" == ""ブロック。ただし、これはまだ内部にあるため、IF "%PARAM%" == "--foo"ブロック、%FOO%値はブロックに入る前に評価され設定されているため、それを検出することはできません。 両方 の--fooパラメータが存在しました そしてまた それは%FOO%値が欠落していました。 - ご了承ください
ECHO Missing bar value. 1>&2エラーメッセージを標準エラー出力に送信します。 - Windows バッチ ファイルに空白行が必要ですか?使わなければなりません
ECHO:またはそのバリエーションの 1 つです。
簡単な解決策（質問は古いですが）
テスト1.bat
echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause
CallTest1.bat
call "C:\Temp\Test1.bat" pass123
出力
YourLocalPath>call "C:\Temp\test.bat" pass123
YourLocalPath>echo off
"Batch started"
"arg1 is pass123"
YourLocalPath>pause
Press any key to continue . . .
YourLocalPath は現在のディレクトリ パスです。
物事をシンプルにするために、コマンド パラメータを変数に保存し、比較に変数を使用します。
書くのが簡単なだけでなく、保守も簡単なので、後で他の人やあなたが長い時間をかけてスクリプトを読んだ場合でも、理解しやすく保守しやすくなります。
コードをインラインで記述するには:他の回答を参照してください。
ループを使用してすべての引数を取得し、純粋なバッチで使用するには:
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
)
goto :eof
コードは、必要な引数番号を使用して何かを実行する準備ができています。
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift
)
fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt
