O que há de errado com este exemplo de gramática Python ANTLR 3?
Pergunta
Estou tentando aprender a usar o ANTLR e parece que encontrei um erro ao seguir este "tutorial":https://theantlrguy.atlassian.net/wiki/display/ANTLR3/Five+minuto+introdução+to+ANTLR+3
Essencialmente, eu crio o arquivo SimpleCalc.g:
grammar SimpleCalc;
options {
language = Python;
}
tokens {
PLUS = '+' ;
MINUS = '-' ;
MULT = '*' ;
DIV = '/' ;
}
@header {
import sys
import traceback
from SimpleCalcLexer import SimpleCalcLexer
}
@main {
def main(argv, otherArg=None):
char_stream = ANTLRFileStream(sys.argv[1])
lexer = SimpleCalcLexer(char_stream)
tokens = CommonTokenStream(lexer)
parser = SimpleCalcParser(tokens);
try:
parser.expr()
except RecognitionException:
traceback.print_stack()
}
/*------------------------------------------------------------------
* PARSER RULES
*------------------------------------------------------------------*/
expr : term ( ( PLUS | MINUS ) term )* ;
term : factor ( ( MULT | DIV ) factor )* ;
factor : NUMBER ;
/*------------------------------------------------------------------
* LEXER RULES
*------------------------------------------------------------------*/
NUMBER : (DIGIT)+ ;
WHITESPACE : ( '\t' | ' ' | '\r' | '\n'| '\u000C' )+ { $channel = HIDDEN; } ;
fragment DIGIT : '0'..'9' ;
Quando executo as ferramentas ANTLR
java -classpath antlr-3.1.3.jar antlr.Tool SimpleCalc.g
Recebo erros, começando pela primeira linha:
ANTLR Parser Generator Version 2.7.7 (20060906) 1989-2005
SimpleCalc.g:2:1: unexpected token: grammar
error: Token stream error reading grammar(s):
SimpleCalc.g:15:1: unexpected char: '@'
SimpleCalc.g:2:1: rule grammar trapped:
SimpleCalc.g:2:1: unexpected token: grammar
TokenStreamException: unexpected char: '@'
Isso me leva a acreditar que estou fazendo algo estúpido, mas não tenho certeza do quê.
Solução
Você está usando o errado Tool
classe para gerar o lexer e o analisador.A maioria das versões ANTLR 3.x ainda possui dependências com a versão mais antiga v2.7, que está incluída na v3.x.O Tool
classe da v2.7 é chamada antlr.Tool
, enquanto a versão v3.x é chamada org.antlr.Tool
.Este último é o que você deve usar:
java -classpath antlr-3.1.3.jar org.antlr.Tool SimpleCalc.g
EDITAR
Aqui está uma pequena demonstração baseada na gramática do Wiki, mas com um pouco de código Python adicionado para avaliar a expressão:
grammar SimpleCalc;
options {
language=Python;
}
@header {
import sys
import traceback
from SimpleCalcLexer import SimpleCalcLexer
}
@main {
def main(argv, otherArg=None):
char_stream = ANTLRStringStream(sys.argv[1])
lexer = SimpleCalcLexer(char_stream)
tokens = CommonTokenStream(lexer)
parser = SimpleCalcParser(tokens);
try:
print parser.eval()
except RecognitionException:
traceback.print_stack()
}
eval returns [value]
: add EOF {$value = $add.value}
;
add returns [value]
: m1=mult {$value = $m1.value} ( '+' m2=mult {$value += $m2.value}
| '-' m2=mult {$value -= $m2.value}
)*
;
mult returns [value]
: a1=atom {$value = $a1.value} ( '*' a2=atom {$value *= $a2.value}
| '/' a2=atom {$value /= $a2.value}
)*
;
atom returns [value]
: NUMBER {$value = float($NUMBER.text)}
| '(' add ')' {$value = $add.value}
;
NUMBER : DIGIT+ ('.' DIGIT*)?;
WHITESPACE : ('\t' | ' ' | '\r' | '\n')+ {$channel = HIDDEN;};
fragment DIGIT : '0'..'9' ;
Gerando um lexer/analisador e avaliando uma expressão:
java -cp antlr-3.1.3.jar org.antlr.Tool SimpleCalc.g
python SimpleCalcParser.py "5 * (8 + 2)"
produz a saída:
50.0