Как мне продублировать целую строку в Emacs?
Вопрос
Я видел тот же вопрос для VIM и я сам хотел узнать, как это сделать для Emacs.В ReSharper для этого действия я использую CTRL-D.Каково наименьшее количество команд для выполнения этого в Emacs?
Решение
я использую
C-a C-SPACE C-n M-w C-y
который распадается на
C-a
:переместить курсор в начало строкиC-SPACE
:начать выделение («установить отметку»)C-n
:переместить курсор на следующую строкуM-w
:копировать регионC-y
:вставить («выдернуть»)
Вышеупомянутое
C-a C-k C-k C-y C-y
означает то же самое (TMTOWTDI)
C-a
:переместить курсор в начало строкиC-k
:перерезать («убить») линиюC-k
:вырезать новую строкуC-y
:вставить («выдернуть») (мы вернулись к исходной точке)C-y
:вставьте еще раз (теперь у нас есть две копии строки)
Оба они ошеломляюще многословны по сравнению с C-d
в вашем редакторе, но в Emacs всегда есть возможность настройки. C-d
связан с delete-char
по умолчанию, так как насчет C-c C-d
?Просто добавьте следующее в свой .emacs
:
(global-set-key "\C-c\C-d" "\C-a\C- \C-n\M-w\C-y")
(@Версия elisp Натана, вероятно, предпочтительнее, потому что она не сломается, если изменить какие-либо привязки клавиш.)
Остерегаться:некоторые режимы Emacs могут вернуть C-c C-d
сделать что-то еще.
Другие советы
В дополнение к предыдущим ответам вы также можете определить свою собственную функцию для дублирования строки.Например, если поместить следующее в ваш файл .emacs, C-d продублирует текущую строку.
(defun duplicate-line()
(interactive)
(move-beginning-of-line 1)
(kill-line)
(yank)
(open-line 1)
(next-line 1)
(yank)
)
(global-set-key (kbd "C-d") 'duplicate-line)
Поместите курсор на строку, если не в начале, выполните CTRL-А, затем:
CTRL-К
CTRL-К
CTRL-Да
CTRL-Да
Моя версия функции для дублирования строки, которая хорошо работает с отменой и не влияет на положение курсора.Это был результат обсуждение в gnu.emacs.sources с ноября 1997 г..
(defun duplicate-line (arg)
"Duplicate current line, leaving point in lower line."
(interactive "*p")
;; save the point for undo
(setq buffer-undo-list (cons (point) buffer-undo-list))
;; local variables for start and end of line
(let ((bol (save-excursion (beginning-of-line) (point)))
eol)
(save-excursion
;; don't use forward-line for this, because you would have
;; to check whether you are at the end of the buffer
(end-of-line)
(setq eol (point))
;; store the line and disable the recording of undo information
(let ((line (buffer-substring bol eol))
(buffer-undo-list t)
(count arg))
;; insert the line arg times
(while (> count 0)
(newline) ;; because there is no newline in 'line'
(insert line)
(setq count (1- count)))
)
;; create the undo information
(setq buffer-undo-list (cons (cons eol (point)) buffer-undo-list)))
) ; end-of-let
;; put the point in the lowest line and return
(next-line arg))
Затем вы можете определить CTRL-D для вызова этой функции:
(global-set-key (kbd "C-d") 'duplicate-line)
Вместо kill-line
(C-k
) как в C-a
C-k
C-k
C-y
C-y
использовать kill-whole-line
команда:
C-S-Backspace
C-y
C-y
Преимущества перед C-k
укажите, что не имеет значения, где находится точка на линии (в отличие от C-k
который требует находиться в начале строки), а также убивает новую строку (опять что-то C-k
не делает).
Вот еще одна функция для этого.Моя версия не затрагивает кольцо уничтожения, и курсор оказывается на новой строке, где он был в оригинале.Он будет дублировать регион, если он активен (режим временной метки), или по умолчанию дублирует строку в противном случае.Он также сделает несколько копий, если ему присвоен префикс arg, и закомментирует исходную строку, если ему присвоен отрицательный префикс arg (это полезно для тестирования другой версии команды/оператора, сохраняя при этом старую).
(defun duplicate-line-or-region (&optional n)
"Duplicate current line, or region if active.
With argument N, make N copies.
With negative N, comment out original line and use the absolute value."
(interactive "*p")
(let ((use-region (use-region-p)))
(save-excursion
(let ((text (if use-region ;Get region if active, otherwise line
(buffer-substring (region-beginning) (region-end))
(prog1 (thing-at-point 'line)
(end-of-line)
(if (< 0 (forward-line 1)) ;Go to beginning of next line, or make a new one
(newline))))))
(dotimes (i (abs (or n 1))) ;Insert N times, or once if not specified
(insert text))))
(if use-region nil ;Only if we're working with a line (not a region)
(let ((pos (- (point) (line-beginning-position)))) ;Save column
(if (> 0 n) ;Comment out original with negative arg
(comment-region (line-beginning-position) (line-end-position)))
(forward-line 1)
(forward-char pos)))))
у меня это связано с C-c d
:
(global-set-key [?\C-c ?d] 'duplicate-line-or-region)
Это никогда не должно быть переназначено режимом или чем-то еще, потому что C-c
за которым следует одна (немодифицированная) буква, зарезервированная для пользовательских привязок.
Добавление Натана в ваш файл .emacs — это правильный путь, но его можно немного упростить, заменив
(open-line 1)
(next-line 1)
с
(newline)
уступчивость
(defun duplicate-line()
(interactive)
(move-beginning-of-line 1)
(kill-line)
(yank)
(newline)
(yank)
)
(global-set-key (kbd "C-d") 'duplicate-line)
Я не совсем помню, как где-либо еще работает дублирование строк, но мне, как бывшему пользователю SciTE, в SciTE-way понравилось одно:он не касается позиции курсора!Так что все приведенные выше рецепты мне не подошли, вот моя хиппи-версия:
(defun duplicate-line ()
"Clone line at cursor, leaving the latter intact."
(interactive)
(save-excursion
(let ((kill-read-only-ok t) deactivate-mark)
(toggle-read-only 1)
(kill-whole-line)
(toggle-read-only 0)
(yank))))
Обратите внимание, что в процессе ничего не уничтожается, оставляя метки и текущий выбор нетронутыми.
Кстати, почему вы, ребята, так любите дергать курсор, когда есть эта милая и чистая штука с уничтожением всей строки (CS-backspace)?
установить дубликат из Melpa:
M-x package-install RET дубликат-вещь
и добавьте эту привязку клавиш в инициализирующий файл :
(глобальный-set-key (kbd "M-c") 'дубликат-вещь)
потому что я не знаю, я начну этот раунд игры в гольф с слоуболла:
Ctrl-K, й, й
«Я написал свою версию duplicate-line
, потому что я не хочу испортить кольцо убийств.
(defun jr-duplicate-line ()
"EASY"
(interactive)
(save-excursion
(let ((line-text (buffer-substring-no-properties
(line-beginning-position)
(line-end-position))))
(move-end-of-line 1)
(newline)
(insert line-text))))
(global-set-key "\C-cd" 'jr-duplicate-line)
У меня есть copy-from-above-command
привязан к ключу и используйте его.Он поставляется с XEmacs, но я ничего не знаю о GNU Emacs.
`Копия из-за колледжа '-это интерактивная компилированная функция LISP
-Загружено из "/usr/share/xemacs/21.4.15/lisp/misc.elc" (Copy-from-above-command & Необязательный Arg)Документация: Скопировать символы из предыдущей неблеки, начиная чуть выше точки.Скопируйте символы ARG, но не после конца этой строки.Если не указан аргумент, скопируйте всю оставшуюся строку.Копированные персонажи вставлены в буфере перед точкой.
C-a C-k C-k C-y C-y
что-то, что вы, возможно, захотите иметь в своем .emacs, это
(setq kill-whole-line t)
По сути, это убивает всю строку плюс новую строку всякий раз, когда вы вызываете строку уничтожения (т.е.через C-k).Тогда без дополнительного кода вы можете просто выполнить C-a C-k C-y C-y, чтобы дублировать строку.Он распадается на
C-a go to beginning of line
C-k kill-line (i.e. cut the line into clipboard)
C-y yank (i.e. paste); the first time you get the killed line back;
second time gives the duplicated line.
Но если вы используете это часто, то, возможно, лучше использовать специальную привязку клавиш, но преимущество простого использования C-a C-k C-y C-y заключается в том, что вы можете дублировать строку в другом месте, а не чуть ниже текущей строки.
Значения по умолчанию для этого ужасны.Однако вы можете расширить Emacs, чтобы он работал как SlickEdit и TextMate, то есть копировать/вырезать текущую строку, когда текст не выделен:
(transient-mark-mode t)
(defadvice kill-ring-save (before slick-copy activate compile)
"When called interactively with no active region, copy a single line instead."
(interactive
(if mark-active (list (region-beginning) (region-end))
(message "Copied line")
(list (line-beginning-position)
(line-beginning-position 2)))))
(defadvice kill-region (before slick-cut activate compile)
"When called interactively with no active region, kill a single line instead."
(interactive
(if mark-active (list (region-beginning) (region-end))
(list (line-beginning-position)
(line-beginning-position 2)))))
Поместите вышеизложенное в .emacs
.Затем, чтобы скопировать строку, M-w
.Чтобы удалить строку, C-w
.Чтобы дублировать строку, C-a M-w C-y C-y C-y ...
.
Версия FraGGod мне понравилась, за исключением двух моментов:(1) Он не проверяет, доступен ли буфер только для чтения с помощью (interactive "*")
, и (2) происходит сбой в последней строке буфера, если эта последняя строка пуста (поскольку в этом случае вы не можете уничтожить строку), оставляя ваш буфер доступным только для чтения.
Чтобы решить эту проблему, я внес следующие изменения:
(defun duplicate-line ()
"Clone line at cursor, leaving the latter intact."
(interactive "*")
(save-excursion
;; The last line of the buffer cannot be killed
;; if it is empty. Instead, simply add a new line.
(if (and (eobp) (bolp))
(newline)
;; Otherwise kill the whole line, and yank it back.
(let ((kill-read-only-ok t)
deactivate-mark)
(toggle-read-only 1)
(kill-whole-line)
(toggle-read-only 0)
(yank)))))
В последних версиях emacs вы можете использовать M-w в любом месте строки, чтобы скопировать его.Итак, получается:
M-w C-a RET C-y
Во всяком случае, я видел очень сложные решения...
(defun duplicate-line ()
"Duplicate current line"
(interactive)
(kill-whole-line)
(yank)
(yank))
(global-set-key (kbd "C-x M-d") 'duplicate-line)
Есть пакет под названием Ави У него есть команда avy-copy-line.Когда вы используете эту команду, каждая строка в вашем окне получает комбинацию букв.Затем вам просто нужно ввести комбинацию, и вы получите эту строку.Это также работает для региона.Тогда вам просто нужно ввести две комбинации.
Здесь вы можете увидеть интерфейс:
@[Кевин Коннер]:Насколько я знаю, довольно близко.Единственное, что следует учитывать, это включение kill-whole-line
чтобы включить новую строку в C-k.
При интерактивном вызове без активной области вместо этого КОПИРУЙТЕ (M-w) одну строку:
(defadvice kill-ring-save (before slick-copy activate compile)
"When called interactively with no active region, COPY a single line instead."
(interactive
(if mark-active (list (region-beginning) (region-end))
(message "Copied line")
(list (line-beginning-position)
(line-beginning-position 2)))))
При интерактивном вызове без активной области вместо этого используйте KILL (C-w) одну строку.
(defadvice kill-region (before slick-cut activate compile)
"When called interactively with no active region, KILL a single line instead."
(interactive
(if mark-active (list (region-beginning) (region-end))
(message "Killed line")
(list (line-beginning-position)
(line-beginning-position 2)))))
Также по соответствующей заметке:
(defun move-line-up ()
"Move up the current line."
(interactive)
(transpose-lines 1)
(forward-line -2)
(indent-according-to-mode))
(defun move-line-down ()
"Move down the current line."
(interactive)
(forward-line 1)
(transpose-lines 1)
(forward-line -1)
(indent-according-to-mode))
(global-set-key [(meta shift up)] 'move-line-up)
(global-set-key [(meta shift down)] 'move-line-down)
Ctrl-к, Ctrl-к, (положение на новое место) Ctrl-й
Добавить Ctrl-а если вы не начинаете с начала строки.И 2-й Ctrl-к состоит в том, чтобы захватить символ новой строки.Его можно удалить, если вам нужен только текст.
Я пишу один по своему усмотрению.
(defun duplicate-line ()
"Duplicate current line."
(interactive)
(let ((text (buffer-substring-no-properties (point-at-bol) (point-at-eol)))
(cur-col (current-column)))
(end-of-line) (insert "\n" text)
(beginning-of-line) (right-char cur-col)))
(global-set-key (kbd "C-c d l") 'duplicate-line)
Но я обнаружил, что могут возникнуть проблемы, если текущая строка содержит многобайтовые символы (например,символы CJK).Если вы столкнулись с этой проблемой, попробуйте следующее:
(defun duplicate-line ()
"Duplicate current line."
(interactive)
(let* ((text (buffer-substring-no-properties (point-at-bol) (point-at-eol)))
(cur-col (length (buffer-substring-no-properties (point-at-bol) (point)))))
(end-of-line) (insert "\n" text)
(beginning-of-line) (right-char cur-col)))
(global-set-key (kbd "C-c d l") 'duplicate-line)
Эта функциональность должна соответствовать реализации JetBrains с точки зрения дублирования как по строке, так и по региону, а затем оставить точку и/или активную область, как ожидалось:
Просто оболочка вокруг интерактивной формы:
(defun wrx/duplicate-line-or-region (beg end)
"Implements functionality of JetBrains' `Command-d' shortcut for `duplicate-line'.
BEG & END correspond point & mark, smaller first
`use-region-p' explained:
http://emacs.stackexchange.com/questions/12334/elisp-for-applying-command-to-only-the-selected-region#answer-12335"
(interactive "r")
(if (use-region-p)
(wrx/duplicate-region-in-buffer beg end)
(wrx/duplicate-line-in-buffer)))
Который называет это,
(defun wrx/duplicate-region-in-buffer (beg end)
"copy and duplicate context of current active region
|------------------------+----------------------------|
| before | after |
|------------------------+----------------------------|
| first <MARK>line here | first line here |
| second item<POINT> now | second item<MARK>line here |
| | second item<POINT> now |
|------------------------+----------------------------|
TODO: Acts funky when point < mark"
(set-mark-command nil)
(insert (buffer-substring beg end))
(setq deactivate-mark nil))
Или это
(defun wrx/duplicate-line-in-buffer ()
"Duplicate current line, maintaining column position.
|--------------------------+--------------------------|
| before | after |
|--------------------------+--------------------------|
| lorem ipsum<POINT> dolor | lorem ipsum dolor |
| | lorem ipsum<POINT> dolor |
|--------------------------+--------------------------|
TODO: Save history for `Cmd-Z'
Context:
http://stackoverflow.com/questions/88399/how-do-i-duplicate-a-whole-line-in-emacs#answer-551053"
(setq columns-over (current-column))
(save-excursion
(kill-whole-line)
(yank)
(yank))
(let (v)
(dotimes (n columns-over v)
(right-char)
(setq v (cons n v))))
(next-line))
И тогда у меня есть привязка к мета+shift+d
(global-set-key (kbd "M-D") 'wrx/duplicate-line-or-region)
С префиксными аргументами и (надеюсь) интуитивно понятным поведением:
(defun duplicate-line (&optional arg)
"Duplicate it. With prefix ARG, duplicate ARG times."
(interactive "p")
(next-line
(save-excursion
(let ((beg (line-beginning-position))
(end (line-end-position)))
(copy-region-as-kill beg end)
(dotimes (num arg arg)
(end-of-line) (newline)
(yank))))))
Курсор останется на последней строке.В качестве альтернативы вы можете указать префикс для одновременного дублирования следующих нескольких строк:
(defun duplicate-line (&optional arg)
"Duplicate it. With prefix ARG, duplicate ARG times."
(interactive "p")
(save-excursion
(let ((beg (line-beginning-position))
(end
(progn (forward-line (1- arg)) (line-end-position))))
(copy-region-as-kill beg end)
(end-of-line) (newline)
(yank)))
(next-line arg))
Я часто использую оба варианта, используя функцию-оболочку для переключения поведения аргумента префикса.
И привязка клавиш:(global-set-key (kbd "C-S-d") 'duplicate-line)
;; http://www.emacswiki.org/emacs/WholeLineOrRegion#toc2
;; cut, copy, yank
(defadvice kill-ring-save (around slick-copy activate)
"When called interactively with no active region, copy a single line instead."
(if (or (use-region-p) (not (called-interactively-p)))
ad-do-it
(kill-new (buffer-substring (line-beginning-position)
(line-beginning-position 2))
nil '(yank-line))
(message "Copied line")))
(defadvice kill-region (around slick-copy activate)
"When called interactively with no active region, kill a single line instead."
(if (or (use-region-p) (not (called-interactively-p)))
ad-do-it
(kill-new (filter-buffer-substring (line-beginning-position)
(line-beginning-position 2) t)
nil '(yank-line))))
(defun yank-line (string)
"Insert STRING above the current line."
(beginning-of-line)
(unless (= (elt string (1- (length string))) ?\n)
(save-excursion (insert "\n")))
(insert string))
(global-set-key (kbd "<f2>") 'kill-region) ; cut.
(global-set-key (kbd "<f3>") 'kill-ring-save) ; copy.
(global-set-key (kbd "<f4>") 'yank) ; paste.
добавьте приведенный выше elisp в свой init.el, и теперь вы получите функцию вырезания/копирования всей строки, затем вы можете F3 F4, чтобы дублировать строку.
Самый простой способ — метод Криса Конвея.
C-a C-SPACE C-n M-w C-y
Это стандартный способ, предусмотренный EMACS.На мой взгляд, лучше использовать стандартный.Я всегда с осторожностью отношусь к настройке собственных привязок клавиш в EMACS.EMACS уже достаточно мощный инструмент, я думаю, нам следует приложить все усилия, чтобы адаптироваться к его собственным сочетаниям клавиш.
Хотя это немного длинно, но когда вы к этому привыкнете, вы сможете делать это быстро и найдете это забавным!
Вот функция для дублирования текущей строки.С аргументами-префиксами строка будет дублироваться несколько раз.Например., C-3 C-S-o
продублирует текущую строку три раза.Не меняет кольцо убийства.
(defun duplicate-lines (arg)
(interactive "P")
(let* ((arg (if arg arg 1))
(beg (save-excursion (beginning-of-line) (point)))
(end (save-excursion (end-of-line) (point)))
(line (buffer-substring-no-properties beg end)))
(save-excursion
(end-of-line)
(open-line arg)
(setq num 0)
(while (< num arg)
(setq num (1+ num))
(forward-line 1)
(insert-string line))
)))
(global-set-key (kbd "C-S-o") 'duplicate-lines)
Я не могу поверить во все эти сложные решения.Это два нажатия клавиш:
<C-S-backspace>
запускает команду kill-whole-line
C-/
запускает команду отмены
Так <C-S-backspace> C-/
«скопировать» целую строку (убить и отменить).
Конечно, вы можете комбинировать это с числовыми и отрицательными аргументами, чтобы уничтожить несколько строк вперед или назад.
Это кажется более естественным по отношению к выбранному ответу Криса Конвея.
(global-set-key "\C-c\C-d" "\C-a\C- \C-n\M-w\C-y\C-p\C-e")
Это позволяет вам дублировать строку несколько раз, просто повторяя нажатия клавиш \C-c\C-d.