لودر واحد لالعفريت متعددة ممكن؟

Question

ولقد بحثت في مختلف الموارد فيما يتعلق بهذا الموضوع، ويبدو لي أن أحتاج إلى لودر لكل العفريت الذي يحتوي على ملف صورة (بابوا غينيا الجديدة).

وأنا أحاول أن جعل نظام التقديم بلاطة، وخلقت شبكة من X من قبل العفاريت Y، ولكن كل منهم الرجوع إلى نفس الملف صورة الواقع. أهناك أي طريقة أخرى لعمل هذا؟ (جعل نفس الملف البيانات بابوا نيو غينيا حصة العفريت)

وبعض نموذج التعليمات البرمجية ما فعلت.

// Create an array of X * Y Loaders
var cTileLoaders:Array = new Array( 100 ); // for example 10 by 10 grid
var cTiles:Array = new Array( 100 );
var nIndex:int = 0;
var nImgLoadCount:int = 0;
for ( ; 100 > nIndex; ++nIndex ) {
    cTileLoaders[ nIndex ] = new Loader();
    cTiles[ nIndex ] = new Sprite();
    // perform more sprite initialization
    ....
    cTileLoaders[ nIndex ].contentLoaderInfo.addEventListener( Event.COMPLETE, ImageLoaded
    cTileLoaders[ nIndex ].Load( new URLRequest( "some image path" ) );
}
// handler for image loaded
function ImageLoaded( eEvent:Event ):void {
    ++nImgLoadCount;
    // when all 100 sprite data are loaded
    // assuming there is no i/o error
    if ( 100 == nImgLoadCount ) { 
        cTiles[ nIndex ].addChild( cTileLoaders[ nIndex ].content );
    }
}

Answer 1

وأعتقد أن الإجابة في حالتك هو استخدام البيانات النقطية الموجود في الصورة كنت تحمل مثل هذا:

var tilesWide:uint = 10;
var tilesHigh:uint = 10;

var tileHolder:Sprite = new Sprite();
this.addChild(tileHolder);

var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onImgLoaded);
loader.load(new URLRequest("tile.png"));

function onImgLoaded(e:Event):void
{
    /* Create a template bitmap to hold the image info */
    var templateBitmap:Bitmap = e.target.content;
    var templateBitmapData:BitmapData = templateBitmap.bitmapData;

    /* Loop through your tiles */
    for (var a:uint = 0; a < tilesWide; a++)
    {
        for (var b:uint = 0; b < tilesHigh; b++)
        {
            var tile:Sprite = new Sprite();
            /* Attach the template BitmapData to each tile */
            var tileBitmap:Bitmap = new Bitmap(templateBitmapData);
            tile.addChild(tileBitmap);

            tile.x = a * tile.width;
            tile.y = b * tile.height;

            tileHolder.addChild(tile);
        }
    }
}

Answer 2

ويمكنك أيضا استخدام SpriteFactory أو قليلا مكتبة كتبت خصيصا لهذا:

var tilesWide:uint = 10;
var tilesHigh:uint = 10;
var tileHolder:Sprite = new Sprite();
var tilePath:String = "some/image/path.png";

var factory:SpriteFactory = new SpriteFactory();
factory.loadBitmap("tile", tilePath);

for (var a:uint = 0; a < tilesWide; a++)
{
    for (var b:uint = 0; b < tilesHigh; b++)
    {
        var tile:Sprite = factory.newSprite("tile");                        
        tile.x = a * tile.width;
        tile.y = b * tile.height;

        tileHolder.addChild(tile);
    }
}

والميزة هنا يجري التي يمكنك استخدامها العفاريت على الفور، وأنها سوف تلقائيا امتلئوا نقطية بمجرد تحميله.