Checkexception принимает только методы 0-параметров; Как я могу проверить, что другие методы бросают исключения?

Question

Мне интересно, какая лучшая практика для проверки для исключения в Днит. Я не очень знаком с указателями метода в Delphi. Есть ли возможность связывать аргументы на указатель метода, чтобы его можно было вызвать без аргументов. На данный момент я всегда пишу дополнительный метод, который делает это «привязку» вручную. Это будет раздражать, если SUT имеет много методов бросания.

// What i did before i knew abput CheckExcepion
procedure MyTest.MyMethod_BadInput_Throws;
var
    res: Boolean;
begin
    res := false;
    try
        sut.MyMethod('this is bad');
    except
        on e : MyExpectedException do:
            res := true;
    end;
    CheckTrue(res);
end;

// What i do now
procedure MyTest.MyMethodWithBadInput;
begin
    sut.MyMethod('this is bad');
end;

procedure MyTest.MyMethod_BadInput_Throws;
begin
    CheckException(MyMethodWithBadInput, MyExpectedException);
end;

// this would be nice
procedure MyTest.MyMethod_BadInput_Throws;
begin
    CheckException(
        BindArguments(sut.MyMethod, 'this is bad'),  // <-- how to do this
        MyExpectedException);
end;

Answer 1

Вы можете использовать StartExpectingException Чтобы окружить ваш ваш метод вызова).

StartExpectingException(MyException);
MyMethod(MyParam);
StopExpectingException();

Answer 2

Я не знаю, если Dunit его еще поддерживает, но это идеальное использование для анонимных методов, которые были введены в Delphi 2010. Если Dunit не поддерживает его, то вы можете легко изменить источник самостоятельно.

Answer 3

Как отмечалось, это отличное место для анонимных методов.

Вот как я это делаю. Я «заимствовал» это от Алекс Чиобану:

procedure TestTMyClass.CheckException(aExceptionType: TClassOfException; aCode: TTestCode; const aMessage: String);
var
  WasException: Boolean;
begin
  WasException := False;
  try
    aCode;
  except
    on E: Exception do
    begin
      if E is aExceptionType then
      begin
        WasException := True;
      end;
    end;
  end;
  Check(WasException, aMessage);
end;

Затем назовите это с чем-то вроде:

CheckException(ETestingException, 
             procedure begin FMyClass.RaiseTestingException end,      
             'The ETestingException exception didn''t get raised.  That is impossible!');

Answer 4

Использовать StartExpectingException() Не лучший способ в случае, если вы хотите проверить более одного исключения. Чтобы проверить все возможные случаи в моей процедуре тестирования вместе с исключениями, я использую этот алгоритм:

uses
  Dialogs;
procedure MyTest.MyMethod_Test;
begin
  // Test for Exceptions
  try
    MyMethod(MyParam1CreatingException1);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType1); end; // This exception is OK
  try
    MyMethod(MyParam2CreatingException2);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType2); end; // This exception is OK
  // ... test other exceptions ...

  // Test other parameters
  CheckEquals('result1', MyMethod(MyParam1));
  CheckEquals('result2', MyMethod(MyParam2));
  // ... other tests ...
end;

Причина, по которой я использую ShowMessage('Error! There should be exception: Exxx here!'); вместо предоставленного Check(false, 'There should have been an EListError.'); метод в том, что в моем случае (delphi6) Check(boolean, 'Message') не работает - это не показывает сообщение в том случае, если проверка находится внутри try...except блок (не знаю почему).

Answer 5

Это работающая и улучшенная версия ответа Ника Ходжес, какие подклассы Dunit's TestFramework.TTestCase:

uses
  TestFramework, System.SysUtils;
type
  TTestCode = reference to procedure;

  TTestCasePlus = class(TestFramework.TTestCase)
    procedure CheckException(
      ExceptionType: TClass; Code: TTestCode; const Message: String = '');
  end;

implementation

procedure TTestCasePlus.CheckException(
  ExceptionType: TClass; Code: TTestCode; const Message: String = '');
{ Check whether some code raises a specific exception type.

Adapted from http://stackoverflow.com/a/5615560/797744

Example:

  Self.CheckException(EConvertError,
                      procedure begin UnformatTimestamp('invalidstr') end);

@param ExceptionType: The exception class which we check if it was raised.
@param Code: Code in the form of an anonymous method that should raise the
  exception.
@param Message: Output message on check failure. }
var
  WasRaised: Boolean;
begin
  WasRaised := False;
  try
    Code;
  except
    on E: Exception do
      if E is ExceptionType then
        WasRaised := True;
  end;
  Check(WasRaised, Message);
end;

Хороший бонус к этому методу проверки, был ли исключение было поднято Start/StopExpectingException() Это то, что вы можете запустить TestRunner в сборке Debug, и она не будет беспокоить вас «Исключением было поднято». Разрыв? Продолжить? " Каждый раз, когда исключение поднимается - даже если он был обработан.