Как мне придать RichTextBox плоский вид?

Question

Я работаю над приложением WinForms SmartClient, которое использует множество элементов управления RichTextBox - некоторые вместо обычного текстового поля по разным причинам.К сожалению, RichTextBox рисует уродливую 3D-границу Win95 вместо тематической границы в стиле XP или Vista.

Кто-нибудь знает о способе применить тематическую рамку к RichTextBox?Я не возражаю против их подкласса для этой цели.

Спасибо!

Answer 1

Это действительно взлом, но одна вещь, которую вы можете сделать, это перенести элемент управления Panel на страницу.Присвойте ему стиль границы FixedSingle (по умолчанию он будет None).

Поместите свой RichTextBox на панель и установите для BorderStyle значение none.Затем установите для свойства Dock для RichTextBox значение Fill (Заполнять).

Это даст вам RichTextBox с плоской границей.

Answer 2

Когда-то мне приходилось решать эту проблему с помощью панели, где текстовое поле является компонентом внутри и для DockPadding установлено значение 3 или 4 пикселя.Затем я бы оформил эту панель в один пиксель.

Меня всегда это очень раздражало!

Answer 3

Я думаю, это немного запоздало, но тем не менее.

Вы всегда можете использовать P / Invoke и подклассировать свой RichEdit с помощью UXTheme API, чтобы вы могли отключить / включить его по своему усмотрению.

Я думаю, что у CodeProject был элемент управления richedit, который использовал UXTheme / Visual Styles API

API UXTheme визуальных стилей может устареть по мере развертывания Windows 8

Answer 4

Вот VB.NET код, он увеличивает область без клиента значением -1, а затем заполняет область без клиента выцветшим синим цветом.Он может быть преобразован в C # с помощью SharpDevelop 4.4.Я вывел код из этой статьи:

http://www.codeproject.com/Articles/13723/Themed-RichTextBox-A-RichTextBox-with-XP-styled-bo

Imports System.Runtime.InteropServices
Imports System.Windows.Forms
Imports System.Windows.Forms.VisualStyles
Imports System.Drawing
Imports System.Diagnostics

Public Class FlatRichTextBox
    Inherits RichTextBox

    Private BorderRect As RECT

    Sub New()
        If VisualStyleInformation.IsEnabledByUser Then
            BorderStyle = BorderStyle.None
        End If
    End Sub

    Protected Overrides Sub WndProc(ByRef m As Message)
        Const WM_NCPAINT = &H85
        Const WM_NCCALCSIZE = &H83
        Const WM_THEMECHANGED = &H31A

        Select Case m.Msg
            Case WM_NCPAINT
                WmNcpaint(m)
            Case WM_NCCALCSIZE
                WmNccalcsize(m)
            Case WM_THEMECHANGED
                UpdateStyles()
            Case Else
                MyBase.WndProc(m)
        End Select
    End Sub

    Private Sub WmNccalcsize(ByRef m As Message)
        MyBase.WndProc(m)

        If Not VisualStyleInformation.IsEnabledByUser Then Return

        Dim par As New NCCALCSIZE_PARAMS()
        Dim windowRect As RECT

        If m.WParam <> IntPtr.Zero Then
            par = CType(Marshal.PtrToStructure(m.LParam, GetType(NCCALCSIZE_PARAMS)), NCCALCSIZE_PARAMS)
            windowRect = par.rgrc0
        End If

        Dim clientRect = windowRect

        clientRect.Left += 1
        clientRect.Top += 1
        clientRect.Right -= 1
        clientRect.Bottom -= 1

        BorderRect = New RECT(clientRect.Left - windowRect.Left,
                              clientRect.Top - windowRect.Top,
                              windowRect.Right - clientRect.Right,
                              windowRect.Bottom - clientRect.Bottom)

        If m.WParam = IntPtr.Zero Then
            Marshal.StructureToPtr(clientRect, m.LParam, False)
        Else
            par.rgrc0 = clientRect
            Marshal.StructureToPtr(par, m.LParam, False)
        End If

        Const WVR_HREDRAW = &H100
        Const WVR_VREDRAW = &H200
        Const WVR_REDRAW = (WVR_HREDRAW Or WVR_VREDRAW)

        m.Result = New IntPtr(WVR_REDRAW)
    End Sub

    Private Sub WmNcpaint(ByRef m As Message)
        MyBase.WndProc(m)

        If Not VisualStyleInformation.IsEnabledByUser Then Return

        Dim r As RECT
        GetWindowRect(Handle, r)

        r.Right -= r.Left
        r.Bottom -= r.Top
        r.Top = 0
        r.Left = 0

        r.Left += BorderRect.Left
        r.Top += BorderRect.Top
        r.Right -= BorderRect.Right
        r.Bottom -= BorderRect.Bottom

        Dim hDC = GetWindowDC(Handle)
        ExcludeClipRect(hDC, r.Left, r.Top, r.Right, r.Bottom)

        Using g = Graphics.FromHdc(hDC)
            g.Clear(Color.CadetBlue)
        End Using

        ReleaseDC(Handle, hDC)
        m.Result = IntPtr.Zero
    End Sub

    <DllImport("user32.dll")>
    Public Shared Function GetWindowRect(hWnd As IntPtr, ByRef lpRect As RECT) As Boolean
    End Function

    <DllImport("user32.dll")>
    Public Shared Function GetWindowDC(hWnd As IntPtr) As IntPtr
    End Function

    <DllImport("user32.dll")>
    Public Shared Function ReleaseDC(hWnd As IntPtr, hDC As IntPtr) As Integer
    End Function

    <DllImport("gdi32.dll")>
    Public Shared Function ExcludeClipRect(hdc As IntPtr, nLeftRect As Integer, nTopRect As Integer, nRightRect As Integer, nBottomRect As Integer) As Integer
    End Function

    <StructLayout(LayoutKind.Sequential)>
    Public Structure NCCALCSIZE_PARAMS
        Public rgrc0, rgrc1, rgrc2 As RECT
        Public lppos As IntPtr
    End Structure

    <StructLayout(LayoutKind.Sequential)>
    Public Structure RECT
        Public Left As Integer
        Public Top As Integer
        Public Right As Integer
        Public Bottom As Integer

        Public Sub New(left As Integer, top As Integer, right As Integer, bottom As Integer)
            Me.Left = left
            Me.Top = top
            Me.Right = right
            Me.Bottom = bottom
        End Sub
    End Structure
End Class

Answer 5

Самый простой способ избавиться от 3D-границы - это установить другую:

richTextBox.BorderStyle = BorderStyle.FixedSingle;

В FixedSingle-BorderStyle наиболее близок к FlatStyle из, например,Кнопка