Как я могу передать аргументы в командный файл?
-
09-06-2019 - |
Вопрос
Мне нужно передать идентификатор и пароль командному файлу во время запуска, а не жестко кодировать их в файле.
Вот как выглядит командная строка:
test.cmd admin P@55w0rd > test-log.txt
Решение 2
Вот как я это сделал:
@fake-command /u %1 /p %2
Вот как выглядит команда:
test.cmd admin P@55w0rd > test-log.txt
Тот Самый %1
применяется к первому параметру следующее %2
(и вот самая сложная часть) относится ко второму.Таким образом, вы можете передать до 9 параметров.
Другие советы
Еще одним полезным советом является использование %*
что означает "все".Например:
echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*
Когда ты бежишь:
test-command admin password foo bar
приведенный выше пакетный файл будет запущен:
fake-command /u admin /p password admin password foo bar
Возможно, у меня немного неправильный синтаксис, но это общая идея.
Если вы хотите разумно обрабатывать недостающие параметры, вы можете сделать что-то вроде:
IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1
:No1
ECHO No param 1
GOTO End1
:No2
ECHO No param 2
GOTO End1
:End1
Доступ к параметрам пакета может быть простым с помощью %1, %2, ...%9 или также %*,
но только в том случае, если содержание простое.
Не существует простого способа для такого сложного содержимого, как "&"^&
, поскольку невозможно получить доступ к %1 без выдачи ошибки.
set var=%1
set "var=%1"
set var=%~1
set "var=%~1"
Линии расширяются до
set var="&"&
set "var="&"&"
set var="&"&
set "var="&"&"
И каждая строка терпит неудачу, так как одна из &
находится за пределами кавычек.
Это может быть решено с помощью чтения из временного файла a замеченный версия параметра.
@echo off
SETLOCAL DisableDelayedExpansion
SETLOCAL
for %%a in (1) do (
set "prompt="
echo on
for %%b in (1) do rem * #%1#
@echo off
) > param.txt
ENDLOCAL
for /F "delims=" %%L in (param.txt) do (
set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'
Хитрость заключается в том, чтобы включить echo on
и расширьте значение %1 после rem
оператор (работает также с %2 .. %*
).
Так что даже "&"&
как уже отмечалось, это может быть повторено без ошибки.
Но для того, чтобы иметь возможность перенаправлять выходные данные echo on
, вам понадобятся два цикла for.
Дополнительные символы * #
используются для защиты от такого содержимого, как /?
(показал бы справку для REM
).
Или символ каретки ^ в конце строки может работать как многострочный символ, даже после rem
.
Затем, читая параметр rem выводите данные из файла, но осторожно.
FOR / F должен работать с отключенным отложенным расширением, иначе содержимое с "!" было бы уничтожено.
После удаления лишних символов в param1
, - ты все понял.
И использовать param1
безопасным способом является включение отложенного расширения.
Да, и просто не забывайте использовать такие переменные, как %%1
при использовании if
и for
и вся банда.
Если ты забудешь о двойном %
, затем вы будете подставлять в (возможно, нулевые) аргументы командной строки и получите несколько довольно запутанных сообщений об ошибках.
Нет необходимости все усложнять.Это просто параметры команды %1 %2, например,
@echo off
xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z
echo copied %1 to %2
pause
Кнопка "пауза" отображает, что сделал пакетный файл, и ожидает, пока вы нажмете клавишу ANY.Сохраните это как xx.bat в папке Windows.
Чтобы использовать его, введите, например:
xx c:\f\30\*.* f:\sites\30
Этот пакетный файл заботится обо всех необходимых параметрах, таких как копирование только более новых файлов и т.д.Я использовал его еще до появления Windows.Если вам нравится видеть названия файлов по мере их копирования, не указывайте Q
параметр.
@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue
Примечание:ЕСЛИ "%1"==""
вызовет проблемы, если %1
сам заключен в кавычки.
В этом случае используйте IF [%1]==[]
или только в NT 4 (SP6) и более поздних версиях, IF "%~1"==""
вместо этого.
Недавно друг спрашивал меня на эту тему, поэтому я решил опубликовать, как я обрабатываю аргументы командной строки в пакетных файлах.
Как вы увидите, этот метод сопряжен с небольшими накладными расходами, но он делает мои пакетные файлы очень простыми для понимания и быстрой реализации.А также поддерживать следующие структуры:
>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]
Суть этого в том, что у него есть :init
, :parse
, и :main
функции.
Пример использования
>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
USAGE:
test.bat [flags] "required argument" "optional argument"
/?, --help shows this help
/v, --version shows the version
/e, --verbose shows detailed output
-f, --flag value specifies a named parameter value
>template.bat <- throws missing argument error
(same as /?, plus..)
**** ****
**** MISSING "REQUIRED ARGUMENT" ****
**** ****
>template.bat -v
1.23
>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument: "arg1"
UnNamedOptionalArg: not provided
NamedFlag: not provided
>template.bat --flag "my flag" arg1 arg2
UnNamedArgument: "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag: "my flag"
>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument: "argument #1"
UnNamedOptionalArg: "second"
NamedFlag: "my flag"
шаблон.bat
@::!/dos/rocks
@echo off
goto :init
:header
echo %__NAME% v%__VERSION%
echo This is a sample batch file template,
echo providing command-line arguments and flags.
echo.
goto :eof
:usage
echo USAGE:
echo %__BAT_NAME% [flags] "required argument" "optional argument"
echo.
echo. /?, --help shows this help
echo. /v, --version shows the version
echo. /e, --verbose shows detailed output
echo. -f, --flag value specifies a named parameter value
goto :eof
:version
if "%~1"=="full" call :header & goto :eof
echo %__VERSION%
goto :eof
:missing_argument
call :header
call :usage
echo.
echo **** ****
echo **** MISSING "REQUIRED ARGUMENT" ****
echo **** ****
echo.
goto :eof
:init
set "__NAME=%~n0"
set "__VERSION=1.23"
set "__YEAR=2017"
set "__BAT_FILE=%~0"
set "__BAT_PATH=%~dp0"
set "__BAT_NAME=%~nx0"
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedOptionalArg="
set "NamedFlag="
:parse
if "%~1"=="" goto :validate
if /i "%~1"=="/?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="-?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="--help" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="/v" call :version & goto :end
if /i "%~1"=="-v" call :version & goto :end
if /i "%~1"=="--version" call :version full & goto :end
if /i "%~1"=="/e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="-e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--verbose" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--flag" set "NamedFlag=%~2" & shift & shift & goto :parse
if not defined UnNamedArgument set "UnNamedArgument=%~1" & shift & goto :parse
if not defined UnNamedOptionalArg set "UnNamedOptionalArg=%~1" & shift & goto :parse
shift
goto :parse
:validate
if not defined UnNamedArgument call :missing_argument & goto :end
:main
if defined OptVerbose (
echo **** DEBUG IS ON
)
echo UnNamedArgument: "%UnNamedArgument%"
if defined UnNamedOptionalArg echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
if not defined UnNamedOptionalArg echo UnNamedOptionalArg: not provided
if defined NamedFlag echo NamedFlag: "%NamedFlag%"
if not defined NamedFlag echo NamedFlag: not provided
:end
call :cleanup
exit /B
:cleanup
REM The cleanup function is only really necessary if you
REM are _not_ using SETLOCAL.
set "__NAME="
set "__VERSION="
set "__YEAR="
set "__BAT_FILE="
set "__BAT_PATH="
set "__BAT_NAME="
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedArgument2="
set "NamedFlag="
goto :eof
Давайте сделаем это проще.
Вот файл .cmd.
@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%
Вот 3 вызова из командной строки.
C:\Users\joeco>echo_3params 1abc 2 def 3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def
C:\Users\joeco>echo_3params 1abc "2 def" "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"
C:\Users\joeco>echo_3params 1abc '2 def' "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'
C:\Users\joeco>
FOR %%A IN (%*) DO (
REM Now your batch file handles %%A instead of %1
REM No need to use SHIFT anymore.
ECHO %%A
)
Это перебирает параметры пакета (%*), заключены они в кавычки или нет, затем отображает каждый параметр.
Я написал простой скрипт read_params, который может быть вызван как функция (или внешняя .bat
) и поместит все переменные в текущую среду.Это не изменит исходные параметры, потому что функция выполняется call
отредактировано с копией исходных параметров.
Например, дана следующая команда:
myscript.bat some -random=43 extra -greeting="hello world" fluff
myscript.bat
смог бы использовать переменные после вызова функции:
call :read_params %*
echo %random%
echo %greeting%
Вот эта функция:
:read_params
if not %1/==/ (
if not "%__var%"=="" (
if not "%__var:~0,1%"=="-" (
endlocal
goto read_params
)
endlocal & set %__var:~1%=%~1
) else (
setlocal & set __var=%~1
)
shift
goto read_params
)
exit /B
Ограничения
- Невозможно загрузить аргументы без значения, такие как
-force
.Вы могли бы использовать-force=true
но я не могу придумать способ разрешить пустые значения, не зная заранее список параметров, которые не будут иметь значения.
Журнал изменений
- 2/18/2016
- Больше не требует отложенного расширения
- Теперь работает с другими аргументами командной строки, ища
-
перед параметрами.
Чтобы обратиться к переменной set в командной строке, вам нужно будет использовать %a%
так, например:
set a=100
echo %a%
rem output = 100
Примечание:Это работает для Windows 7 pro.
Создайте новый пакетный файл (пример:openclass.bat) и запишите эту строку в файл:
java %~n1
Затем поместите пакетный файл, скажем, в папку system32, перейдите в свой файл класса Java, щелкните правой кнопкой мыши "Свойства", откройте с помощью ..., затем найдите свой пакетный файл, выберите его, и все...
У меня это работает.
PS:Я не могу найти способ закрыть окно cmd, когда я закрываю класс Java.На данный момент...
Вдохновленный отвечайте в другом месте автор: @Jon, я разработал более общий алгоритм для извлечения именованных параметров, необязательных значений и переключателей.
Допустим, мы хотим реализовать утилиту foobar
.Для этого требуется начальная команда.У него есть необязательный параметр --foo
который требует необязательно значение (которое, конечно, не может быть другим параметром);если значение отсутствует, то по умолчанию оно равно default
.Он также имеет необязательный параметр --bar
который требует требуемый ценность.Наконец, для этого может потребоваться флаг --baz
без допустимого значения.О, и эти параметры могут располагаться в любом порядке.
Другими словами, это выглядит примерно так:
foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]
Вот такое решение:
@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson
SET CMD=%~1
IF "%CMD%" == "" (
GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=
SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
SHIFT
IF NOT "%ARG%" == "" (
IF NOT "%ARG:~0,2%" == "--" (
SET FOO=%ARG%
SHIFT
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE IF "%PARAM%" == "--bar" (
SHIFT
IF NOT "%ARG%" == "" (
SET BAR=%ARG%
SHIFT
) ELSE (
ECHO Missing bar value. 1>&2
ECHO:
GOTO usage
)
) ELSE IF "%PARAM%" == "--baz" (
SHIFT
SET BAZ=true
) ELSE IF "%PARAM%" == "" (
GOTO endargs
) ELSE (
ECHO Unrecognized option %1. 1>&2
ECHO:
GOTO usage
)
GOTO args
:endargs
ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
ECHO Baz
)
REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof
:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1
- Использование
SETLOCAL
чтобы переменные не попадали в вызывающую среду. - Не забудьте инициализировать переменные
SET FOO=
, и т.д.на случай, если кто-то определил их в вызывающей среде. - Использование
%~1
чтобы убрать кавычки. - Использование
IF "%ARG%" == ""
и неIF [%ARG%] == []
потому что[
и]
вообще не играйте в will со значениями, заканчивающимися пробелом. - Даже если ты
SHIFT
внутриIF
блокируйте текущие аргументы, такие как%~1
не обновляются, потому что они определяются, когдаIF
анализируется.Вы могли бы использовать%~1
и%~2
внутриIF
блокировать, но это сбивало бы с толку, потому что у вас былSHIFT
.Вы могли бы поместитьSHIFT
в конце блока для ясности, но это также может затеряться и / или сбить людей с толку.Итак, "захват"%~1
и%~1
лучше всего кажется выйти за пределы квартала. - Вы не хотите использовать параметр вместо необязательного значения другого параметра, поэтому вам нужно проверить
IF NOT "%ARG:~0,2%" == "--"
. - Будьте осторожны только с тем, чтобы
SHIFT
когда ты использование один из параметров. - Дублирующий код
SET FOO=%DEFAULT_FOO%
прискорбно, но альтернативой было бы добавитьIF "%FOO%" == "" SET FOO=%DEFAULT_FOO%
за пределамиIF NOT "%ARG%" == ""
блок.Однако, поскольку это все еще находится внутриIF "%PARAM%" == "--foo"
блок, тот самый%FOO%
значение было бы оценено и установлено еще до того, как вы вошли в блок, так что вы никогда бы этого не обнаружили и то , и другое тот самый--foo
параметр присутствовал а также что тот%FOO%
значение отсутствовало. - Обратите внимание , что
ECHO Missing bar value. 1>&2
отправляет сообщение об ошибке в stderr. - Нужна пустая строка в пакетном файле Windows?Ты должен использовать
ECHO:
или одна из вариаций.
Простое решение (даже если вопрос старый)
Тест1.летучая мышь
echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause
CallTest1.bat
call "C:\Temp\Test1.bat" pass123
выходной сигнал
YourLocalPath>call "C:\Temp\test.bat" pass123
YourLocalPath>echo off
"Batch started"
"arg1 is pass123"
YourLocalPath>pause
Press any key to continue . . .
Где YourLocalPath - это текущий путь к каталогу.
Чтобы упростить задачу, сохраните параметр команды в переменной и используйте переменную для сравнения.
Его не только просто написать, но и просто поддерживать, поэтому, если позже кто-то другой или вы прочтете ваш скрипт спустя длительный промежуток времени, его будет легко понять и поддерживать.
Для написания встроенного кода :смотрите другие ответы.
Для использования цикла получаем все аргументы и в чистом пакетном режиме:
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
)
goto :eof
Ваш код готов сделать что-то с номером аргумента там, где ему нужно, например...
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift
)
fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt