вопрос об общих лиспе

Question

Я снимаюсь с ума с небольшой проблемой здесь, я продолжаю получать ошибку, и я не могу понять, почему код должен изменить диапазон списка, поэтому, если мы дадим ему список со значениями (1 2 3 4) и мы хотим изменить диапазон в 11 до четырнадцати, результат будет (11 12 13 14)Проблема в том, что последняя функция называется scale-list вернут ошибку, говоря:

Введенный отладчик - ошибка lisp: (номер неправильного типа-аргумента или маркера-P Nil)

У кого-нибудь есть ключ почему? Я использую Aquamacs в качестве редактора, спасибо заранее

;;finds minimum in a list
(defun minimum (list)
  (car (sort list #'<)))

;;finds maximum in a list
(defun maximum (list)
  (car (sort list #'>)))

;;calculates the range of a list
(defun range (list)
  (- (maximum list) (minimum list)))

;;scales one value to another range
(defun scale-value (list low high n)
   (+ (/ (* (- (nth (- n 1) list)
               (minimum list))
            (- high low))
         (range list))
      low))


;;is supposed to scale the whole list to another range
(defun scale-list (list low high n)
  (unless (= n 0)
   (cons (scale-value list low high n)
         (scale-list list low high (- n 1)))))

(scale-list '(1 2 3 4) 21 24 4)

Answer 1

Определения максимальной и минимальной необходимости быть улучшенными. Сортировка разрушительно. Также неправильно называть сортировку с буквальной константой, как «(1 2 3 4) - опять же, сортировка разрушительно.

Лучшие определения:

(defun minimum (list)
  (reduce #'min list))

(defun maximum (list)
  (reduce #'max list))

Более эффективное определение диапазона:

(defun range (list)
  (loop for e in list
        maximize e into max
        minimize e into min
        finally (return (- max min))))

Список масштаба и значение масштаба также не являются лисштабными. Если вы называете NTH подобное в рекурсивной функции, то что-то не так. Вы должны перезагрузить перечень, а не индекс. Диапазон вызовов на масштабе и минимум для каждого вызова. Почему?

Проверьте этот вариант:

;;scales one value to another range
(defun scale-value (item low high min range)
   (+ (/ (* (- item min)
            (- high low))
         range)
      low))

;;is supposed to scale the whole list to another range
(defun scale-list (list low high)
  (let ((min (minimum list))
        (range (range list)))
    (labels ((scale-list-aux (list)
               (when list
                 (cons (scale-value (first list) low high min range)
                       (scale-list-aux (rest list))))))
      (scale-list-aux list))))

(scale-list '(1 2 3 4) 21 24)

Что вы можете улучшить больше? Например, я бы избавился от рекурсии и заменил его mapcar.

Answer 2

Я отправляю код, потому что что-то пошло не так ...

;;finds minimum in a list
(defun minimum(list)
  (car  (sort list #'<)))
;;finds maximum in a list
(defun maximum(list)
  (car (sort list #'>)))
;;calculates the range of a list
(defun range(list)
  (- (maximum list) (minimum list)))

;;scales one value to another range
(defun scale-value(list low high n)
     (+ (/ (* (- (nth (- n 1) list) (minimum list)) (- high low)) (range list)) low))


;;is supposed to scale the whole list to another range
(defun scale-list(list low high n)
  (unless (= n 0)
   (cons (scale-value list low high n) (scale-list list low high (- n 1)))))

(scale-list '(1 2 3 4) 21 24 4)

Answer 3

Ваш фактический след стека - это что-то вроде:

-(nil 0.1)
  (* (- (nth ... list) (minimum list)) (- high low))
  (/ (* (- ... ...) (- high low)) (range list))
  (+ (/ (* ... ...) (range list)) low)
  scale-value((0.1) 20 30 3)

Я предполагаю, что вы определяете неправильный N-й элемент, и это возвращает Nil, что испортиет вычитание.