Пакетные команды Windows для чтения первой строки из текстового файла

Question

Как я могу прочитать первую строку из текстового файла с помощью пакетного файла Windows?Поскольку файл большой, я хочу иметь дело только с первой строкой.

Answer 1

Вот пакетный файл общего назначения для печати верхнего n строки из файла, подобного GNU head утилита, а не просто одна строка.

@echo off

if [%1] == [] goto usage
if [%2] == [] goto usage

call :print_head %1 %2
goto :eof

REM
REM print_head
REM Prints the first non-blank %1 lines in the file %2.
REM
:print_head
setlocal EnableDelayedExpansion
set /a counter=0

for /f ^"usebackq^ eol^=^

^ delims^=^" %%a in (%2) do (
        if "!counter!"=="%1" goto :eof
        echo %%a
        set /a counter+=1
)

goto :eof

:usage
echo Usage: head.bat COUNT FILENAME

Например:

Z:\>head 1 "test file.c"
; this is line 1

Z:\>head 3 "test file.c"
; this is line 1
    this is line 2
line 3 right here

В настоящее время он не учитывает пустые строки.На него также распространяется ограничение длины строки пакетного файла в 8 КБ.

Answer 2

эээ?имо, это намного проще

  set /p texte=< file.txt  
  echo %texte%

Answer 3

Э-э, вы, ребята...

C:\>findstr /n . c:\boot.ini | findstr ^1:

1:[boot loader]

C:\>findstr /n . c:\boot.ini | findstr ^3:

3:default=multi(0)disk(0)rdisk(0)partition(1)\WINNT

C:\>

Answer 4

Вы могли бы попробовать это сделать:

@echo off

for /f %%a in (sample.txt) do (
  echo %%a
  exit /b
)

Редактировать Или, допустим, у вас есть четыре столбца данных и вы хотите перейти от 5-й строки к нижней, попробуйте следующее:

@echo off

for /f "skip=4 tokens=1-4" %%a in (junkl.txt) do (
  echo %%a %%b %%c %%d
)

Answer 5

Спасибо thetalkingwalnut за ответ Пакетные команды Windows для чтения первой строки из текстового файла Я пришел к следующему решению:

@echo off
for /f "delims=" %%a in ('type sample.txt') do (
echo %%a
exit /b
)

Answer 6

Немного опираясь на ответы других людей.Теперь это позволяет вам указать файл, из которого вы хотите прочитать, и переменную, в которую вы хотите поместить результат:

@echo off
for /f "delims=" %%x in (%2) do (
set %1=%%x
exit /b
)

Это означает, что вы можете использовать приведенное выше вот так (предполагая, что вы назвали это getline.bat)

c:\> dir > test-file
c:\> getline variable test-file
c:\> set variable  
variable= Volume in drive C has no label.

Answer 7

Одна строка, полезная для перенаправления стандартного вывода с помощью ">":

@for /f %%i in ('type yourfile.txt') do @echo %%i & exit

Answer 8

Попробуй это

@echo off
setlocal enableextensions enabledelayedexpansion
set firstLine=1
for /f "delims=" %%i in (yourfilename.txt) do (
    if !firstLine!==1 echo %%i
    set firstLine=0
)
endlocal

Answer 9

Проблема с EXIT /B решения, когда более реалистично использовать пакетный файл как только одну его часть, заключаются в следующем.Последующая обработка в указанном пакетном файле после завершения EXIT /B.Обычно в пакетах содержится гораздо больше, чем просто одна ограниченная задача.

Чтобы противостоять этой проблеме:

@echo off & setlocal enableextensions enabledelayedexpansion
set myfile_=C:\_D\TEST\My test file.txt
set FirstLine=
for /f "delims=" %%i in ('type "%myfile_%"') do (
  if not defined FirstLine set FirstLine=%%i)
echo FirstLine=%FirstLine%
endlocal & goto :EOF

(Однако так называемые ядовитые персонажи по-прежнему будут представлять проблему.)

Подробнее о получении определенной строки с помощью пакетных команд:

Как мне получить n-ю, первую и последнюю строку текстового файла?" http://www.netikka.net/tsneti/info/tscmd023.htm

[Добавлено 28 августа 2012] Можно также иметь:

@echo off & setlocal enableextensions
set myfile_=C:\_D\TEST\My test file.txt
for /f "tokens=* delims=" %%a in (
  'type "%myfile_%"') do (
    set FirstLine=%%a& goto _ExitForLoop)
:_ExitForLoop
echo FirstLine=%FirstLine%
endlocal & goto :EOF

Answer 10

Вот обходной путь, использующий powershell:

powershell (Get-Content file.txt)[0]

(Вы также можете легко прочитать ряд строк с powershell (Get-Content file.txt)[0..3])

Если вам нужно установить переменную внутри пакетного скрипта в качестве первой строки file.txt вы можете использовать:

for /f "usebackq delims=" %%a in (`powershell ^(Get-Content file.txt^)[0]`) do (set "head=%%a")

Answer 11

Обратите внимание, что доступ к пакетным файлам будет ограничен пределом строк для командного процессора DOS - см. Каково ограничение по длине командной строки?.

Итак, если вы пытаетесь обработать файл, содержащий еще какие-либо строки, которые 8192 символы, которые скрипт просто пропустит, так как значение не может быть сохранено.

Answer 12

Другой способ

setlocal enabledelayedexpansion
@echo off
for /f "delims=" %%i in (filename.txt) do (
if 1==1 (
set first_line=%%i
echo !first_line!
goto :eof
))

Answer 13

Чтобы скопировать файл (file1.txt, file1[1].txt, file1[2].txt, и т.д.):

START/WAIT C:\LAERCIO\DELPHI\CICLADOR\dprCiclador.exe C:\LAERCIUM\Ciclavel.txt

rem set/p ciclo=< C:\LAERCIUM\Ciclavel.txt:
set/p ciclo=< C:\LAERCIUM\Ciclavel.txt

rem echo %ciclo%:
echo %ciclo%

И он работает.