كيفية القضاء على قواعد العقد المكررة على قيم سمات متعددة؟
https://stackoverflow.com/questions/4613267
italiano
english
français
española
中国
日本の
العربية
Deutsch
한국어
Português
Russianسؤال
كيف يمكنني القضاء على العقد المكررة بناءً على قيم سمات متعددة (أكثر من 1)؟ كما يتم تمرير أسماء السمات كمعلمات إلى ورقة الأنماط. الآن أنا على دراية بالطريقة المنازية للتجميع التي تستخدم أ <xsl:key> عنصر. لكنني عرفت أن XSLT 1.0 لا يسمح للمعايير/المتغيرات في <xsl:key>.
هل هناك طريقة (طرق) أخرى لتحقيق إزالة العقد المكررة؟ لا بأس إذا لم تكن فعالة مثل طريقة Munechian.
تحديث من Previus سؤال:
XML:
<data id = "root"> <record id="1" operator1='xxx' operator2='yyy' operator3='zzz'/> <record id="2" operator1='abc' operator2='yyy' operator3='zzz'/> <record id="3" operator1='abc' operator2='yyy' operator3='zzz'/> <record id="4" operator1='xxx' operator2='yyy' operator3='zzz'/> <record id="5" operator1='xxx' operator2='lkj' operator3='tyu'/> <record id="6" operator1='xxx' operator2='yyy' operator3='zzz'/> <record id="7" operator1='abc' operator2='yyy' operator3='zzz'/> <record id="8" operator1='abc' operator2='yyy' operator3='zzz'/> <record id="9" operator1='xxx' operator2='yyy' operator3='zzz'/> <record id="10" operator1='rrr' operator2='yyy' operator3='zzz'/> </data>
المحلول
استخدم هذا التحول (بسيطة ولا حاجة لتوليد ورقة أنماط جديدة):
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ext="http://exslt.org/common">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="pAttribs">
<name>operator1</name>
<name>operator2</name>
<name>operator3</name>
</xsl:param>
<xsl:variable name="vAttribs" select=
"document('')/*/xsl:param[@name='pAttribs']"/>
<xsl:key name="kRecByAtts" match="record"
use="@___g_key"/>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="/">
<xsl:variable name="vrtdPass1">
<xsl:apply-templates/>
</xsl:variable>
<xsl:variable name="vPass1" select=
"ext:node-set($vrtdPass1)/*"/>
<xsl:apply-templates select="$vPass1"/>
</xsl:template>
<xsl:template match="record[not(@___g_key)]">
<xsl:copy>
<xsl:copy-of select="@*"/>
<xsl:attribute name="___g_key">
<xsl:for-each select="@*[name()=$vAttribs/name]">
<xsl:sort select="name()"/>
<xsl:value-of select=
"concat('___Attrib___',name(),'___Value___',.,'+++')"/>
</xsl:for-each>
</xsl:attribute>
</xsl:copy>
</xsl:template>
<xsl:template match=
"record[@___g_key]
[not(generate-id()
=
generate-id(key('kRecByAtts', @___g_key)[1])
)
]
"/>
<xsl:template match="@___g_key"/>
</xsl:stylesheet>
عند تطبيقه على مستند XML لسؤالك السابق:
<data id = "root">
<record id="1" operator1='xxx' operator2='yyy' operator3='zzz'/>
<record id="2" operator1='abc' operator2='yyy' operator3='zzz'/>
<record id="3" operator1='abc' operator2='yyy' operator3='zzz'/>
<record id="4" operator1='xxx' operator2='yyy' operator3='zzz'/>
<record id="5" operator1='xxx' operator2='lkj' operator3='tyu'/>
<record id="6" operator1='xxx' operator2='yyy' operator3='zzz'/>
<record id="7" operator1='abc' operator2='yyy' operator3='zzz'/>
<record id="8" operator1='abc' operator2='yyy' operator3='zzz'/>
<record id="9" operator1='xxx' operator2='yyy' operator3='zzz'/>
<record id="10" operator1='rrr' operator2='yyy' operator3='zzz'/>
</data>
يتم إنتاج النتيجة الصحيحة المطلوبة:
<data id="root">
<record id="1" operator1="xxx" operator2="yyy" operator3="zzz"/>
<record id="2" operator1="abc" operator2="yyy" operator3="zzz"/>
<record id="5" operator1="xxx" operator2="lkj" operator3="tyu"/>
<record id="10" operator1="rrr" operator2="yyy" operator3="zzz"/>
</data>
نصائح أخرى
نهج آخر لتحول واحد في خطوتين:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:msxsl="urn:schemas-microsoft-com:xslt"
exclude-result-prefixes="msxsl">
<xsl:key name="kItemByLocal" match="record[@local-key]" use="@local-key"/>
<xsl:param name="pAttNames" select="'operator1 operator2 operator3'"/>
<xsl:template match="/">
<xsl:variable name="vFirstRTF">
<xsl:apply-templates/>
</xsl:variable>
<xsl:apply-templates select="msxsl:node-set($vFirstRTF)/node()"/>
</xsl:template>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="record[not(@local-key)]">
<xsl:copy>
<xsl:attribute name="local-key">
<xsl:call-template name="local-key"/>
</xsl:attribute>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="record[@local-key]
[count(.|key('kItemByLocal',@local-key)[1])
!= 1]|@local-key"/>
<xsl:template name="local-key">
<xsl:param name="pAttributes" select="concat($pAttNames,' ')"/>
<xsl:if test="normalize-space($pAttributes)">
<xsl:variable name="vName"
select="substring-before($pAttributes,' ')"/>
<xsl:variable name="vAttribute" select="@*[name()=$vName]"/>
<xsl:value-of select="concat($vName,'+',$vAttribute,'+')"/>
<xsl:call-template name="local-key">
<xsl:with-param name="pAttributes"
select="substring-after($pAttributes,' ')"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
انتاج:
<data id="root">
<record id="1" operator1="xxx" operator2="yyy" operator3="zzz"></record>
<record id="2" operator1="abc" operator2="yyy" operator3="zzz"></record>
<record id="5" operator1="xxx" operator2="lkj" operator3="tyu"></record>
<record id="10" operator1="rrr" operator2="yyy" operator3="zzz"></record>
</data>
يحرر: أيضا بدون قالب اسمه @local-key توليد
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:msxsl="urn:schemas-microsoft-com:xslt"
exclude-result-prefixes="msxsl">
<xsl:key name="kItemByLocal" match="record[@local-key]" use="@local-key"/>
<xsl:param name="pAttNames" select="'operator1 operator2 operator3'"/>
<xsl:template match="/">
<xsl:variable name="vFirstRTF">
<xsl:apply-templates/>
</xsl:variable>
<xsl:apply-templates select="msxsl:node-set($vFirstRTF)/node()"/>
</xsl:template>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="record[not(@local-key)]">
<xsl:variable name="vAttNames"
select="concat(' ',$pAttNames,' ')"/>
<xsl:copy>
<xsl:attribute name="local-key">
<xsl:for-each select="@*[contains(
$vAttNames,
concat(' ',name(),' ')
)]">
<xsl:sort select="substring-before(
$vAttNames,
concat(' ',name(),' ')
)"/>
<xsl:value-of select="concat(name(),'++',.,'++')"/>
</xsl:for-each>
</xsl:attribute>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="record[@local-key]
[count(.|key('kItemByLocal',@local-key)[1])
!= 1]|@local-key"/>
</xsl:stylesheet>
ملحوظة: إذا كنت متأكدًا من أن ترتيب السمات هو نفسه بالنسبة لجميع العناصر ، فيمكنك إزالة الفرز.
إذا كنت ترغب في تمرير أسماء السمات كمعلمة ، فقد يكون نهج واحد هو تحويل من خطوتين حيث تأخذ الخطوة الأولى أي إدخال XML وببساطة أسماء السمات وأسماء العناصر كمعلمات لإنشاء ورقة أنماط ثانية تقوم بعد ذلك بإلغاء التكرار . فيما يلي مثال على ورقة الأنماط الأولى:
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
xmlns:axsl="http://www.w3.org/1999/XSL/TransformAlias"
exclude-result-prefixes="axsl exsl"
version="1.0">
<xsl:param name="parent-name" select="'items'"/>
<xsl:param name="element-name" select="'item'"/>
<xsl:param name="att-names" select="'att1,att2'"/>
<xsl:param name="sep" select="'|'"/>
<xsl:namespace-alias stylesheet-prefix="axsl" result-prefix="xsl"/>
<xsl:output method="xml" indent="yes"/>
<xsl:variable name="key-value">
<xsl:text>concat(</xsl:text>
<xsl:call-template name="define-values">
<xsl:with-param name="att-names" select="$att-names"/>
</xsl:call-template>
<xsl:text>)</xsl:text>
</xsl:variable>
<xsl:template name="define-values">
<xsl:param name="att-names"/>
<xsl:choose>
<xsl:when test="contains($att-names, ',')">
<xsl:value-of select="concat('@', substring-before($att-names, ','), ',"', $sep, '",')"/>
<xsl:call-template name="define-values">
<xsl:with-param name="att-names" select="substring-after($att-names, ',')"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="concat('@', $att-names)"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="/">
<axsl:stylesheet version="1.0">
<axsl:output indent="yes"/>
<axsl:key name="k1" match="{$parent-name}/{$element-name}" use="{$key-value}"/>
<axsl:template match="@* | node()">
<axsl:copy>
<axsl:apply-templates select="@* | node()"/>
</axsl:copy>
</axsl:template>
<axsl:template match="{$parent-name}">
<axsl:copy>
<axsl:apply-templates select="@*"/>
<axsl:apply-templates select="{$element-name}[generate-id() = generate-id(key('k1', {$key-value})[1])]"/>
</axsl:copy>
</axsl:template>
</axsl:stylesheet>
</xsl:template>
</xsl:stylesheet>
يستغرق أربعة معلمات:
parent-name: اسم العنصر الذي يحتوي على تلك العناصر التي تريد القضاء عليها التكراراتelement-name: اسم تلك العناصر التي تريد التخلص منها التكراراتatt-names: قائمة مفصولة بأسماء السماتsep: حرف فاصل لا ينبغي أن يحدث في قيم السمات في إدخال XML
ثم تقوم ورقة الأنماط بإنشاء ورقة الأنماط الثانية التي تطبق مجموعة Muenchian للتخلص من التكرارات. على سبيل المثال مع المعلمات الافتراضية الواردة في ورقة الأنماط Saxon 6.5.5 يولد ورقة الأنماط التالية:
<axsl:stylesheet xmlns:axsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<axsl:output indent="yes"/>
<axsl:key name="k1" match="items/item" use="concat(@att1,"|",@att2)"/>
<axsl:template match="@* | node()">
<axsl:copy>
<axsl:apply-templates select="@* | node()"/>
</axsl:copy>
</axsl:template>
<axsl:template match="items">
<axsl:copy>
<axsl:apply-templates select="@*"/>
<axsl:apply-templates select="item[generate-id() = generate-id(key('k1', concat(@att1,"|",@att2))[1])]"/>
</axsl:copy>
</axsl:template>
</axsl:stylesheet>
يمكن تطبيق هذا على مستند XML مثل
<items>
<item att1="a" att2="1" att3="A"/>
<item att1="b" att2="1" att3="A"/>
<item att1="a" att2="1" att3="B"/>
<item att1="c" att2="2" att3="A"/>
<item att1="d" att2="3" att3="C"/>
</items>
والإخراج هو
<items>
<item att1="a" att2="1" att3="A"/>
<item att1="b" att2="1" att3="A"/>
<item att1="c" att2="2" att3="A"/>
<item att1="d" att2="3" att3="C"/>
</items>
لا تنتمي إلى StackOverflow
