DrScheme против mzscheme:обращение с определениями

Question

Один долгосрочный проект, который у меня есть, - это проработка всех упражнений SICP.Я заметил кое-что немного странное в самом последнем упражнении.Я тестирую дерево кодирования Хаффмана.Когда я выполняю следующий код в DrScheme, я получаю ожидаемый результат:

(a d a b b c a)

Однако, если я выполняю этот же код в mzscheme, вызывая (load "2.67.scm") или запуская mzscheme -f 2.67.scm, он сообщает:

symbols: expected symbols as arguments, given: (leaf D 1) 

Мой вопрос заключается в следующем:почему?Это потому, что mzscheme и drscheme используют разные правила для загрузки определений программ?Программный код приведен ниже.

;; Define an encoding tree and a sample message
;; Use the decode procedure to decode the message, and give the result. 

(define (make-leaf symbol weight)
  (list 'leaf symbol weight))
(define (leaf? object)
  (eq? (car object) 'leaf))
(define (symbol-leaf x) (cadr x))
(define (weight-leaf x) (caddr x))

(define (make-code-tree left right)
  (list left
        right
        (append (symbols left) (symbols right))
        (+ (weight left) (weight right))))

(define (left-branch tree) (car tree))
(define (right-branch tree) (cadr tree))

(define (symbols tree)
  (if (leaf? tree)
      (list (symbol-leaf tree))
      (caddr tree)))
(define (weight tree)
  (if (leaf? tree)
      (weight-leaf tree)
      (cadddr tree)))

(define (decode bits tree)
  (define (decode-1 bits current-branch)
    (if (null? bits)
        '()
        (let ((next-branch
               (choose-branch (car bits) current-branch)))
          (if (leaf? next-branch)
              (cons (symbol-leaf next-branch)
                    (decode-1 (cdr bits) tree))
              (decode-1 (cdr bits) next-branch)))))
  (decode-1 bits tree))
(define (choose-branch bit branch)
  (cond ((= bit 0) (left-branch branch))
        ((= bit 1) (right-branch branch))
        (else (error "bad bit -- CHOOSE-BRANCH" bit))))

(define (test s-exp)
  (display s-exp)
  (newline))

(define sample-tree
  (make-code-tree (make-leaf 'A 4)
                  (make-code-tree
                   (make-leaf 'B 2)
                   (make-code-tree (make-leaf 'D 1)
                                   (make-leaf 'C 1)))))

(define sample-message '(0 1 1 0 0 1 0 1 0 1 1 1 0))

(test (decode sample-message sample-tree))

Answer 1

По умолчанию MzScheme запускается в режиме, в котором существует существующее определение для symbols, и он вводит функции , о которых он знает , - поэтому, когда он компилирует ваш make-code-tree определение, он использует привязку, о которой он знает.Когда он позже скомпилирует ваш symbols, это не оказывает влияния на предыдущее определение.

Самый простой способ справиться с этим - превратить ваш код в модуль, добавив к нему префикс #lang scheme.