Как раскрасить cxgrid на основе значения таблицы?

StackOverflow https://stackoverflow.com/questions/6078715

  •  08-09-2020
  •  | 
  •  

Вопрос

Я бы хотел, чтобы все ряды, где присутствует в конкретном названии поля «привет», чтобы стать зеленым.Я попробовал это на customdrawcell:

if abstable1.fieldbyname('somename').asstring = 'Hello' then
  cxgrid.canvas.brush.color:=clGreen

Но это не сработает...что мне здесь не хватает?

Это было полезно?

Решение

Не пытайтесь изменить цвета холста в сетке.Скорее - и я нахожу это всегда быть правдой — изменить цвета в Видобработчик OnDrawCell, как в этом примере:

procedure T_fmTabSnapList.View1CustomDrawCell(Sender: TcxCustomGridTableView;
  ACanvas: TcxCanvas; AViewInfo: TcxGridTableDataCellViewInfo; var ADone: Boolean);
begin
  if abstable1.fieldbyname('somename').asstring = 'Hello' then 
    ACanvas.Brush.Color := clGreen
end;

cxGrid — это просто контейнер для представлений.Виды — это то место, где происходит вся картина.с

Другие советы

Используйте событие OnGetContentStyle для отдельных столбцов или объекта сетки.Со стилями гораздо проще работать, чем возиться с холстом.

Вам нужно просмотреть внутренние данные для каждой строки представления, а не данные текущей позиции в таблице.Также используйте холст, предоставленный в событии OnCustomDrawCell().

procedure TForm1.YourViewCustomDrawCell(
  Sender: TcxCustomGridTableView; ACanvas: TcxCanvas;
  AViewInfo: TcxGridTableDataCellViewInfo; var ADone: Boolean);
begin
  if(AViewInfo.GridRecord.Values[YourColumn.Index] = 'Hello') then
    ACanvas.Brush.Color := clGreen;
end;

procedure Tfm1.Grid1StylesGetContentStyle(Sender: TcxCustomGridTableView;
  ARecord: TcxCustomGridRecord; AItem: TcxCustomGridTableItem;
  out AStyle: TcxStyle);
Var
 Style1: TcxStyle;
begin
 if AItem = nil then exit;

 if ARecord.Values[Grid1Med.Index] = true then
   AStyle := cxStyleMed;

 if ARecord.Values[Grid1CP.Index] = true then
   AStyle := cxStyleHost;

 if (ARecord.Values[Grid1Med.Index] = true) and
    (ARecord.Values[Grid1CP.Index] = true) then
   AStyle := cxStyleHostAndCP;

  if not VarIsNull(ARecord.Values[colColor.Index]) then
  begin
    if not Assigned(AStyle) then
      AStyle := TcxStyle.Create(Sender);
    AStyle.Color := ARecord.Values[colColor.Index];
  end;
end;

Вот рабочий код моей программы, который делает нечто подобное.

procedure TDoDockets.grDocketsDrawColumnCell(Sender: TObject;
            const Rect: TRect; DataCol: Integer; Column: TColumn;
            State: TGridDrawState);
begin
 with grDockets do
  begin
   if (qDocketsOpenCost.asinteger > 1) and (datacol = 5)
    then canvas.font.color:= clRed;

   if datacol = 9 then // status
    if qDocketsColour.Value <> 0
     then Canvas.font.color:= tcolor (qDocketsColour.Value);

   if datacol = 10 then // attention
    if qDocketsAttention.asinteger = 1
     then canvas.brush.color:= clRed;

   if qDocketsUrgent.asinteger = 1 then canvas.brush.color:= 10092543;
   // light yellow
   DefaultDrawColumnCell (Rect, DataCol, Column, State);
  end
end;

grDockets — это сетка, а qDockets — это запрос, отображаемый в сетке.Определенные столбцы могут быть окрашены в другой цвет в зависимости от отображаемого значения, а в одном случае (qDocketsUrgent = 1) меняется цвет фона всей строки.

Лицензировано под: CC-BY-SA с атрибуция
Не связан с StackOverflow
scroll top