كيفية تحويل ثواني إلى HH: MM: SS باستخدام T-SQL
سؤال
الوضع هو أن يكون لديك قيمة في الثواني (xxx.xx)، وتريد تحويلها إلى HH: MM: SS باستخدام T-SQL.
مثال:
- 121.25 S يصبح 00: 02: 01.25
المحلول
تريد أن تضاعف إلى مللي ثانية حيث يتم تجاهل الجزء الكسري.
SELECT DATEADD(ms, 121.25 * 1000, 0)
إذا كنت تريد ذلك دون جزء التاريخ، يمكنك استخدام تحويل، مع نمط 114
SELECT CONVERT(varchar, DATEADD(ms, 121.25 * 1000, 0), 114)
نصائح أخرى
إذا كان لديك مبلغ الوقت يتجاوز 24 ساعة لن يتم التعامل معها بشكل صحيح مع DataDD وتحويل الأساليب.
SELECT CONVERT(varchar, DATEADD(ms, 24*60*60 * 1000, 0), 114)
00:00:00:000
ستتعامل الوظيفة التالية في التعامل مع الأوقات التي تتجاوز 24 ساعة (~ كحد أقصى 35،791،394 ساعة).
create function [dbo].[ConvertTimeToHHMMSS]
(
@time decimal(28,3),
@unit varchar(20)
)
returns varchar(20)
as
begin
declare @seconds decimal(18,3), @minutes int, @hours int;
if(@unit = 'hour' or @unit = 'hh' )
set @seconds = @time * 60 * 60;
else if(@unit = 'minute' or @unit = 'mi' or @unit = 'n')
set @seconds = @time * 60;
else if(@unit = 'second' or @unit = 'ss' or @unit = 's')
set @seconds = @time;
else set @seconds = 0; -- unknown time units
set @hours = convert(int, @seconds /60 / 60);
set @minutes = convert(int, (@seconds / 60) - (@hours * 60 ));
set @seconds = @seconds % 60;
return
convert(varchar(9), convert(int, @hours)) + ':' +
right('00' + convert(varchar(2), convert(int, @minutes)), 2) + ':' +
right('00' + convert(varchar(6), @seconds), 6)
end
الاستعمال:
select dbo.ConvertTimeToHHMMSS(123, 's')
select dbo.ConvertTimeToHHMMSS(96.999, 'mi')
select dbo.ConvertTimeToHHMMSS(35791394.999, 'hh')
0:02:03.000
1:36:59.940
35791394:59:56.400
بالنسبة لأولئك الذين لديهم مشكلات باستخدام Dateadd وتحويل ثوان تتجاوز 24 ساعة، يمكننا استخدام المعدلة للتحصل على ما يلي:
SELECT CONVERT(varchar, @seconds / 86400 ) + ':' + -- Days
CONVERT(varchar, DATEADD(ms, ( @seconds % 86400 ) * 1000, 0), 114)
as "Converted to D:HH:MM:SS.MS"
DECLARE @seconds AS int = 896434;
SELECT
CONVERT(varchar, (@seconds / 86400)) --Days
+ ':' +
CONVERT(varchar, DATEADD(ss, @seconds, 0), 108); --Hours, Minutes, Seconds
المخرجات:
10:09:00:34
باستخدام SQL Server 2008
declare @Seconds as int = 3600;
SELECT CONVERT(time(0), DATEADD(SECOND, @Seconds, 0)) as 'hh:mm:ss'
باستخدام SQL Server 05 يمكنني الحصول على هذا للعمل باستخدام:
declare @OrigValue int;
set @OrigValue = 121.25;
select replace(str(@OrigValue/3600,len(ltrim(@OrigValue/3600))+abs(sign(@OrigValue/359999)-1)) + ':' + str((@OrigValue/60)%60,2) + ':' + str(@OrigValue%60,2),' ','0')
SELECT substring(convert (varchar(23),Dateadd(s,10000,LEFT(getdate(),11)),121),12,8)
10000 هي القيمة الخاصة بك في ثانية
DECLARE @TimeinSecond INT
SET @TimeinSecond = 340 -- Change the seconds
SELECT RIGHT('0' + CAST(@TimeinSecond / 3600 AS VARCHAR),2) + ':' +
RIGHT('0' + CAST((@TimeinSecond / 60) % 60 AS VARCHAR),2) + ':' +
RIGHT('0' + CAST(@TimeinSecond % 60 AS VARCHAR),2)
هذا ما أستخدمه (عادة عن تقارير البريد الإلكتروني لجدول HTML)
declare @time int, @hms varchar(20)
set @time = 12345
set @hms = cast(cast((@Time)/3600 as int) as varchar(3))
+':'+ right('0'+ cast(cast(((@Time)%3600)/60 as int) as varchar(2)),2)
+':'+ right('0'+ cast(((@Time)%3600)%60 as varchar(2)),2) +' (hh:mm:ss)'
select @hms
يمكنك تجربة هذا
set @duration= 112000
SELECT
"Time" = cast (@duration/3600 as varchar(3)) +'H'
+ Case
when ((@duration%3600 )/60)<10 then
'0'+ cast ((@duration%3600 )/60)as varchar(3))
else
cast ((@duration/60) as varchar(3))
End
قم بتحويل ثوان إلى ساعات في Select Query:
SELECT field_in_seconds,round((field_in_seconds / 3600),2) FROM a_table;
هذا سوف يمنحك النتيجة بتنسيق عشري. لست متأكدا كيفية تحويل 1.50 إلى 1:30. لا تتردد في تحرير التعليمات البرمجية الخاصة بي!