Como faço para concatenar duas matrizes multi-dimensionais em VB?

Question

Eu tenho este código:

rs1 = getResults(sSQL1)
rs2 = getResults(sSQL2)

rs1 e RS2 e 2D matrizes. O primeiro índice representa o número de colunas (estáticos) e o segundo índice representa o número de linhas (dinâmico).

Eu preciso juntar as duas matrizes e armazená-los em RS3. Eu não sei que tipo RS1 e RS2 são embora.

Answer 1

Eu percebi isso. Acontece que eu estava fazendo isso da maneira certa o tempo todo, eu estava fora por um. Você não precisa de uma terceira série também.

        aRS_RU = rowsQuery(sSQL & ", 'RU'")
        aRS_KR = rowsQuery(sSQL & ", 'KR'")

        uboundRU1 = UBound(aRS_RU, 1)
        uboundRU2 = UBound(aRS_RU, 2)
        uboundKR2 = Ubound(aRS_KR, 2)

        ' Redim original array
        ReDim Preserve aRS_RU(uboundRU1, uboundRU2 + uboundKR2 + 1 )
        uboundRU2 = UBound(aRS_RU, 2)

        ' Add the values from the second array            
        For m = LBound(aRS_KR, 1) To UBound(aRS_KR, 1)      'Loop for 1st dimension
            For n = LBound(aRS_KR, 2) To UBound(aRS_KR, 2)  'Loop for 2nd dimension
                aRS_RU(m, uboundRU2 + n) = aRS_KR(m,n)
            Next
        Next           

Answer 2

Você tem certeza de que as colunas irá igualar-se? Porque se não é esse o caso, eu não sei como você pode fazê-lo de uma forma genérica em qualquer idioma. Se for o caso, então você provavelmente poderia fazê-lo muito simplesmente assim:

rs1 = getResults(sSQL1 & " UNION " sSQL2)

Answer 3

Eu sei que este post é antigo, mas eu adaptei o código para corrigir alguns erros que eu tinha durante a sua execução. O seguinte exemplo de código funciona para mim:

Sub ConcatRecordSets(ByRef avFirstRS As Variant, ByRef avSecondRS As Variant)

    Dim lIndex1 As Long, lIndex2 As Long
    Dim lFirstRSSize As Long, lSecondRSSize As Long

    ' Redim original array
    lFirstRSSize = UBound(avFirstRS, 2) - LBound(avFirstRS, 2) + 1
    lSecondRSSize = UBound(avSecondRS, 2) - LBound(avSecondRS, 2) + 1
    ReDim Preserve avFirstRS(LBound(avFirstRS, 1) To UBound(avFirstRS, 1), LBound(avFirstRS, 2) To UBound(avFirstRS, 2) + lSecondRSSize)

    ' Add the values from the second array
    For lIndex1 = LBound(avSecondRS, 1) To UBound(avSecondRS, 1)      ' Loop for 1st dimension
        For lIndex2 = LBound(avSecondRS, 2) To UBound(avSecondRS, 2)  ' Loop for 2nd dimension
            avFirstRS(lIndex1, lFirstRSSize + lIndex2) = avSecondRS(lIndex1, lIndex2)
        Next lIndex2
    Next lIndex1

End Sub