SQL Server：ストアドプロシージャを使用したプロセスの強制終了

Question

プロセスを強制終了しないように見えるため、以下を変更します-ユーザーを切断することになっていると思います（これは同じですか？）。特定のデータベースのすべてのプロセスを強制終了できるようにしたい-以下を変更するにはどうすればよいですか：

create procedure [dbo].[sp_killusers](@database varchar(30))
as
----------------------------------------------------
-- * Created By David Wiseman, Updated 19/11/2006
-- * http://www.wisesoft.co.uk
-- * This procedure takes the name of a database as input
-- * and uses the kill statment to disconnect them from
-- * the database.
-- * PLEASE USE WITH CAUTION!!
-- * Usage:
-- * exec sp_killusers 'databasename'
----------------------------------------------------
set nocount on
declare @spid int
declare @killstatement nvarchar(10)

-- Declare a cursor to select the users connected to the specified database
declare c1 cursor for select request_session_id
                                from sys.dm_tran_locks
                                    where resource_type='DATABASE'
                                    AND DB_NAME(resource_database_id) = @database
open c1
fetch next from c1 into @spid
-- for each spid...
while @@FETCH_STATUS = 0
begin
      -- Don't kill the connection of the user executing this statement
      IF @@SPID <> @spid
      begin
            -- Construct dynamic sql to kill spid
            set @killstatement = 'KILL ' + cast(@spid as varchar(3))
            exec sp_executesql @killstatement
            -- Print killed spid
            print @spid
      end
      fetch next from c1 into @spid
end
-- Clean up
close c1
deallocate c1

更新

上記は機能しません。つまり、プロセスを強制終了しません。

  

プロセスは強制終了されません。私は見ます   アクティビティモニターとその静止   プロセスが継続していることを示しています。   私のクエリが   クエリウィンドウ。 「キル53」を行うと、   クエリウィンドウでクエリを停止し、   プロセスはアクティビティから削除されました   モニター！殺すのはうまくいくが、この手順ではないのはなぜか？

Answer 1

このスクリプトには精通しています。はい、データベースを使用しているすべてのSPIDを強制終了します。正しい権限で実行する必要があります-すべてのユーザーがSPIDを強制終了できるわけではありません。

また、DBへの永続的な接続を試行および維持しようとするアプリケーションが存在する可能性があるため、SPIDを強制終了するとすぐに再接続する可能性があります。

Answer 2

特定のDBのすべてのアクティビティを停止して、メンテナンスを行えるようにしているだけですか？

もしそうなら、次のことができます：

ALTER DATABASE myDB SET SINGLE_USER WITH ROLLBACK IMMEDIATE;

これにより、DBにアクセスする他のすべてのSPIDが強制終了され、DBがシングルユーザーモードになります。その後、メンテナンスアクションを実行し、その後次の操作を実行します。

ALTER DATABASE myDB SET MULTI_USER;

Answer 3

sp_execの代わりにexecを使用してみることをお勧めします（違いが生じるわけではありません）

SET @killstatement = 'KILL ' + cast(@spid as varchar(3)) 
EXEC (@killstatement)

Answer 4

プロシージャの実行時に実際に発生する内容のデバッグ/出力を試みましたか？たとえば、@ killstatementを変更してnvarchar（max）として宣言し、次のような詳細な出力を含めて結果を投稿できますか？基本的に、begin / endブロック内のすべてを次のように置き換えます。

-- Construct dynamic sql to kill spid
select  @killstatement = N'
            select  *
            from    sys.dm_exec_sessions s
            join    sys.dm_exec_connections c
            on      s.session_id = c.session_id
            where   c.session_id = @spid;

            kill ' + cast(@spid as varchar(3)) + ';

            select  *
            from    sys.dm_exec_sessions s
            join    sys.dm_exec_connections c
            on      s.session_id = c.session_id
            where   c.session_id = @spid;           
        ';
-- Print & Exec
print @killstatement;
exec sp_executesql @killstatement, N'@spid smallint', @spid;
print @spid;

適切な権限を持っていると仮定し、有効なspidを削除するなど、プロシージャコード内で何かが異なる動作をする理由はありません-デバッグの結果を投稿できる場合上記（およびあなたが試したかもしれない他の何か）、それは問題がどこにあるかを理解するのを助けるでしょう。また、使用しているカーソル宣言の結果のデバッグ出力を含めて、強制終了しようとしているセッションを実際に取得していることを確認することもできます。次のような結果セット：

declare c1 cursor for select request_session_id
                                from sys.dm_tran_locks
                                    where resource_type='DATABASE'
                                    AND DB_NAME(resource_database_id) = @database

-- Debug output - sessions we should try and kill...
select  request_session_id
from    sys.dm_tran_locks
where   resource_type='DATABASE'
AND     DB_NAME(resource_database_id) = @database;

結果を投稿できれば、うまくいけば先に進むことができます。

Answer 5

これらのどれも当てはまらないのは良いことですが、念のために、ここ数年前にこのようなものを扱うときに遭遇した奇妙な状況があります（すべてSQL 2005）。

• 自分の接続を強制終了することはできません。
• 使用したコードでは、51歳未満のspidを決して決して試したり、殺したりしませんでした（これらはシステム接続です。試してください。）
• 接続がトランザクションを処理している場合、強制終了する前にそのトランザクションをロールバックする必要があります。巨大なトランザクションは、ロールバックにかなりの時間がかかる場合があります。
• 接続プーリングに注意してください。彼らはアンデッドのようなものです-彼らを殺してください、そして彼らはすぐに戻ってきます、しばしば1秒未満で。

このプロセスの実行中にSQLプロファイラーを実行し、ログインとログアウトを追跡すると、特に接続プーリングの問題が明らかになる場合があります。

Answer 6

これはSQLServer 2000で動作します

DECLARE @DbName VARCHAR(100)
DECLARE @SPID INT
DECLARE @TranUOW UNIQUEIDENTIFIER
DECLARE @KillStmt NVARCHAR(100)

SET @DbName = 'MyDatabase'

-----------------------------------
-- Kill distributed transactions

DECLARE dist CURSOR FOR
    SELECT DISTINCT req_transactionUOW
        FROM master..syslockinfo
        WHERE db_name(rsc_dbid) = @DbName
              AND req_transactionUOW <> '00000000-0000-0000-0000-000000000000'

OPEN dist

FETCH NEXT FROM dist INTO @TranUOW

WHILE @@FETCH_STATUS = 0
BEGIN
    SET @KillStmt = 'kill ''' + CAST(@TranUOW AS VARCHAR(50)) + ''''

    PRINT @KillStmt
    EXECUTE(@KillStmt)

    FETCH NEXT FROM dist INTO @TranUOW
END

CLOSE dist
DEALLOCATE dist

-----------------------------------
-- Kill user connections

DECLARE cur CURSOR FOR
    SELECT spid
        FROM master..sysprocesses
        WHERE db_name(dbid) = @DbName
              AND spid > 50

OPEN cur

FETCH NEXT FROM cur INTO @SPID

WHILE @@FETCH_STATUS = 0
BEGIN
    SET @KillStmt = 'kill ' + CAST(@SPID AS VARCHAR(10))

    PRINT @KillStmt
    EXECUTE(@KillStmt)

    FETCH NEXT FROM cur INTO @SPID
END

CLOSE cur
DEALLOCATE cur