Elimine todas as tabelas cujos nomes comecem com uma determinada string
-
08-06-2019 - |
Pergunta
Gostaria que um script eliminasse todas as tabelas cujo nome começa com uma determinada string.Tenho certeza que isso pode ser feito com algum SQL dinâmico e o INFORMATION_SCHEMA
tabelas.
Se alguém tiver um script ou puder criar um rapidamente, poste-o.
Se ninguém postar uma resposta antes de eu descobrir, postarei minha solução.
Solução
Talvez seja necessário modificar a consulta para incluir o proprietário se houver mais de um no banco de dados.
DECLARE @cmd varchar(4000)
DECLARE cmds CURSOR FOR
SELECT 'drop table [' + Table_Name + ']'
FROM INFORMATION_SCHEMA.TABLES
WHERE Table_Name LIKE 'prefix%'
OPEN cmds
WHILE 1 = 1
BEGIN
FETCH cmds INTO @cmd
IF @@fetch_status != 0 BREAK
EXEC(@cmd)
END
CLOSE cmds;
DEALLOCATE cmds
Isso é mais limpo do que usar uma abordagem em duas etapas de gerar script e executar.Mas uma vantagem da geração de scripts é que ela oferece a oportunidade de revisar tudo o que será executado antes de realmente ser executado.
Eu sei que se fosse fazer isso em um banco de dados de produção, seria o mais cuidadoso possível.
Editar Amostra de código corrigida.
Outras dicas
SELECT 'DROP TABLE "' + TABLE_NAME + '"'
FROM INFORMATION_SCHEMA.TABLES
WHERE TABLE_NAME LIKE '[prefix]%'
Isso irá gerar um script.
Adicionando cláusula para verificar a existência da tabela antes de excluir:
SELECT 'IF OBJECT_ID(''' +TABLE_NAME + ''') IS NOT NULL BEGIN DROP TABLE [' + TABLE_NAME + '] END;'
FROM INFORMATION_SCHEMA.TABLES
WHERE TABLE_NAME LIKE '[prefix]%'
Isso fornecerá as tabelas em ordem de chave estrangeira e evitará a eliminação de algumas das tabelas criadas pelo SQL Server.O t.Ordinal
value dividirá as tabelas em camadas de dependência.
WITH TablesCTE(SchemaName, TableName, TableID, Ordinal) AS
(
SELECT OBJECT_SCHEMA_NAME(so.object_id) AS SchemaName,
OBJECT_NAME(so.object_id) AS TableName,
so.object_id AS TableID,
0 AS Ordinal
FROM sys.objects AS so
WHERE so.type = 'U'
AND so.is_ms_Shipped = 0
AND OBJECT_NAME(so.object_id)
LIKE 'MyPrefix%'
UNION ALL
SELECT OBJECT_SCHEMA_NAME(so.object_id) AS SchemaName,
OBJECT_NAME(so.object_id) AS TableName,
so.object_id AS TableID,
tt.Ordinal + 1 AS Ordinal
FROM sys.objects AS so
INNER JOIN sys.foreign_keys AS f
ON f.parent_object_id = so.object_id
AND f.parent_object_id != f.referenced_object_id
INNER JOIN TablesCTE AS tt
ON f.referenced_object_id = tt.TableID
WHERE so.type = 'U'
AND so.is_ms_Shipped = 0
AND OBJECT_NAME(so.object_id)
LIKE 'MyPrefix%'
)
SELECT DISTINCT t.Ordinal, t.SchemaName, t.TableName, t.TableID
FROM TablesCTE AS t
INNER JOIN
(
SELECT
itt.SchemaName AS SchemaName,
itt.TableName AS TableName,
itt.TableID AS TableID,
Max(itt.Ordinal) AS Ordinal
FROM TablesCTE AS itt
GROUP BY itt.SchemaName, itt.TableName, itt.TableID
) AS tt
ON t.TableID = tt.TableID
AND t.Ordinal = tt.Ordinal
ORDER BY t.Ordinal DESC, t.TableName ASC
No Oracle XE isso funciona:
SELECT 'DROP TABLE "' || TABLE_NAME || '";'
FROM USER_TABLES
WHERE TABLE_NAME LIKE 'YOURTABLEPREFIX%'
Ou se você quiser remova as restrições e libere espaço também, use isto:
SELECT 'DROP TABLE "' || TABLE_NAME || '" cascade constraints PURGE;'
FROM USER_TABLES
WHERE TABLE_NAME LIKE 'YOURTABLEPREFIX%'
O que irá gerar um monte de DROP TABLE cascade constraints PURGE
declarações...
Para VIEWS
usa isto:
SELECT 'DROP VIEW "' || VIEW_NAME || '";'
FROM USER_VIEWS
WHERE VIEW_NAME LIKE 'YOURVIEWPREFIX%'
EXEC sp_MSforeachtable 'if PARSENAME("?",1) like ''%CertainString%'' DROP TABLE ?'
Editar:
sp_MSforeachtable não está documentado, portanto, não é adequado para produção porque seu comportamento pode variar dependendo da versão do MS_SQL.
CREATE PROCEDURE usp_GenerateDROP
@Pattern AS varchar(255)
,@PrintQuery AS bit
,@ExecQuery AS bit
AS
BEGIN
DECLARE @sql AS varchar(max)
SELECT @sql = COALESCE(@sql, '') + 'DROP TABLE [' + TABLE_NAME + ']' + CHAR(13) + CHAR(10)
FROM INFORMATION_SCHEMA.TABLES
WHERE TABLE_NAME LIKE @Pattern
IF @PrintQuery = 1 PRINT @sql
IF @ExecQuery = 1 EXEC (@sql)
END
Eu vi esta postagem quando estava procurando uma instrução mysql para eliminar todas as tabelas do WordPress com base em @Xenph Yan, aqui está o que fiz eventualmente:
SELECT CONCAT( 'DROP TABLE `', TABLE_NAME, '`;' ) AS query
FROM INFORMATION_SCHEMA.TABLES
WHERE TABLE_NAME LIKE 'wp_%'
isso lhe dará o conjunto de consultas suspensas para todas as tabelas que começam com wp_
Aqui está minha solução:
SELECT CONCAT('DROP TABLE `', TABLE_NAME,'`;')
FROM INFORMATION_SCHEMA.TABLES
WHERE TABLE_NAME LIKE 'TABLE_PREFIX_GOES_HERE%';
E é claro que você precisa substituir TABLE_PREFIX_GOES_HERE
com seu prefixo.
Xenph Yana resposta de foi muito mais limpa que a minha, mas aqui está a minha mesmo assim.
DECLARE @startStr AS Varchar (20)
SET @startStr = 'tableName'
DECLARE @startStrLen AS int
SELECT @startStrLen = LEN(@startStr)
SELECT 'DROP TABLE ' + name FROM sysobjects
WHERE type = 'U' AND LEFT(name, @startStrLen) = @startStr
Apenas mude tableName
para os caracteres com os quais você deseja pesquisar.
Obrigado Curt, esse é o mesmo tipo de solução que eu estava no meio do processo.
O seu é melhor que o meu - ele pode ser facilmente modificado.Eu adicionei uma união ao select e eliminei algumas visualizações também;)
declare @cmd varchar(4000)
declare cmds cursor for
Select 'drop table [' + Table_Name + ']'
From INFORMATION_SCHEMA.TABLES
Where Table_Name like 'prefix%'
union
Select 'drop view [' + Table_Name + ']'
From INFORMATION_SCHEMA.VIEWS
Where Table_Name like 'prefix%'
open cmds
while 1=1
begin
fetch cmds into @cmd
if @@fetch_status != 0 break
exec(@cmd)
end
close local
deallocate local
Não se preocupe, não é um banco de dados de produção - isso é apenas para facilitar a limpeza do meu banco de dados de desenvolvimento enquanto eu experimento algumas coisas.
select 'DROP TABLE ' + name from sysobjects
where type = 'U' and sysobjects.name like '%test%'
--Test é o nome da tabela
SELECT 'if object_id(''' + TABLE_NAME + ''') is not null begin drop table "' + TABLE_NAME + '" end;'
FROM INFORMATION_SCHEMA.TABLES
WHERE TABLE_NAME LIKE '[prefix]%'
Tive que fazer uma pequena derivação da resposta de Xenph Yan, suspeito, porque tinha tabelas que não estavam no esquema padrão.
SELECT 'DROP TABLE Databasename.schema.' + TABLE_NAME
FROM INFORMATION_SCHEMA.TABLES
WHERE TABLE_NAME LIKE 'strmatch%'
No caso de tabelas temporárias, você pode tentar
SELECT 'DROP TABLE "' + t.name + '"'
FROM tempdb.sys.tables t
WHERE t.name LIKE '[prefix]%'