Wie konvertiert Sekunden HH: MM: SS mit T-SQL

Question

Die Situation ist, dass Sie einen Wert in Sekunden (XXX.XX) haben, und Sie wollen HH konvertieren: MM: SS. Mit T-SQL

Beispiel:

• 121.25 s wird 00: 02: 01.25

Answer 1

Sie möchten Millisekunden multiplizieren, wie der Bruchteil wird verworfen.

SELECT DATEADD(ms, 121.25 * 1000, 0)

Wenn Sie es ohne den Datumsteil mögen Sie CONVERT verwenden können, mit Stil 114

SELECT CONVERT(varchar, DATEADD(ms, 121.25 * 1000, 0), 114)

Answer 2

Wenn Ihr Zeitmenge 24 Stunden überschreitet es wird nicht richtig mit dem DATEADD und Methoden CONVERT behandelt werden.

SELECT CONVERT(varchar, DATEADD(ms, 24*60*60 * 1000, 0), 114)
00:00:00:000

Die folgende Funktion wird behandeln Zeiten von mehr als 24 Stunden (~ max 35.791.394 Stunden).

create function [dbo].[ConvertTimeToHHMMSS]
(
    @time decimal(28,3), 
    @unit varchar(20)
)
returns varchar(20)
as
begin

    declare @seconds decimal(18,3), @minutes int, @hours int;

    if(@unit = 'hour' or @unit = 'hh' )
        set @seconds = @time * 60 * 60;
    else if(@unit = 'minute' or @unit = 'mi' or @unit = 'n')
        set @seconds = @time * 60;
    else if(@unit = 'second' or @unit = 'ss' or @unit = 's')
        set @seconds = @time;
    else set @seconds = 0; -- unknown time units

    set @hours = convert(int, @seconds /60 / 60);
    set @minutes = convert(int, (@seconds / 60) - (@hours * 60 ));
    set @seconds = @seconds % 60;

    return 
        convert(varchar(9), convert(int, @hours)) + ':' +
        right('00' + convert(varchar(2), convert(int, @minutes)), 2) + ':' +
        right('00' + convert(varchar(6), @seconds), 6)

end

Verwendung:

select dbo.ConvertTimeToHHMMSS(123, 's')
select dbo.ConvertTimeToHHMMSS(96.999, 'mi')
select dbo.ConvertTimeToHHMMSS(35791394.999, 'hh')
0:02:03.000
1:36:59.940
35791394:59:56.400

Answer 3

Für die Probleme, die mit DATEADD mit und für Sekunden CONVERT von maximal 24 Stunden, können wir Modul verwenden, um das zu bekommen:

SELECT CONVERT(varchar, @seconds / 86400 ) + ':' + -- Days
CONVERT(varchar, DATEADD(ms, ( @seconds % 86400 ) * 1000, 0), 114)
as "Converted to D:HH:MM:SS.MS"

Answer 4

DECLARE @seconds AS int = 896434;
SELECT
    CONVERT(varchar, (@seconds / 86400))                --Days
    + ':' +
    CONVERT(varchar, DATEADD(ss, @seconds, 0), 108);    --Hours, Minutes, Seconds

Ausgänge:

10:09:00:34

Answer 5

Verwenden von SQL Server 2008

declare @Seconds as int = 3600;
SELECT CONVERT(time(0), DATEADD(SECOND, @Seconds, 0)) as 'hh:mm:ss'

Answer 6

Verwenden von SQL Server 05 Ich kann diese erhalten, indem Sie arbeitet:

declare @OrigValue int;
set @OrigValue = 121.25;
select replace(str(@OrigValue/3600,len(ltrim(@OrigValue/3600))+abs(sign(@OrigValue/359999)-1)) + ':' + str((@OrigValue/60)%60,2) + ':' + str(@OrigValue%60,2),' ','0')

Answer 7

SELECT substring(convert (varchar(23),Dateadd(s,10000,LEFT(getdate(),11)),121),12,8)

10000 ist der Wert in sec

Answer 8

DECLARE @TimeinSecond INT
SET @TimeinSecond = 340 -- Change the seconds
SELECT RIGHT('0' + CAST(@TimeinSecond / 3600 AS VARCHAR),2) + ':' +
RIGHT('0' + CAST((@TimeinSecond / 60) % 60 AS VARCHAR),2)  + ':' +
RIGHT('0' + CAST(@TimeinSecond % 60 AS VARCHAR),2)

Answer 9

Dies ist, was ich (in der Regel für HTML-Tabelle E-Mail-Berichte)

declare @time int, @hms varchar(20)
set @time = 12345
set @hms = cast(cast((@Time)/3600 as int) as varchar(3)) 
  +':'+ right('0'+ cast(cast(((@Time)%3600)/60 as int) as varchar(2)),2) 
  +':'+ right('0'+ cast(((@Time)%3600)%60 as varchar(2)),2) +' (hh:mm:ss)'
select @hms

Answer 10

DECLARE @Seconds INT = 86200;
SELECT 
CONVERT(VARCHAR(15), 
CAST(CONVERT(VARCHAR(12), @Seconds / 60 / 60 % 24)
+':'+ CONVERT(VARCHAR(2), @Seconds / 60 % 60)
+':'+ CONVERT(VARCHAR(2), @Seconds % 60) AS TIME), 100) AS [HH:MM:SS (AM/PM)]

Answer 11

Sie können versuchen, diese

set @duration= 112000
SELECT 
   "Time" = cast (@duration/3600 as varchar(3)) +'H'
         + Case 
       when ((@duration%3600 )/60)<10 then
                 '0'+ cast ((@duration%3600 )/60)as varchar(3))
       else 
               cast ((@duration/60) as varchar(3))
       End

Answer 12

Konvertieren Sekunden bis Stunden in SELECT-Abfrage:

SELECT field_in_seconds,round((field_in_seconds / 3600),2) FROM a_table;

Dies wird Ihnen das Ergebnis im Dezimalformat. Nicht sicher, wie 1,50 bis 1:30 zu konvertieren. Bitte zögern Sie nicht meinen Code bearbeiten!