Construir um menu multi-nível para umbraco
Pergunta
Eu estou tentando construir um menu CSS dropdrown multi-nível para um site que estou escrevendo sobre o sistema de gerenciamento de conteúdo umbraco.
Eu preciso construí-lo a ter a seguinte estrutura:
<ul id="nav">
<li><a href="..">Page #1</a></li>
<li>
<a href="..">Page #2</a>
<ul>
<li><a href="..">Subpage #1</a></li>
<li><a href="..">Subpage #2</a></li>
</ul>
</li>
</ul>
Então agora eu estou tentando descobrir como fazer o aninhamento usando XSLT. Isto é o que eu tenho até agora:
<xsl:output method="xml" omit-xml-declaration="yes"/>
<xsl:param name="currentPage"/>
<!-- update this variable on how deep your menu should be -->
<xsl:variable name="maxLevelForMenu" select="4"/>
<xsl:template match="/">
<ul id="nav">
<xsl:call-template name="drawNodes">
<xsl:with-param
name="parent"
select="$currentPage/ancestor-or-self::node [@level=1]"
/>
</xsl:call-template>
</ul>
</xsl:template>
<xsl:template name="drawNodes">
<xsl:param name="parent"/>
<xsl:if test="umbraco.library:IsProtected($parent/@id, $parent/@path) = 0 or (umbraco.library:IsProtected($parent/@id, $parent/@path) = 1 and umbraco.library:IsLoggedOn() = 1)">
<xsl:for-each select="$parent/node [string(./data [@alias='umbracoNaviHide']) != '1' and @level <= $maxLevelForMenu]">
<li>
<a href="{umbraco.library:NiceUrl(@id)}">
<xsl:value-of select="@nodeName"/>
</a>
<xsl:if test="count(./node [string(./data [@alias='umbracoNaviHide']) != '1' and @level <= $maxLevelForMenu]) > 0">
<xsl:call-template name="drawNodes">
<xsl:with-param name="parent" select="."/>
</xsl:call-template>
</xsl:if>
</li>
</xsl:for-each>
</xsl:if>
</xsl:template>
O que eu não consigo entender é como verificar se o primeiro nível (aqui Página # 1 e Página # 2) tem filhos, e se eles fazem adicionar o <ul>
extra para conter as crianças <li>
.
Qualquer um lá fora para me apontar na direção certa?
Solução
Em primeiro lugar, não há necessidade passar o parâmetro um parent
redor. O contexto vai transportar esta informação.
Aqui é a folha de estilo XSL que deve resolver o seu problema:
<!-- update this variable on how deep your menu should be -->
<xsl:variable name="maxLevelForMenu" select="4"/>
<!--- match the document root --->
<xsl:template match="/root">
<div id="nav">
<xsl:call-template name="SubTree" />
</div>
</xsl:template>
<!-- this will be called by xsl:apply-templates -->
<xsl:template match="node">
<!-- the node is either protected, or the user is logged on (no need to check for IsProtected twice) -->
<xsl:if test="umbraco.library:IsProtected($parent/@id, $parent/@path) = 0 or umbraco.library:IsLoggedOn() = 1">
<li>
<a href="{umbraco.library:NiceUrl(@id)}"><xsl:value-of select="@nodeName"/></a>
<xsl:call-template name="SubTree" />
</li>
</xsl:if>
</xsl:template>
<xsl:template name="SubTree">
<!-- render sub-tree only if there are any child nodes --->
<xsl:if test="node">
<ul>
<xsl:apply-templates select="node[data[@alias='umbracoNaviHide'] != '1'][@level <= $maxLevelForMenu]">
<!-- ensure sorted output of the child nodes --->
<xsl:sort select="@sortOrder" data-type="number" />
</xsl:apply-templates>
</ul>
</xsl:if>
</xsl:template>
Este é o XML que eu testei no (Eu não sei muito sobre Umbraco, mas depois de olhar para algumas amostras eu espero que eu tenho perto de um documento Umbraco):
<root id="-1">
<node id="1" level="1" sortOrder="1" nodeName="Page #1">
<data alias="umbracoNaviHide">0</data>
</node>
<node id="2" level="1" sortOrder="2" nodeName="Page #2">
<data alias="umbracoNaviHide">0</data>
<node id="3" level="2" sortOrder="2" nodeName="Subpage #2.2">
<data alias="umbracoNaviHide">0</data>
</node>
<node id="4" level="2" sortOrder="1" nodeName="Subpage #2.1">
<data alias="umbracoNaviHide">0</data>
<node id="5" level="3" sortOrder="3" nodeName="Subpage #2.1.1">
<data alias="umbracoNaviHide">0</data>
</node>
</node>
<node id="6" level="2" sortOrder="3" nodeName="Subpage #2.3">
<data alias="umbracoNaviHide">1</data>
</node>
</node>
<node id="7" level="1" sortOrder="3" nodeName="Page #3">
<data alias="umbracoNaviHide">1</data>
</node>
</root>
Esta é a saída:
<div id="nav">
<ul>
<li><a href="http://foo/">Page #1</a></li>
<li><a href="http://foo/">Page #2</a>
<ul>
<li><a href="http://foo/">Subpage #2.1</a>
<ul>
<li><a href="http://foo/">Subpage #2.1.1</a></li>
</ul>
</li>
<li><a href="http://foo/">Subpage #2.2</a></li>
</ul>
</li>
</ul>
</div>
Outras dicas
Não há nada de muito especial sobre este problema. Os seguintes testes de soluções que a lista de nó para
<xsl:apply-templates/>
não estiver vazia, antes de aplicar os modelos:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> <xsl:output omit-xml-declaration="yes"/> <xsl:variable name="vLevel" select="0"/> <xsl:template match="root"> <xsl:variable name="vnextLevelNodes" select="node[@level = $vLevel+1]"/> <xsl:if test="$vnextLevelNodes"> <ul> <xsl:apply-templates select="$vnextLevelNodes"/> </ul> </xsl:if> </xsl:template> <xsl:template match="node"> <!-- the node is either protected, or the user is logged on (no need to check for IsProtected twice) --> <!-- <xsl:if test= "umbraco.library:IsProtected($parent/@id, $parent/@path) = 0 or umbraco.library:IsLoggedOn() = 1"> --> <xsl:if test="1"> <li> <!-- <a href="{umbraco.library:NiceUrl(@id)}"> --> <a href="'umbraco.library:NiceUrl(@id)'"> <xsl:value-of select="@nodeName"/> </a> <xsl:variable name="vnextLevelNodes" select="node[@level = current()/@level+1]"/> <xsl:if test="$vnextLevelNodes"> <ul> <xsl:apply-templates select="$vnextLevelNodes"/> </ul> </xsl:if> </li> </xsl:if> </xsl:template> </xsl:stylesheet>
Eu tenho usado o seguinte documento de origem XML:
<root id="-1"> <node id="1" level="1" sortOrder="1" nodeName="Page #1"> <data alias="umbracoNaviHide">0</data> </node> <node id="2" level="1" sortOrder="2" nodeName="Page #2"> <data alias="umbracoNaviHide">0</data> <node id="3" level="2" sortOrder="2" nodeName="Subpage #2.2"> <data alias="umbracoNaviHide">0</data> </node> <node id="4" level="2" sortOrder="1" nodeName="Subpage #2.1"> <data alias="umbracoNaviHide">0</data> <node id="5" level="3" sortOrder="3" nodeName="Subpage #2.1.1"> <data alias="umbracoNaviHide">0</data> </node> </node> <node id="6" level="2" sortOrder="3" nodeName="Subpage #2.3"> <data alias="umbracoNaviHide">1</data> </node> </node> <node id="7" level="1" sortOrder="3" nodeName="Page #3"> <data alias="umbracoNaviHide">1</data> </node> </root>
Além disso, tenho comentado qualquer código referenciando funções de extensão umbraco, como eu não tenho acesso a eles.
Quando a transformação acima é aplicado sobre este documento XML de origem, o resultado correto, queria é produzido:
<ul> <li> <a href="'umbraco.library:NiceUrl(@id)'">Page #1</a> </li> <li> <a href="'umbraco.library:NiceUrl(@id)'">Page #2</a> <ul> <li> <a href="'umbraco.library:NiceUrl(@id)'">Subpage #2.2</a> </li> <li> <a href="'umbraco.library:NiceUrl(@id)'">Subpage #2.1</a> <ul> <li> <a href="'umbraco.library:NiceUrl(@id)'">Subpage #2.1.1</a> </li> </ul> </li> <li> <a href="'umbraco.library:NiceUrl(@id)'">Subpage #2.3</a> </li> </ul> </li> <li> <a href="'umbraco.library:NiceUrl(@id)'">Page #3</a> </li> </ul>
Espero que isso ajudou.
Cheers,
Dimitre Novatchev