Como definir vários emacs rostos?

Question

Eu estou tentando definir alguns emacs fonte rostos para fazer alguns personalizado destacando.Isso parece funcionar quando eu defini-los individualmente:

(defface my-r-face `((t (:foreground "red")))  "Red highlight")
(defvar m-r-face 'my-r-face "Red.")
(defface my-g-face `((t (:foreground "green")))  "Green highlight")
(defvar m-g-face 'my-g-face "Green.")
(defface my-b-face `((t (:foreground "#0088ff")))  "Blue highlight")
(defvar m-b-face 'my-b-face "Blue.")
....etc

No entanto, tenho algumas dezenas desses e eu quero defini-los todos de uma só vez a partir de algum tipo de tabela de cores:

(setq ctable '(("red" "r")
           ("orange" "o")
           ("yellow" "y")
           ("#88ff00" "gy")
           ("green" "g")
           ("#00ff88" "gc")
           ("cyan" "c")
           ("#0088ff" "bc")
           ("blue" "b")
           ("purple" "bm")
           ("magenta" "m")
           ("#ff0088" "rm")
           ("grey" "lg")
           ("white" "w") ))

A minha dificuldade é com a montagem os nomes de símbolo para cada face, ou seja, a concatenação de "meu" e "face", em ambos os lados de uma entrada da tabela.Eu descobri (interno) que pode fazer um novo símbolo a partir de uma seqüência de caracteres, no entanto, este símbolo é, então, não aceitável (defface), como parece que eu estou fazendo é equivalente a (defface 'meu-r-cara ..., e defface não gosta do citado símbolo, e espera (defface meu-r-cara ..em vez disso.A minha tentativa é como segue:

(dolist (tpl ctable)
  (defvar (intern (concat "my-" (nth 1 tpl) "-face"))
    (quote (intern (concat "my-" (nth 1 tpl) "-face"))) "colour")
  (defface (intern (concat "my-" (nth 1 tpl) "-face"))
    `((t (:foreground ,(car tpl)))) "Highlight" :group 'fortran)
)

Executando isso resulta em

Lisp error: (wrong-type-argument symbolp (intern (concat "fegs-" (nth 1 tpl) "-face")))
  (defvar (intern (concat "fegs-" ... "-face")) (quote (intern ...)) "colour")

Alguém pode lançar alguma luz sobre o que eu estou fazendo de errado, ou se eu estou latindo até a árvore errada inteiramente e não há uma maneira melhor de fazer isso?

Obrigado.

Answer 1

defvar é uma forma especial, defface é uma macro (portanto, argumentos são passados trabalho).Já tentou usar algo na linha de

(eval `(defface ,(intern "foo") '((t (:foreground "red"))) "Highlight" :group 'fortran))

(eval `(defvar ,(intern "bar")))

Answer 2

Você pode evitar eval:

(defconst my-ctable '(...))

(defmacro my-init-cfaces ()
  `(progn
    ,@(mapcar (lambda (tpl)
               `(defface ,(intern (format "my-%s-face" (nth 1 tpl)))
                  '((t :foreground ,(car tpl)))
                  ,(format "Face for color %s." (car tpl))
                  :group 'fortran))
              my-ctable)))

(my-init-cfaces)

Answer 3

O código completo que trabalhou no final é o seguinte:

(setq ctable '(("red" "r")
           ("orange" "o")
           ("yellow" "y")
           ("#88ff00" "gy")
           ("green" "g")
           ("#00ff88" "gc")
           ("cyan" "c")
           ("#0088ff" "bc")
           ("blue" "b")
           ("purple" "bm")
           ("magenta" "m")
           ("#ff0088" "rm")
           ("grey" "lg")
           ("white" "w") ))

(dolist (tpl ctable)
  (let ((fname (concat "fegs-" (nth 1 tpl) "-face")))
    (eval `(defface ,(intern fname) '((t (:foreground ,(car tpl)))) "Highlight" :group 'fortran))
    (eval `(defvar ,(intern fname) ',(intern fname)))
  )
)

Meu defvar linha é um pouco diferente, pois ela permite que a face a ser captado pelo código de realce de outro modo, como uma variável global.