Delphi에서 Levenshtein 거리를 어떻게 구현합니까?

Question

여러분의 질문에 답하고자 이 글을 게시합니다.

내가 가졌던 질문은 다음과 같습니다.두 문자열 사이의 편집 거리를 계산하기 위해 Levenshtein 알고리즘을 어떻게 구현할 수 있습니까? 여기에 설명되어 있습니다, 델파이에서?

성능에 대한 참고 사항:이 일은 매우 빠릅니다.내 데스크탑(2.33Ghz 듀얼 코어, 2GB RAM, WinXP)에서는 1초 이내에 100K 문자열 배열을 실행할 수 있습니다.

Answer 1

function EditDistance(s, t: string): integer;
var
  d : array of array of integer;
  i,j,cost : integer;
begin
  {
  Compute the edit-distance between two strings.
  Algorithm and description may be found at either of these two links:
  http://en.wikipedia.org/wiki/Levenshtein_distance
  http://www.google.com/search?q=Levenshtein+distance
  }

  //initialize our cost array
  SetLength(d,Length(s)+1);
  for i := Low(d) to High(d) do begin
    SetLength(d[i],Length(t)+1);
  end;

  for i := Low(d) to High(d) do begin
    d[i,0] := i;
    for j := Low(d[i]) to High(d[i]) do begin
      d[0,j] := j;
    end;
  end;

  //store our costs in a 2-d grid  
  for i := Low(d)+1 to High(d) do begin
    for j := Low(d[i])+1 to High(d[i]) do begin
      if s[i] = t[j] then begin
        cost := 0;
      end
      else begin
        cost := 1;
      end;

      //to use "Min", add "Math" to your uses clause!
      d[i,j] := Min(Min(
                 d[i-1,j]+1,      //deletion
                 d[i,j-1]+1),     //insertion
                 d[i-1,j-1]+cost  //substitution
                 );
    end;  //for j
  end;  //for i

  //now that we've stored the costs, return the final one
  Result := d[Length(s),Length(t)];

  //dynamic arrays are reference counted.
  //no need to deallocate them
end;