Por que esse mapa declaração em Perl não compilar?
Pergunta
Esta falha:
my @a = ("a", "b", "c", "d", "e");
my %h = map { "prefix-$_" => 1 } @a;
com este erro:
Not enough arguments for map at foo.pl line 4, near "} @a"
mas isso funciona:
my @a = ("a", "b", "c", "d", "e");
my %h = map { "prefix-" . $_ => 1 } @a;
Por quê?
Solução
Como Perl é supondo uma EXPR (uma referência de hash, por exemplo) em vez de um bloco. Isso deve funcionar (observe o símbolo '+'):
my @a = ("a", "b", "c", "d", "e");
my %h = map { +"prefix-$_" => 1 } @a;
Outras dicas
Eu prefiro escrever que, como
my %h = map { ("prefix-$_" => 1) } @a;
para mostrar a intenção, que eu estou retornando uma lista de 2 elementos.
De perldoc -f map
:
"{" starts both hash references and blocks, so "map { ..."
could be either the start of map BLOCK LIST or map EXPR, LIST.
Because perl doesn’t look ahead for the closing "}" it has to
take a guess at which its dealing with based what it finds just
after the "{". Usually it gets it right, but if it doesn’t it
won’t realize something is wrong until it gets to the "}" and
encounters the missing (or unexpected) comma. The syntax error
will be reported close to the "}" but you’ll need to change
something near the "{" such as using a unary "+" to give perl
some help:
%hash = map { "\L$_", 1 } @array # perl guesses EXPR. wrong
%hash = map { +"\L$_", 1 } @array # perl guesses BLOCK. right
%hash = map { ("\L$_", 1) } @array # this also works
%hash = map { lc($_), 1 } @array # as does this.
%hash = map +( lc($_), 1 ), @array # this is EXPR and works!
%hash = map ( lc($_), 1 ), @array # evaluates to (1, @array)
or to force an anon hash constructor use "+{"
@hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
and you get list of anonymous hashes each with only 1 entry.
Além disso, a outra maneira de fazer o que está fazendo, inicializar o hash, você pode fazer assim:
my @a = qw( a b c d e );
my %h;
@h{@a} = ();
Isso vai criar entradas undef para cada uma das cinco chaves. Se você quer dar-lhes todos os valores verdadeiros, então fazer isso.
@h{@a} = (1) x @a;
Você também pode fazê-lo explicitamente com um laço;
@h{$_} = 1 for @a;
Eu acho que
map { ; "prefix-$_" => 1 } @a;
é mais idiomática, na medida em que especifica que é um bloco de instruções e não um hash ref. Você está apenas chutando-a com uma declaração nulo.