순수한 기능적 ML에서 N- 차원 산책을하고 있습니까?

Question

아이디어는 여러 차원을 넘어서는 것입니다. 각 차원은 범위로 정의되었습니다.

(* lower_bound, upper_bound, number_of_steps *)
type range = real * real * int

기능이 있습니다 fun foo y x 또는 fun foo z y x 전체 정사각형 x에 적용될 수 있습니다y 또는 큐브 xy*z.

SML/NJ는 아래 구현이 마음에 들지 않습니다.

test2.sml:7.5-22.6 Error: right-hand-side of clause doesn't agree with function result type [circularity]
  expression:  (real -> 'Z) -> unit
  result type:  'Z -> 'Y
  in declaration:
    walk = (fn arg => (fn <pat> => <exp>))

코드는 다음과 같습니다.

fun walk []      _ = ()
  | walk (r::rs) f =
  let
    val (k0, k1, n) = r
    val delta = k1 - k0
    val step = delta / real n

    fun loop 0 _ = ()
      | loop i k = 
        let in
          walk rs (f k) ;          (* Note (f k) "eats" the first argument.
                                      I guess SML doesn't like having the
                                      type of walk change in the middle of its
                                      definition *)
          loop (i - 1) (k + step)
        end
  in
    loop n k0
  end

fun do2D y x = (* ... *) ()
fun do3D z y x = (* ... *) ()

val x_axis = (0.0, 1.0, 10)
val y_axis = (0.0, 1.0, 10)
val z_axis = (0.0, 1.0, 10)

val _ = walk [y_axis, x_axis] do2D
val _ = walk [z_axis, y_axis, x_axis] do3D

이런 종류의 구성이 가능합니까?

모든 포인터가 환영했습니다.

Answer 1

~이다 walk ML 유형 시스템에서 표현할 수 있습니까?

val walk : range list -> (real -> real -> unit) -> unit
val walk : range list -> (real -> real -> real -> unit) -> unit

ML의 두 유형 모두에서 동일한 값이있을 수 없습니다.

---

그러나 원하는 각 유형에 대한 값을 쉽게 생성 할 수 있습니다.

type range = real * real * int

signature WALK =
  sig
    type apply
    val walk : range list -> apply -> unit
  end

structure Walk0 : WALK =
  struct
    type apply = unit
    fun walk _ _ = ()
  end

functor WALKF (Walk : WALK) : WALK =
  struct
    type apply = real -> Walk.apply
    fun walk ((low, high, steps)::rs) f =
          let fun loop i =
                if i > steps then () else
                  let val x = low + (high - low) * real i / real steps
                  in (Walk.walk rs (f x); loop (i + 1)) end
          in loop 0 end
  end

struture Walk1 = WALKF(Walk0)
struture Walk2 = WALKF(Walk1)
struture Walk3 = WALKF(Walk2)

이를 통해 다음 값은 원하는 유형으로 존재합니다.

val Walk0.walk : range list -> unit -> unit
val Walk1.walk : range list -> (real -> unit) -> unit
val Walk2.walk : range list -> (real -> real -> unit) -> unit
val Walk3.walk : range list -> (real -> real -> real -> unit) -> unit

그런 다음 글을 쓸 필요가 있습니다

val _ = Walk2.walk [y_axis, x_axis] do2D
val _ = Walk3.walk [z_axis, y_axis, x_axis] do3D

---

동일하게 사용합니다 walk 모든 차원의 경우 모든 차원에 대해 동일한 유형을 사용해야합니다.

fun walk nil f = f nil
  | walk ((low, high, steps)::rs) f =
      let fun loop i =
            if i > steps then () else
              let val x = low + (high - low) * real i / real steps
              in (walk rs (fn xs -> f (x::xs)); loop (i + 1)) end
      in loop 0 end

유형이 변경되기 때문에

val walk : range list -> (real list -> unit) -> unit

사용량도 변경해야합니다

fun do2D [y,x] = (* ... *) ()
fun do3D [z,y,x] = (* ... *) ()

Answer 2

fun walk lst f = let
  fun aux rev_prefix [] = f (rev rev_prefix)
    | aux rev_prefix (r::rs) = let
        val (k0, k1, n) = r
        val delta = k1 - k0
        val step = delta / real n

        fun loop 0 _ = ()
          | loop i k = (
              aux (k+step :: rev_prefix) rs;
              loop (i - 1) (k + step)
            )
      in
        loop n k0
      end
in
  aux [] lst
end

fun do2D [x,y] = print (Real.toString x ^ "\t" ^
                        Real.toString y ^ "\n")
fun do3D [x,y,z] = print (Real.toString x ^ "\t" ^
                          Real.toString y ^ "\t" ^
                          Real.toString z ^ "\n")

val x_axis = (0.0, 1.0, 10)
val y_axis = (0.0, 1.0, 10)
val z_axis = (0.0, 1.0, 10)

val () = walk [y_axis, x_axis] do2D
val () = walk [z_axis, y_axis, x_axis] do3D

Answer 3

이것을 찾았습니다 가변 수의 인수에 대한 구현. 그것이 적용되는지 확실하지 않지만 상당히 추악 해 보입니다.