C#:Преобразуйте десятичную дробь, упакованную в формате COMP-3, в Удобочитаемое значение
https://stackoverflow.com/questions/142972
-
02-07-2019 - |
italiano
english
français
española
中国
日本の
العربية
Deutsch
한국어
Português
RussianВопрос
У меня есть серия плоских файлов ASCII, поступающих с мэйнфрейма для обработки приложением C #.Был введен новый канал с заполненным десятичным полем (COMP-3), которое необходимо преобразовать в числовое значение.
Файлы передаются по FTP с использованием режима передачи ASCII.Я обеспокоен тем, что двоичное поле может содержать то, что будет интерпретировано как очень низкие ASCII-коды или управляющие символы вместо значения - Или, что еще хуже, может быть потеряно в процессе FTP.
Более того, поля считываются как строки.Возможно, у меня хватит гибкости, чтобы обойти эту часть (т. е.какой-то поток), но бизнес даст мне отпор.
Требование гласило "Преобразовать из шестнадцатеричного в ASCII", но очевидно, что это не дало правильных значений.Будем признательны за любую помощь;это не обязательно должно зависеть от языка, если вы можете объяснить логику процесса преобразования.
Решение
Прежде всего, вы должны устранить проблемы с переводом в конец строки (EOL), которые будут вызваны режимом передачи ASCII.Вы абсолютно правы, беспокоясь о повреждении данных, когда значения BCD совпадают с символами EOL.Худшим аспектом этой проблемы является то, что она будет возникать редко и неожиданно.
Лучшее решение - сменить режим передачи на BIN.Это уместно, поскольку передаваемые вами данные являются двоичными.Если невозможно использовать правильный режим передачи по FTP, вы можете исправить повреждение режима ASCII в коде.Все, что вам нужно сделать, это преобразовать пар обратно в .На вашем месте я бы позаботился о том, чтобы это было хорошо протестировано.
Как только вы разберетесь с проблемой EOL, преобразование COMP-3 будет довольно простым.Мне удалось найти эта статья в базе знаний MS с примерами кода на BASIC.Ниже VB.NET порт этот код.
Поскольку вы имеете дело со значениями COMP-3, формат файла, который вы читаете, почти наверняка имеет фиксированные размеры записей с фиксированной длиной полей.На вашем месте я бы получил в свои руки спецификацию формата файла, прежде чем вы продолжите в этом вопросе.Для работы с этими данными вы должны использовать программу BinaryReader.Если кто-то настаивает на этом, я бы ушел.Пусть они найдут кого-нибудь другого, кто потакал бы их безрассудству.
Вот VB.NET порт БАЗОВОГО примера кода.Я не тестировал это, потому что у меня нет доступа к файлу COMP-3.Если это не сработает, я бы вернулся к исходному образцу кода MS для получения рекомендаций или к ссылкам в других ответах на этот вопрос.
Imports Microsoft.VisualBasic
Module Module1
'Sample COMP-3 conversion code
'Adapted from http://support.microsoft.com/kb/65323
'This code has not been tested
Sub Main()
Dim Digits%(15) 'Holds the digits for each number (max = 16).
Dim Basiceqv#(1000) 'Holds the Basic equivalent of each COMP-3 number.
'Added to make code compile
Dim MyByte As Char, HighPower%, HighNibble%
Dim LowNibble%, Digit%, E%, Decimal%, FileName$
'Clear the screen, get the filename and the amount of decimal places
'desired for each number, and open the file for sequential input:
FileName$ = InputBox("Enter the COBOL data file name: ")
Decimal% = InputBox("Enter the number of decimal places desired: ")
FileOpen(1, FileName$, OpenMode.Binary)
Do Until EOF(1) 'Loop until the end of the file is reached.
Input(1, MyByte)
If MyByte = Chr(0) Then 'Check if byte is 0 (ASC won't work on 0).
Digits%(HighPower%) = 0 'Make next two digits 0. Increment
Digits%(HighPower% + 1) = 0 'the high power to reflect the
HighPower% = HighPower% + 2 'number of digits in the number
'plus 1.
Else
HighNibble% = Asc(MyByte) \ 16 'Extract the high and low
LowNibble% = Asc(MyByte) And &HF 'nibbles from the byte. The
Digits%(HighPower%) = HighNibble% 'high nibble will always be a
'digit.
If LowNibble% <= 9 Then 'If low nibble is a
'digit, assign it and
Digits%(HighPower% + 1) = LowNibble% 'increment the high
HighPower% = HighPower% + 2 'power accordingly.
Else
HighPower% = HighPower% + 1 'Low nibble was not a digit but a
Digit% = 0 '+ or - signals end of number.
'Start at the highest power of 10 for the number and multiply
'each digit by the power of 10 place it occupies.
For Power% = (HighPower% - 1) To 0 Step -1
Basiceqv#(E%) = Basiceqv#(E%) + (Digits%(Digit%) * (10 ^ Power%))
Digit% = Digit% + 1
Next
'If the sign read was negative, make the number negative.
If LowNibble% = 13 Then
Basiceqv#(E%) = Basiceqv#(E%) - (2 * Basiceqv#(E%))
End If
'Give the number the desired amount of decimal places, print
'the number, increment E% to point to the next number to be
'converted, and reinitialize the highest power.
Basiceqv#(E%) = Basiceqv#(E%) / (10 ^ Decimal%)
Print(Basiceqv#(E%))
E% = E% + 1
HighPower% = 0
End If
End If
Loop
FileClose() 'Close the COBOL data file, and end.
End Sub
End Module
Другие советы
Я просматривал сообщения на многочисленных форумах, касающиеся преобразования данных Comp-3 BCD из "устаревших" файлов мэйнфреймов во что-то пригодное для использования на C #.Во-первых, я хотел бы сказать, что я менее чем в восторге от ответов, полученных некоторыми из этих сообщений, особенно от тех, в которых говорилось по существу: "почему вы беспокоите нас этими сообщениями, не связанными с C # / C ++", а также "Если вам нужен ответ о каком-то соглашении COBOL, почему бы вам не посетить сайт, ориентированный на COBOL".На мой взгляд, это полная чушь, поскольку разработчикам программного обеспечения, вероятно, потребуется еще много лет (к сожалению), чтобы понять, как справляться с некоторыми из этих унаследованных проблем, существующих в РЕАЛЬНОМ МИРЕ.Итак, даже если меня раскритикуют за этот пост из-за следующего кода, я собираюсь поделиться с вами РЕАЛЬНЫМ опытом, с которым мне пришлось столкнуться в отношении преобразования COMP-3 / EBCDIC (и да, я тот, кто говорит о "гибких дисках, бумажной ленте, дисковых пакетах и т.д...- Я работаю инженером-программистом с 1979 года").
Во-первых, поймите, что любой файл, который вы читаете из устаревшей мейнфреймовой системы, такой как IBM, представит вам данные в формате EBCDIC, и для преобразования любых этих данных в строку C # / C ++, с которой вы можете работать, вам придется использовать надлежащий перевод кодовой страницы, чтобы перевести данные в формат ASCII.Хорошим примером того, как с этим справиться, было бы:
StreamReader ReadFile = новый StreamReader(путь, кодировка.GetEncoding(037);// 037 = Перевод EBCDIC в ASCII.
Это гарантирует, что все, что вы прочитаете из этого потока, затем будет преобразовано в ASCII и может быть использовано в строковом формате.Сюда входят поля "Zoned Decimal" (рис. 9) и "Text" (рис. X), объявленные COBOL.Однако это не обязательно преобразует поля COMP-3 в правильный "двоичный" эквивалент при чтении в массив char[] или byte[].Чтобы сделать это, единственный способ, которым вы когда-либо сможете правильно перевести это (даже используя кодовые страницы UTF-8, UTF-16, по умолчанию или что-то еще), вам нужно будет открыть файл следующим образом:
FileStream FileStream = новый FileStream (путь, режим файла.Открыть, доступ к файлу.Прочитать, общий доступ к файлу.Читать);
Конечно, опция "FileShare.Read" является "необязательной".
Когда вы выделили поле, которое хотите преобразовать в десятичное значение (а затем, при необходимости, в строку ASCII), вы можете использовать следующий код - и он был в основном украден из публикации MicroSoft "UnpackDecimal", которую вы можете получить по адресу:
Я выделил (как мне кажется) наиболее важные части этой логики и объединил ее в два метода, с помощью которых вы можете делать все, что захотите.Для моих целей я решил оставить это как возвращающее десятичное значение, с которым я затем мог бы делать то, что хотел.По сути, метод называется "unpack", и вы передаете ему массив byte[] (не длиннее 12 байт) и масштаб в виде int, который представляет собой количество десятичных разрядов, которые вы хотите вернуть в десятичном значении.Я надеюсь, что это сработает для вас так же хорошо, как и для меня.
private Decimal Unpack(byte[] inp, int scale)
{
long lo = 0;
long mid = 0;
long hi = 0;
bool isNegative;
// this nybble stores only the sign, not a digit.
// "C" hex is positive, "D" hex is negative, and "F" hex is unsigned.
switch (nibble(inp, 0))
{
case 0x0D:
isNegative = true;
break;
case 0x0F:
case 0x0C:
isNegative = false;
break;
default:
throw new Exception("Bad sign nibble");
}
long intermediate;
long carry;
long digit;
for (int j = inp.Length * 2 - 1; j > 0; j--)
{
// multiply by 10
intermediate = lo * 10;
lo = intermediate & 0xffffffff;
carry = intermediate >> 32;
intermediate = mid * 10 + carry;
mid = intermediate & 0xffffffff;
carry = intermediate >> 32;
intermediate = hi * 10 + carry;
hi = intermediate & 0xffffffff;
carry = intermediate >> 32;
// By limiting input length to 14, we ensure overflow will never occur
digit = nibble(inp, j);
if (digit > 9)
{
throw new Exception("Bad digit");
}
intermediate = lo + digit;
lo = intermediate & 0xffffffff;
carry = intermediate >> 32;
if (carry > 0)
{
intermediate = mid + carry;
mid = intermediate & 0xffffffff;
carry = intermediate >> 32;
if (carry > 0)
{
intermediate = hi + carry;
hi = intermediate & 0xffffffff;
carry = intermediate >> 32;
// carry should never be non-zero. Back up with validation
}
}
}
return new Decimal((int)lo, (int)mid, (int)hi, isNegative, (byte)scale);
}
private int nibble(byte[] inp, int nibbleNo)
{
int b = inp[inp.Length - 1 - nibbleNo / 2];
return (nibbleNo % 2 == 0) ? (b & 0x0000000F) : (b >> 4);
}
Если у вас есть какие-либо вопросы, размещайте их здесь - потому что я подозреваю, что меня "раскритикуют", как и всех остальных, кто решил опубликовать вопросы, имеющие отношение к сегодняшним выпускам...
Спасибо, Джон - Старший.
Если исходные данные были в EBCDIC, то ваше поле COMP-3 было искажено.Процесс FTP выполнил преобразование EBCDIC в ASCII байтовых значений в поле COMP-3, что не является тем, что вы хотите.Чтобы исправить это, вы можете:
1) Используйте ДВОИЧНЫЙ режим для передачи, чтобы получить необработанные данные EBCDIC.Затем вы преобразуете поле COMP-3 в число и переводите любой другой текст EBCDIC в записи в ASCII.Упакованное поле хранит каждую цифру в виде полубайта с младшим полубайтом в качестве знака (F - положительное значение, а другие значения, обычно D или E, отрицательные).Сохранение 123.4 в PIC 999.99 USAGE COMP-3 будет равно X '01234F' (три байта), а значение -123 в том же поле равно X '01230D'.
2) Попросите отправителя преобразовать поле в НАЧАЛЬНОЕ (или ЗАВЕРШАЮЩЕЕ) числовое поле с ОТОБРАЖАЕМЫМ ЗНАКОМ ИСПОЛЬЗОВАНИЯ.При этом число сохраняется в виде строки цифровых цифр EBCDIC со знаком в виде отдельного отрицательного (-) или пустого символа.Все цифры и знак корректно переводятся в их эквивалент ASCII при передаче по FTP.
Прошу прощения, если я здесь отклонился от основной темы, но, возможно, этот пример кода, который я вставлю здесь, мог бы вам помочь.Это пришло от Vbroks...
Imports System
Imports System.IO
Imports System.Text
Imports System.Text.Encoding
'4/20/07 submission includes a line spacing addition when a control character is used:
' The line spacing is calculated off of the 3rd control character.
'
' Also includes the 4/18 modification of determining end of file.
'4/26/07 submission inclues an addition of 6 to the record length when the 4th control
' character is an 8. This is because these records were being truncated.
'Authored by Gary A. Lima, aka. VBRocks
''' <summary>
''' Translates an EBCDIC file to an ASCII file.
''' </summary>
''' <remarks></remarks>
Public Class EBCDIC_to_ASCII_Translator
#Region " Example"
Private Sub Example()
'Set your source file and destination file paths
Dim sSourcePath As String = "c:\Temp\MyEBCDICFile"
Dim sDestinationPath As String = "c:\Temp\TranslatedFile.txt"
Dim trans As New EBCDIC_to_ASCII_Translator()
'If your EBCDIC file uses Control records to determine the length of a record, then this to True
trans.UseControlRecord = True
'If the first record of your EBCDIC file is filler (junk), then set this to True
trans.IgnoreFirstRecord = True
'EBCDIC files are written in block lengths, set your block length (Example: 134, 900, Etc.)
trans.BlockLength = 900
'This method will actually translate your source file and output it to the specified destination file path
trans.TranslateFile(sSourcePath, sDestinationPath)
'Here is a alternate example:
'No Control record is used
'trans.UseControlRecord = False
'Translate the whole file, including the first record
'trans.IgnoreFirstRecord = False
'Set the block length
'trans.BlockLength = 134
'Translate...
'trans.TranslateFile(sSourcePath, sDestinationPath)
'*** Some additional methods that you can use are:
'Trim off leading characters from left side of string (position 0 to...)
'trans.LTrim = 15
'Translate 1 EBCDIC character to an ASCII character
'Dim strASCIIChar as String = trans.TranslateCharacter("S")
'Translate an EBCDIC character array to an ASCII string
'trans.TranslateCharacters(chrEBCDICArray)
'Translates an EBCDIC string to an ASCII string
'Dim strASCII As String = trans.TranslateString("EBCDIC String")
End Sub
#End Region 'Example
'Translate characters from EBCDIC to ASCII
Private ASCIIEncoding As Encoding = Encoding.ASCII
Private EBCDICEncoding As Encoding = Encoding.GetEncoding(37) 'EBCDIC
'Block Length: Can be fixed (Ex: 134).
Private miBlockLength As Integer = 0
Private mbUseControlRec As Boolean = True 'If set to False, will return exact block length
Private mbIgnoreFirstRecord As Boolean = True 'Will Ignore first record if set to true (First record may be filler)
Private miLTrim As Integer = 0
''' <summary>
''' Translates SourceFile from EBCDIC to ASCII. Writes output to file path specified by DestinationFile parameter.
''' Set the BlockLength Property to designate block size to read.
''' </summary>
''' <param name="SourceFile">Enter the path of the Source File.</param>
''' <param name="DestinationFile">Enter the path of the Destination File.</param>
''' <remarks></remarks>
Public Sub TranslateFile(ByVal SourceFile As String, ByVal DestinationFile As String)
Dim iRecordLength As Integer 'Stores length of a record, not including the length of the Control Record (if used)
Dim sRecord As String = "" 'Stores the actual record
Dim iLineSpace As Integer = 1 'LineSpace: 1 for Single Space, 2 for Double Space, 3 for Triple Space...
Dim iControlPosSix As Byte() 'Stores the 6th character of a Control Record (used to calculate record length)
Dim iControlRec As Byte() 'Stores the EBCDIC Control Record (First 6 characters of record)
Dim bEOR As Boolean 'End of Record Flag
Dim bBOF As Boolean = True 'Beginning of file
Dim iConsumedChars As Integer = 0 'Stores the number of consumed characters in the current block
Dim bIgnoreRecord As Boolean = mbIgnoreFirstRecord 'Ignores the first record if set.
Dim ControlArray(5) As Char 'Stores Control Record (first 6 bytes)
Dim chrArray As Char() 'Stores characters just after read from file
Dim sr As New StreamReader(SourceFile, EBCDICEncoding)
Dim sw As New StreamWriter(DestinationFile)
'Set the RecordLength to the RecordLength Property (below)
iRecordLength = miBlockLength
'Loop through entire file
Do Until sr.EndOfStream = True
'If using a Control Record, then check record for valid data.
If mbUseControlRec = True Then
'Read the Control Record (first 6 characters of the record)
sr.ReadBlock(ControlArray, 0, 6)
'Update the value of consumed (read) characters
iConsumedChars += ControlArray.Length
'Get the bytes of the Control Record Array
iControlRec = EBCDICEncoding.GetBytes(ControlArray)
'Set the line spacing (position 3 divided by 64)
' (64 decimal = Single Spacing; 128 decimal = Double Spacing)
iLineSpace = iControlRec(2) / 64
'Check the Control record for End of File
'If the Control record has a 8 or 10 in position 1, and a 1 in postion 2, then it is the end of the file
If (iControlRec(0) = 8 OrElse iControlRec(0) = 10) AndAlso _
iControlRec(1) = 1 Then
If bBOF = False Then
Exit Do
Else
'The Beginning of file flag is set to true by default, so when the first
' record is encountered, it is bypassed and the bBOF flag is set to False
bBOF = False
End If 'If bBOF = Fals
End If 'If (iControlRec(0) = 8 OrElse
'Set the default value for the End of Record flag to True
' If the Control Record has all zeros, then it's True, else False
bEOR = True
'If the Control record contains all zeros, bEOR will stay True, else it will be set to False
For i As Integer = 0 To 5
If iControlRec(i) > 0 Then
bEOR = False
Exit For
End If 'If iControlRec(i) > 0
Next 'For i As Integer = 0 To 5
If bEOR = False Then
'Convert EBCDIC character to ASCII
'Multiply the 6th byte by 6 to get record length
' Why multiply by 6? Because it works.
iControlPosSix = EBCDICEncoding.GetBytes(ControlArray(5))
'If the 4th position of the control record is an 8, then add 6
' to the record length to pick up remaining characters.
If iControlRec(3) = 8 Then
iRecordLength = CInt(iControlPosSix(0)) * 6 + 6
Else
iRecordLength = CInt(iControlPosSix(0)) * 6
End If
'Add the length of the record to the Consumed Characters counter
iConsumedChars += iRecordLength
Else
'If the Control Record had all zeros in it, then it is the end of the Block.
'Consume the remainder of the block so we can continue at the beginning of the next block.
ReDim chrArray(miBlockLength - iConsumedChars - 1)
'ReDim chrArray(iRecordLength - iConsumedChars - 1)
'Consume (read) the remaining characters in the block.
' We are not doing anything with them because they are not actual records.
'sr.ReadBlock(chrArray, 0, iRecordLength - iConsumedChars)
sr.ReadBlock(chrArray, 0, miBlockLength - iConsumedChars)
'Reset the Consumed Characters counter
iConsumedChars = 0
'Set the Record Length to 0 so it will not be processed below.
iRecordLength = 0
End If ' If bEOR = False
End If 'If mbUseControlRec = True
If iRecordLength > 0 Then
'Resize our array, dumping previous data. Because Arrays are Zero (0) based, subtract 1 from the Record length.
ReDim chrArray(iRecordLength - 1)
'Read the specfied record length, without the Control Record, because we already consumed (read) it.
sr.ReadBlock(chrArray, 0, iRecordLength)
'Copy Character Array to String Array, Converting in the process, then Join the Array to a string
sRecord = Join(Array.ConvertAll(chrArray, New Converter(Of Char, String)(AddressOf ChrToStr)), "")
'If the record length was 0, then the Join method may return Nothing
If IsNothing(sRecord) = False Then
If bIgnoreRecord = True Then
'Do nothing - bypass record
'Reset flag
bIgnoreRecord = False
Else
'Write the line out, LTrimming the specified number of characters.
If sRecord.Length >= miLTrim Then
sw.WriteLine(sRecord.Remove(0, miLTrim))
Else
sw.WriteLine(sRecord.Remove(0, sRecord.Length))
End If ' If sRecord.Length >= miLTrim
'Write out the number of blank lines specified by the 3rd control character.
For i As Integer = 1 To iLineSpace - 1
sw.WriteLine("")
Next 'For i As Integer = 1 To iLineSpace
End If 'If bIgnoreRecord = True
'Obviously, if we have read more characters from the file than the designated size of the block,
' then subtract the number of characters we have read into the next block from the block size.
If iConsumedChars > miBlockLength Then
'If iConsumedChars > iRecordLength Then
iConsumedChars = iConsumedChars - miBlockLength
'iConsumedChars = iConsumedChars - iRecordLength
End If
End If 'If IsNothing(sRecord) = False
End If 'If iRecordLength > 0
'Allow computer to process (works in a class module, not in a dll)
'Application.DoEvents()
Loop
'Destroy StreamReader (sr)
sr.Close()
sr.Dispose()
'Destroy StreamWriter (sw)
sw.Close()
sw.Dispose()
End Sub
''' <summary>
''' Translates 1 EBCDIC Character (Char) to an ASCII String
''' </summary>
''' <param name="chr"></param>
''' <returns></returns>
''' <remarks></remarks>
Private Function ChrToStr(ByVal chr As Char) As String
Dim sReturn As String = ""
'Convert character into byte
Dim EBCDICbyte As Byte() = EBCDICEncoding.GetBytes(chr)
'Convert EBCDIC byte to ASCII byte
Dim ASCIIByte As Byte() = Encoding.Convert(EBCDICEncoding, ASCIIEncoding, EBCDICbyte)
sReturn = Encoding.ASCII.GetString(ASCIIByte)
Return sReturn
End Function
''' <summary>
''' Translates an EBCDIC String to an ASCII String
''' </summary>
''' <param name="sStringToTranslate"></param>
''' <returns>String</returns>
''' <remarks></remarks>
Public Function TranslateString(ByVal sStringToTranslate As String) As String
Dim i As Integer = 0
Dim sReturn As New System.Text.StringBuilder()
'Loop through the string and translate each character
For i = 0 To sStringToTranslate.Length - 1
sReturn.Append(ChrToStr(sStringToTranslate.Substring(i, 1)))
Next
Return sReturn.ToString()
End Function
''' <summary>
''' Translates 1 EBCDIC Character (Char) to an ASCII String
''' </summary>
''' <param name="sCharacterToTranslate"></param>
''' <returns>String</returns>
''' <remarks></remarks>
Public Function TranslateCharacter(ByVal sCharacterToTranslate As Char) As String
Return ChrToStr(sCharacterToTranslate)
End Function
''' <summary>
''' Translates an EBCDIC Character (Char) Array to an ASCII String
''' </summary>
''' <param name="sCharacterArrayToTranslate"></param>
''' <returns>String</returns>
''' <remarks>Remarks</remarks>
Public Function TranslateCharacters(ByVal sCharacterArrayToTranslate As Char()) As String
Dim sReturn As String = ""
'Copy Character Array to String Array, Converting in the process, then Join the Array to a string
sReturn = Join(Array.ConvertAll(sCharacterArrayToTranslate, _
New Converter(Of Char, String)(AddressOf ChrToStr)), "")
Return sReturn
End Function
''' <summary>
''' Block Length must be set. You can set the BlockLength for specific block sizes (Ex: 134).
''' Set UseControlRecord = False for files with specific block sizes (Default is True)
''' </summary>
''' <value>0</value>
''' <returns>Integer</returns>
''' <remarks></remarks>
Public Property BlockLength() As Integer
Get
Return miBlockLength
End Get
Set(ByVal value As Integer)
miBlockLength = value
End Set
End Property
''' <summary>
''' Determines whether a ControlKey is used to calculate RecordLength of valid data
''' </summary>
''' <value>Default value is True</value>
''' <returns>Boolean</returns>
''' <remarks></remarks>
Public Property UseControlRecord() As Boolean
Get
Return mbUseControlRec
End Get
Set(ByVal value As Boolean)
mbUseControlRec = value
End Set
End Property
''' <summary>
''' Ignores first record if set (Default is True)
''' </summary>
''' <value>Default is True</value>
''' <returns>Boolean</returns>
''' <remarks></remarks>
Public Property IgnoreFirstRecord() As Boolean
Get
Return mbIgnoreFirstRecord
End Get
Set(ByVal value As Boolean)
mbIgnoreFirstRecord = value
End Set
End Property
''' <summary>
''' Trims the left side of every string the specfied number of characters. Default is 0.
''' </summary>
''' <value>Default is 0.</value>
''' <returns>Integer</returns>
''' <remarks></remarks>
Public Property LTrim() As Integer
Get
Return miLTrim
End Get
Set(ByVal value As Integer)
miLTrim = value
End Set
End Property
End Class
Несколько полезных ссылок для перевода EBCDIC:
Таблица перевода - полезно проверить некоторые значения в упакованных десятичных полях:http://www.simotime.com/asc2ebc1.htm
Список кодовых страниц в msdn:
http://msdn.microsoft.com/en-us/library/dd317756 (ПРОТИВ 85).aspx
И фрагмент кода для преобразования полей массива байтов в C#:
// 500 is the code page for IBM EBCDIC International
System.Text.Encoding enc = new System.Text.Encoding(500);
string value = enc.GetString(byteArrayField);
Упакованные поля одинаковы в EBCDIC или ASCII.Не запускайте на них преобразование EBCDIC в ASCII.В .Net выгрузите их в виде байта[].
Вы используете побитовые маски и сдвиги для упаковки / распаковки.-- Но побитовые операции применяются только к целочисленным типам в .Сетка, так что вам нужно перепрыгнуть через несколько обручей!
Хороший разработчик COBOL или C может указать вам правильное направление.
Найди кого-нибудь из старичков и заплати свои взносы (этого должно хватить примерно на три кружки пива).
