Принудительная перерисовка TMainMenu при самостоятельной обработке WM_NCPAINT

Question

Я рисую свою строку заголовка в довольно большом приложении с множеством форм и решил попробовать сделать это старомодным способом, самостоятельно обрабатывая некоторые сообщения и используя рисунок, когда я обрабатываю WM_NCPAINT.

Сама картина идет неплохо и по существу работает.Однако есть одна вещь, которая не сработает — это рисование TMainMenu.Либо у меня есть обработчик WM_NCACTIVATE по умолчанию, который рисует всю неклиентскую область (мне нужно выполнить сообщение WM_NCACTIVATE внутри моего обработчика WM_NCPAINT), прежде чем закрашивать ее, что вызывает мерцание, с которым, по-видимому, ничего не поделаешь.Или я могу попытаться заставить обработчик WM_NCPAINT по умолчанию рисовать только Rect, содержащий TMainMenu, что приводит к плавному результату, но не перерисовывает меню.

Мой вопрос:

• Как я могу перерисовать TMainMenu и только TMainmenu, когда я сам обрабатываю WM_NCPAINT?

Я сделал несколько попыток и думаю, что нахожусь на правильном пути, но натыкаюсь на стену;У меня недостаточно знаний о том, что я делаю, и я не могу найти четкую документацию по этому поводу.Самая важная часть моего кода:

RedrawWindow(Handle, nil, MenuRegion, RDW_INVALIDATE or RDW_FRAME or RDW_NOERASE or RDW_ALLCHILDREN or RDW_UPDATENOW);

И я думаю, что именно это и идет не так.(вернее, код, в котором я вычисляю «MenuRegion».Я просто понятия не имею, происходит ли что-то не так, потому что я использую неправильную систему координат или потому, что я иду совершенно неправильным путем.

Вот сокращенная версия моего кода, которая будет компилироваться и запускаться «как есть» в Delphi (xe3):

unit Unit3;
interface
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.Menus;
type
  TForm3 = class(TForm)
  private
    FDrawMenu: Boolean;
    function CalcFrameRegion: HRGN;
    function CalcMenuRegion: HRGN;
    procedure DrawMenu;
    procedure FormFrame(minimal: Boolean = false);
    procedure WMNCActivate(var message: TWMNCActivate); message WM_NCACTIVATE;
    procedure WMNCPaint(var message: TMessage); message WM_NCPAINT;
    procedure WMSIZE(var message : TWMSIZE); message WM_SIZE;
    constructor Create(AOwner: TComponent); override;
  public
    { Public declarations }
  end;
var
  Form3: TForm3;
implementation
{$R *.dfm}
{ TForm3 }
function TForm3.CalcFrameRegion: HRGN;
var
  YCaption, YFrame, XFrame: Integer;
begin
  YCaption := GetSystemMetrics(SM_CYCaption);
  YFrame := GetSystemMetrics(SM_CYFRAME);
  XFrame := GetSystemMetrics(SM_CXFRAME);
  Result :=  CreateRectRgn(0, 0, YCaption + YFrame, Width);
  Result := Result +  CreateRectRgn(0, 0, Height, XFrame);
  Result := Result + CreateRectRgn(0, Height - YFrame, Width, Height);
  Result := Result + CreateRectRgn(Width - XFrame, 0, Width, Height);
end;
function TForm3.CalcMenuRegion: HRGN;
var
  XFrame, YFrame, YCaption, YMenu: Integer;
begin
  XFrame := GetSystemMetrics(SM_CXFRAME);
  YFrame := GetSystemMetrics(SM_CYFRAME);
  YCaption := GetSystemMetrics(SM_CYCAPTION);
  YMenu := GetSystemMetrics(SM_CYMENU);
  Result := CreateRectRgn(XFrame, YFrame + YCaption, Width - XFrame, YFrame + YCaption + YMenu);
end;
constructor TForm3.Create(AOwner: TComponent);
var
  testItem: TMenuItem;
begin
  inherited;
  // Creating a MainMenu and attatching it to the form.
  Menu := TMainMenu.Create(self);
  // The menu need san item.
  testItem := TMenuItem.Create(Menu);
  testItem.Caption := 'test';
  Menu.Items.Add(testItem);
  FDrawMenu := false;
end;
procedure TForm3.FormFrame(minimal: Boolean);
var
  YCaption, YFrame, XFrame: Integer;
begin
  YCaption := GetSystemMetrics(SM_CYCaption);
  YFrame := GetSystemMetrics(SM_CYFRAME);
  XFrame := GetSystemMetrics(SM_CXFRAME);
  Canvas.Handle := GetWindowDC(Handle);
  Canvas.Pen.Style := psClear;
  Canvas.Brush.Style := bsSolid;
  Canvas.Brush.Color := clRed;
  if not minimal then begin
    Canvas.Rectangle(0, 0, Width + 1, YCaption + YFRame + 1);
    Canvas.Rectangle(0, YCaption + YFRame, XFrame + 1, Height + 1);
    Canvas.Rectangle(XFrame, Height - YFrame, Width + 1, Height + 1);
    Canvas.Rectangle(Width - XFrame, YCaption + YFRame, Width + 1, Height - YFrame + 1);
  end;
end;
procedure TForm3.DrawMenu;
var
  MenuRegion: HRGN;
begin
  if Assigned(Menu) then begin
    MenuRegion := CalcMenuRegion;
    FDrawMenu := true; // Make sure the inherited handler gets called.
    // Force a redraw of the region defined by MenuRegion.
    RedrawWindow(Handle, nil, MenuRegion,
                  RDW_INVALIDATE or RDW_FRAME or RDW_NOERASE or RDW_ALLCHILDREN or RDW_UPDATENOW);
    FDrawMenu := false; // Use the FormFrame function again.
  end;
end;
procedure TForm3.WMNCActivate(var message: TWMNCActivate);
begin
  FormFrame;
  message.Result := 1; // This makes sure the message gets handled properly.
end;
procedure TForm3.WMNCPaint(var message: TMessage);
begin
  if FDrawMenu then
    inherited // Gets called when the Menu has to be drawn.
  else
    FormFrame; // Gets called in all other cases.
end;
procedure TForm3.WMSIZE(var message: TWMSIZE);
begin
  inherited;
  DrawMenu;
end;
end.

Answer 1

«Как я могу перерисовать TMainMenu и только TMainmenu, когда я сам обрабатываю WM_NCPAINT?»

Теоретически вы можете изменить регион WM_NCPAINT передается.Определите область, соответствующую области строки меню, оставив все остальное.Ниже приведено доказательство концепции:

procedure TForm3.WMNCPaint(var Message: TWMNCPaint);
var
  R: TRect;
  MenubarInfo: TMenuBarInfo;
  MenuRgn: HRGN;
begin
  FormFrame( whatever );

  MenubarInfo.cbSize := SizeOf(MenubarInfo);
  GetMenuBarInfo(Handle, OBJID_MENU, 0, MenubarInfo);

  MenuRgn := CreateRectRgnIndirect(MenubarInfo.rcBar);
  if Message.RGN <> 1 then
    DeleteObject(Message.RGN);
  Message.RGN := MenuRgn;

  inherited;
end;

На практике вы в конечном итоге откажетесь от этого маршрута.Обратите внимание на тест для «1» в приведенном выше примере.Псевдодескриптор региона обновления не упоминается в документация.Однако для обычного окна дескриптор региона всегда равен «1».На самом деле работа с неклиентами никогда должным образом не документировалась.Я предполагаю, что это потому, что сама ОС не играет по правилам.Возьмем, к примеру, тот факт, что область ЧПУ, окрашиваемая во время обработки по умолчанию, WM_NCACTIVATE.Какое отношение активация имеет к ЧПУ-покраске?Почему ОС красится за вашей спиной?

Я предлагаю пойти по пути, по которому пошли стили VCL.Как только вы начнете рисовать область NC, нарисуйте все это.Область строки меню является частью неклиентской области.