(Wide) String - Armazenamento no TfileStream, Delphi 7. Qual é a maneira mais rápida?

Question

Estou usando o Delphi7 (VCL não-UNICODE), preciso armazenar muitas redes dentro de um TfileStream. Não posso usar o TStringStream, pois as cordas (amplas) são misturadas com dados binários, o formato é projetado para acelerar o carregamento e a escrita dos dados ... no entanto, acredito que a maneira atual de carregar/escrever as seqüências de caracteres pode ser um gargalo do meu código ...

Atualmente, estou escrevendo comprimento de uma corda, depois escrevê -la char por char ... enquanto carrega, primeiro estou carregando o comprimento e depois carregando char por char ...

Então, qual é a maneira mais rápida de salvar e carregar o WideString no TfileStream?

desde já, obrigado

Answer 1

Em vez de ler e escrever um personagem de cada vez, leia e escreva -os de uma só vez:

procedure WriteWideString(const ws: WideString; stream: TStream);
var
  nChars: LongInt;
begin
  nChars := Length(ws);
  stream.WriteBuffer(nChars, SizeOf(nChars);
  if nChars > 0 then
    stream.WriteBuffer(ws[1], nChars * SizeOf(ws[1]));
end;

function ReadWideString(stream: TStream): WideString;
var
  nChars: LongInt;
begin
  stream.ReadBuffer(nChars, SizeOf(nChars));
  SetLength(Result, nChars);
  if nChars > 0 then
    stream.ReadBuffer(Result[1], nChars * SizeOf(Result[1]));
end;

Agora, tecnicamente, desde WideString é uma janela BSTR, pode conter um ímpar Número de bytes. o Length A função lê o número de bytes e se divide por dois, por isso é possível (embora não provável) que o código acima seja interrompido o último byte. Você pode usar este código:

procedure WriteWideString(const ws: WideString; stream: TStream);
var
  nBytes: LongInt;
begin
  nBytes := SysStringByteLen(Pointer(ws));
  stream.WriteBuffer(nBytes, SizeOf(nBytes));
  if nBytes > 0 then
    stream.WriteBuffer(Pointer(ws)^, nBytes);
end;

function ReadWideString(stream: TStream): WideString;
var
  nBytes: LongInt;
  buffer: PAnsiChar;
begin
  stream.ReadBuffer(nBytes, SizeOf(nBytes));
  if nBytes > 0 then begin
    GetMem(buffer, nBytes);
    try
      stream.ReadBuffer(buffer^, nBytes);
      Result := SysAllocStringByteLen(buffer, nBytes)
    finally
      FreeMem(buffer);
    end;
  end else
    Result := '';
end;

Inspirado por A resposta de Mghie, substituíram meu Read e Write chamadas com ReadBuffer e WriteBuffer. Este último aumentará exceções se não conseguir ler ou escrever o número solicitado de bytes.

Answer 2

Não há nada de especial em cordas amplas, para ler e escrevê -las o mais rápido possível, você precisa ler e escrever o máximo possível de uma só vez:

procedure TForm1.Button1Click(Sender: TObject);
var
  Str: TStream;
  W, W2: WideString;
  L: integer;
begin
  W := 'foo bar baz';

  Str := TFileStream.Create('test.bin', fmCreate);
  try
    // write WideString
    L := Length(W);
    Str.WriteBuffer(L, SizeOf(integer));
    if L > 0 then
      Str.WriteBuffer(W[1], L * SizeOf(WideChar));

    Str.Seek(0, soFromBeginning);
    // read back WideString
    Str.ReadBuffer(L, SizeOf(integer));
    if L > 0 then begin
      SetLength(W2, L);
      Str.ReadBuffer(W2[1], L * SizeOf(WideChar));
    end else
      W2 := '';
    Assert(W = W2);
  finally
    Str.Free;
  end;
end;

Answer 3

Os wideestrings contêm uma 'string' de WideChar, que usam 2 bytes cada. Se você deseja armazenar strings UTF-16 (que as widestrings usam internamente) em um arquivo e poder usar esse arquivo em outros programas como o bloco de notas, você precisa escrever um Marca de pedidos de byte primeiro: #$FEFF.

Se você sabe disso, escrever pode ser assim:

Stream1.Write(WideString1[1],Length(WideString)*2); //2=SizeOf(WideChar)

A leitura pode ficar assim:

Stream1.Read(WideChar1,2);//assert returned 2 and WideChar1=#$FEFF
SetLength(WideString1,(Stream1.Size div 2)-1);
Stream1.Read(WideString1[1],(Stream1.Size div 2)-1);

Answer 4

Você também pode usar o TastFileStream para ler os dados ou strings, eu colei a unidade em http://pastebin.com/m6ecdc8c2 e uma amostra abaixo:

program Project36;

{$APPTYPE CONSOLE}

uses
  SysUtils, Classes,
  FastStream in 'FastStream.pas';

const
  WideNull: WideChar = #0;

procedure WriteWideStringToStream(Stream: TFileStream; var Data: WideString);
var
  len: Word;
begin
  len := Length(Data);
  // Write WideString length
  Stream.Write(len, SizeOf(len));
  if (len > 0) then
  begin
    // Write WideString
    Stream.Write(Data[1], len * SizeOf(WideChar));
  end;
  // Write null termination
  Stream.Write(WideNull, SizeOf(WideNull));
end;

procedure CreateTestFile;
var
  Stream: TFileStream;
  MyString: WideString;
begin
  Stream := TFileStream.Create('test.bin', fmCreate);
  try
    MyString := 'Hello World!';
    WriteWideStringToStream(Stream, MyString);

    MyString := 'Speed is Delphi!';
    WriteWideStringToStream(Stream, MyString);
  finally
    Stream.Free;
  end;
end;

function ReadWideStringFromStream(Stream: TFastFileStream): WideString;
var
  len: Word;
begin
  // Read length of WideString
  Stream.Read(len, SizeOf(len));
  // Read WideString
  Result := PWideChar(Cardinal(Stream.Memory) + Stream.Position);
  // Update position and skip null termination
  Stream.Position := Stream.Position + (len * SizeOf(WideChar)) + SizeOf(WideNull);
end;

procedure ReadTestFile;
var
  Stream: TFastFileStream;

  my_wide_string: WideString;
begin
  Stream := TFastFileStream.Create('test.bin');
  try
    Stream.Position := 0;
    // Read WideString
    my_wide_string := ReadWideStringFromStream(Stream);
    WriteLn(my_wide_string);
    // Read another WideString
    my_wide_string := ReadWideStringFromStream(Stream);
    WriteLn(my_wide_string);
  finally
    Stream.Free;
  end;
end;

begin
  CreateTestFile;
  ReadTestFile;
  ReadLn;
end.