Usando SAS Macro para canalizar uma lista de nomes de arquivos de um diretório do Windows
Pergunta
Eu estou tentando alterar a macro abaixo para aceitar um parâmetro macro como o argumento 'localização' para um comando dir. No entanto eu não posso obtê-lo para resolver corretamente devido à questão citações aninhada. Usando% str (% ') não funciona, nem citando funções por algum motivo.
A macro trabalho vontade bem quando o filepath tem sem espaços (por exemplo C: \ temp \ withnospace) como as cotações médias não são necessários. No entanto eu preciso essa macro para trabalho para filepaths com espaços (por exemplo, 'C: \ temp \ com espaço \')
.ajuda por favor!
%macro get_filenames(location)
filename pipedir pipe "dir &location. /b " lrecl=32767;
data filenames;
infile pipedir truncover;
input line $char1000.;
run;
%mend;
%get_filenames(C:\temp\) /* works */
%get_filenames('C:\temp\with space') /* doesnt work */
Solução
Aqui está outra maneira de alcançar o mesmo resultado sem a necessidade de usar um tubo.
%macro get_filenames(location);
filename _dir_ "%bquote(&location.)";
data filenames(keep=memname);
handle=dopen( '_dir_' );
if handle > 0 then do;
count=dnum(handle);
do i=1 to count;
memname=dread(handle,i);
output filenames;
end;
end;
rc=dclose(handle);
run;
filename _dir_ clear;
%mend;
%get_filenames(C:\temp\);
%get_filenames(C:\temp\with space);
%get_filenames(%bquote(C:\temp\with'singlequote));
Outras dicas
Faça as seguintes várias mudanças e seu código irá funcionar.
%macro get_filenames(location); %*--(1)--*;
filename pipedir pipe "dir ""%unquote(&location)"" /b" lrecl=32767; %*--(2)--*;
data filenames;
infile pipedir truncover;
input filename $char1000.;
put filename=;
run;
filename pipedir clear; %*--(3)--*;
%mend;
%get_filenames(d:\)
%get_filenames(d:\your dir) %*--(4)--*;
(1) terminar a instrução %macro
com um ponto e vírgula;
(2) Surround a resolução variável macro com citações e %unquote
duplas dobrou-up;
(3) Solte o identificador de arquivo, limpando-o; e
(4) Não aspa seu parâmetro de entrada. Citação macro em vez disso, se necessário.
Com base na última amostra no este página , em vez da instrução nome do arquivo, tente
%let filrf=pipedir;
%let rc=%sysfunc(filename(filrf,%bquote(dir "&location" /b),pipe));
e chamar a macro sem usar aspas:
%get_filenames(c:\temp\with spaces);
Eu também tentei macro citando, mas não conseguiu fazê-lo funcionar.
aqui está uma macro rápida para puxar janelas baseados em diretório listagens em um conjunto de dados sas.
%macro DirList(dir); /* %if &SUBDIR eq %then %let subdir=/s; */ /*** &SUBDIR not defined ****/ filename dirpipe pipe "dir &DIR.\*.* /s /-c"; data dir_list(label="Directory Listing [&DIR.]" drop=re_: _line_ date time); format Path File $250. ModDT datetime19. Size 16. _line_ $32000. ; if _N_ = 1 then do; re_path=prxparse("/Directory of (.+)/"); re_subd=prxparse("/(\d\d\/\d\d\/\d\d\d\d)\s+(\d\d:\d\d [A|P]M)\s+\s+(\S.*)/"); re_file=prxparse("/(\d\d\/\d\d\/\d\d\d\d)\s+(\d\d:\d\d [A|P]M)\s+(\d+)\s+(\S.*)/"); retain re_: path; end; infile dirpipe lrecl=32000; input; _line_ = _infile_; if lengthn(_line_)=0 then delete; else if prxmatch(re_path, _line_) then do; path=prxposn(re_path, 1, _line_); end; else if prxmatch(re_subd, _line_) then do; date=input(prxposn(re_subd, 1, _line_), mmddyy10.); time=input(prxposn(re_subd, 2, _line_), time6.); ModDT=dhms(date, 0, 0, time); File=prxposn(re_subd, 3, _line_); size = .D; /*mark subdirectory records*/ if file not in ('.', '..') then output; end; else if prxmatch(re_file, _line_) then do; date=input(prxposn(re_file, 1, _line_), mmddyy10.); time=input(prxposn(re_file, 2, _line_), time6.); ModDT=dhms(date, 0, 0, time); size=input(prxposn(re_file, 3, _line_), 16.); file=prxposn(re_file, 4, _line_); output; end; run; filename dirpipe clear; %mend;
e aqui está como eles são chamados
%dirlist(c:); %dirlist(c:\temp);
aviso que não há barra invertida quando especificar o diretório base. C:
não C:\
.
funciona para mim se eu chamar a macro original desta forma
%get_filenames(""C:\Program Files"")
É claro que eu tinha para adicionar o ponto e vírgula no fim da instrução %macro
.
Se o seu diretório contém uma vírgula, coisas ruins acontecem. a correção, use a macro %str()
%get_filenames(%str(C:\temp\comma, fail))
Aqui está uma versão pura código de macro. Ele também permite que você especifique que você só quer saber sobre arquivos (e não pastas) e permite que você especifique um filtro básico. Ele retorna a lista de arquivos em um formato delimitado, mas você pode facilmente inserir-los em um conjunto de dados usando a inserção SQL se você quiser (exemplo incluído, mas não testado - nenhum acesso SAS atm). Ele pode ser chamado de qualquer lugar - dentro de outra macro, um conjunto de dados, uma instrução SQL ... onde quer. Basta adicionar estes dois macros à sua macro biblioteca autocall e você está certo a seguir.
Existem 2 macros abaixo. A macro% isDir é exigido pela macro% file_list. As macros são um pouco maiores e mais complexo do que o anterior, mas eles são muito mais flexíveis. Além disso, eles fornecem a verificação de erros.
/******************************************************************************
** PROGRAM: ISDIR.SAS
**
** DESCRIPTION: DETERMINES IF THE SPECIFIED PATH EXISTS OR NOT.
** RETURNS: 0 IF THE PATH DOES NOT EXIST OR COULD NOT BE OPENED.
** 1 IF THE PATH EXISTS AND CAN BE OPENED.
**
** PARAMETERS: iPath: THE FULL PATH TO EXAMINE. NOTE THAT / AND \ ARE TREATED
** THE SAME SO &SASDIR/COMMON/MACROS IS THE SAME AS
** &SASDIR\COMMON\MACROS.
**
******************************************************************************/
%macro isDir(iPath=,iQuiet=1);
%local result dname;
%let result = 0;
%if %sysfunc(filename(dname,&iPath)) eq 0 %then %do;
%if %sysfunc(dopen(&dname)) %then %do;
%let result = 1;
%end;
%else %if not &iQuiet %then %do;
%put ERROR: ISDIR: %sysfunc(sysmsg());
%end;
%end;
%else %if not &iQuiet %then %do;
%put ERROR: ISDIR: %sysfunc(sysmsg());
%end;
&result
%mend;
%put %isDir(iPath=&sasdir/common/macros);
%put %isDir(iPath=&sasdir/kxjfdkebnefe);
%put %isDir(iPath=&sasdir/kxjfdkebnefe, iQuiet=0);
%put %isDir(iPath=c:\temp);
/******************************************************************************
** PROGRAM: FILE_LIST.SAS
**
** DESCRIPTION: RETURNS THE LIST OF FILES IN A DIRECTORY SEPERATED BY THE
** SPECIFIED DELIMITER. RETURNS AN EMPTY STRING IF THE THE
** DIRECTORY CAN'T BE READ OR DOES NOT EXIST.
**
** PARAMETERS: iPath : THE FULL PATH TO EXAMINE. NOTE THAT / AND \ ARE
** TREATED THE SAME SO &SASDIR/COMMON/MACROS IS THE
** SAME AS &SASDIR\COMMON\MACROS. WORKS WITH BOTH UNIX
** AND WINDOWS.
** iFilter : SPECIFY A BASIC FILTER TO THE FILENAMES, NO REGULAR
** EXPRESSIONS OR WILDCARDS.
** iFiles_only: 0=RETURN FILES AND FOLDERS
** 1=RETURN FILES ONLY.
** iDelimiter : SPECIFY THE DELIMITER TO SEPERATE THE RESULTS BY.
******************************************************************************/
/*
** TODO: DOESNT CATER FOR MACRO CHARS IN FILENAMES. FIX SOMETIME.
** TODO: IMPROVE THE FILTER. JUST A SIMPLE IF STATEMENT AT THE MOMENT.
*/
%macro file_list(iPath=, iFilter=, iFiles_only=0, iDelimiter=|);
%local result did dname cnt num_members filename;
%let result=;
%if %sysfunc(filename(dname,&iPath)) eq 0 %then %do;
%let did = %sysfunc(dopen(&dname));
%let num_members = %sysfunc(dnum(&did));
%do cnt=1 %to &num_members;
%let filename = %sysfunc(dread(&did,&cnt));
%if "&filename" ne "" %then %do;
%if &iFiles_only %then %do;
%if not %isDir(iPath=&iPath/&filename) %then %do;
%if "&iFilter" ne "" %then %do;
%if %index(%lowcase(&filename),%lowcase(&iFilter)) %then %do;
%let result = &result%str(&iDelimiter)&filename;
%end;
%end;
%else %do;
%let result = &result%str(&iDelimiter)&filename;
%end;
%end;
%end;
%else %do;
%if "&iFilter" ne "" %then %do;
%if %index(%lowcase(&filename),%lowcase(&iFilter)) %then %do;
%let result = &result%str(&iDelimiter)&filename;
%end;
%end;
%else %do;
%let result = &result%str(&iDelimiter)&filename;
%end;
%end;
%end;
%else %do;
%put ERROR: (CMN_MAC.FILE_LIST) FILE CANNOT BE READ.;
%put %sysfunc(sysmsg());
%end;
%end;
%end;
%else %do;
%put ERROR: (CMN_MAC.FILE_LIST) PATH DOES NOT EXIST OR CANNOT BE OPENED.;
%put %sysfunc(sysmsg());
%end;
/*
** RETURN THE RESULT. TRIM THE LEADING DELIMITER OFF THE FRONT OF THE RESULTS.
*/
%if "&result" ne "" %then %do;
%substr(&result,2)
%end;
%mend;
**
** EXAMPLES - HAVENT TESTED THE LAST TWO YET BUT THEY SHOULD WORK IF SYNTAX IS CORRECT
*;
%put %file_list(iPath=c:\temp);
%put %file_list(iPath=c:\xxdffsds);
%put %file_list(iPath=c:\rob\SASDev\, iFilter=a);
%put %file_list(iPath=c:\rob\SASDev\,iFiles_only=1);
%put %file_list(iPath=/tmp/unix_sasdir,iFiles_only=1);
data x;
file_list = "%file_list(iPath=c:\temp)";
run;
proc sql noprint;
insert into my_table values ("%file_list(iPath=c:\temp,iDelimiter=%str(","))");
quit;
Aqui está um que decodifica a ordem de citar e unquoting:
%let command =%unquote(%str(%')dir "&baseDir.data\*txt"%str(%'));
filename datain pipe &command;
onde macro variável basedir pode conter espaços e por isso pode os nomes de arquivos.
Esta combinação de
%unquote
e %str(%')
é um idioma macro frequentemente ocorrendo.
"o que se eu tiver aspas simples no meu dir?"
lidar com esta situação requer uma função citando macro, tais como %bquote();
Continuando o exemplo acima, o seguinte:
%let command =%unquote(%str(%')dir "%bquote(&baseDir.data\*txt)"%str(%'));
deve fazê-lo.
Para evitar infinitas repetições de esse tipo de pergunta, olhada papel de Ian Whitlock, um olhar sério Macro Citando, que está disponível aqui ;
Existem (muitos) outros, mas este é o mais citado. Uma pequena nota: nada por Ian Whitlock é provavelmente vale a pena. Ele escreve claramente e sua compreensão das questões SAS é incrível.
Nós usamos este pequeno macro
%macro getdir(dir=,redirect=, switch=);
options noxwait xsync;
%if %length(&switch)=0 %then %let switch=b;
data _null_;
xcmd='dir "' || "&dir" || '"' || "/&switch " || ">" || "&redirect";
put 'generated the following command: ' xcmd=;
rc=system(xcmd);
put 'result code of above command: ' rc=;
run;
%mend getdir;
Chamada Amostra
%getdir(dir=c:\temp\,redirect=c:\temp\dir.txt) *run;
Se você executar em lote e não têm a option noxwait xsync
o trabalho vai pendurar no servidor esperando por uma resposta do operador.