Как я могу создать ожидаемый запрос скрипта на ввод пароля?
Вопрос
У меня есть ожидаемый скрипт, который подключается к нескольким маршрутизаторам через ssh.Все эти маршрутизаторы имеют один и тот же пароль (я знаю, это неправильно), и скрипт должен знать этот пароль, чтобы иметь возможность подключаться к маршрутизаторам.В настоящее время пароль передается моему скрипту в качестве аргумента в командной строке, но это означает, что в моем файле .bash_history есть след этого пароля, а также в запущенных процессах.Поэтому вместо этого я бы хотел, чтобы пользователю было предложено ввести пароль, по возможности беззвучно.
Знаете ли вы, возможно ли запросить у пользователя пароль с помощью expect?
Спасибо.
Редактировать:если бы я подключался к серверам вместо маршрутизаторов, я бы, вероятно, использовал ssh-ключи вместо паролей.Но маршрутизаторы, которые я использую, поддерживают только пароли.
Решение
Используйте ожидаемые stty
команда, подобная этой:
# grab the password
stty -echo
send_user -- "Password for $user@$host: "
expect_user -re "(.*)\n"
send_user "\n"
stty echo
set pass $expect_out(1,string)
#... later
send -- "$pass\r"
Обратите внимание, что важно позвонить stty -echo
до того , как зовущий send_user
-- Я не совсем уверен , почему:Я думаю, что это проблема времени.
ожидайте, что программисты все должны читать в книга:Исследуя Ожидания Дона Либеса
Другие советы
Хорошо, объединяем 2 ответа выше (или ниже, или где бы они ни были сейчас!):
#!/usr/bin/expect
log_user 0
set timeout 10
set userid "XXXXX"
set pass "XXXXXX"
### Get two arguments - (1) Host (2) Command to be executed
set host [lindex $argv 0]
set command [lindex $argv 1]
# grab the password
stty -echo
send_user -- "Password for $userid@$host: "
expect_user -re "(.*)\n"
send_user "\n"
stty echo
set pass $expect_out(1,string)
spawn /usr/bin/ssh -l $userid $host
match_max [expr 32 * 1024]
expect {
-re "RSA key fingerprint" {send "yes\r"}
timeout {puts "Host is known"}
}
expect {
-re "username: " {send "$userid\r"}
-re "(P|p)assword: " {send "$pass\r"}
-re "Warning:" {send "$pass\r"}
-re "Connection refused" {puts "Host error -> $expect_out(buffer)";exit}
-re "Connection closed" {puts "Host error -> $expect_out(buffer)";exit}
-re "no address.*" {puts "Host error -> $expect_out(buffer)";exit}
timeout {puts "Timeout error. Is host down or unreachable?? ssh_expect";exit}
}
expect {
-re "\[#>]$" {send "term len 0\r"}
timeout {puts "Error reading prompt -> $expect_out(buffer)";exit}
}
expect {
-re "\[#>]$" {send "$command\r"}
timeout {puts "Error reading prompt -> $expect_out(buffer)";exit}
}
expect -re "\[#>]$"
set output $expect_out(buffer)
send "exit\r"
puts "$output\r\n"
Обратите внимание, что я изменил переменную $ password на $pass, чтобы соответствовать другому ответу.
В качестве альтернативы вы могли бы позволить ssh собирать пароль через X11, используя переменную окружения SSH_ASKPASS.
Со справочной страницы:
> SSH_ASKPASS
> If ssh needs a passphrase, it will read the passphrase from the
> current terminal if it was run from a terminal. If ssh does not
> have a terminal associated with it but DISPLAY and SSH_ASKPASS
> are set, it will execute the program specified by SSH_ASKPASS
> and open an X11 window to read the passphrase. This is particularly
> useful when calling ssh from a .xsession or related script.
> (Note that on some machines it may be necessary to redirect the
> input from /dev/null to make this work.)