كيف العديد من الطرق المختلفة هناك لسلسلة ملفين سطرا باستخدام بيرل?

Question

لنفترض file1 يبدو مثل هذا:

bye bye
hello
thank you

و file2 يبدو مثل هذا:

chao
hola
gracias

الإخراج المطلوب هو هذا:

bye bye chao
hello hola
thank you gracias

أنا نفسي قد حان بالفعل مع خمسة أساليب مختلفة لحل هذه المشكلة.لكن أعتقد يجب أن يكون هناك المزيد من الطرق ، وربما أكثر إيجازا وأكثر أناقة الطرق ، وآمل أن أتمكن من معرفة المزيد من الاشياء باردة :)

التالي هو ما كنت قد حاولت حتى الآن ، بناء على ما تعلمته من العديد من الحلول من المشاكل السابقة.أيضا, أنا أحاول نوع من هضم أو استيعاب المعرفة التي اكتسبتها من اللاما الكتاب.

رمز 1:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';

while(defined(my $line1 = <$file1>)
        and defined(my $line2 = <$file2>)){
    die "Files are different sizes!\n" unless eof(file1) == eof(file2);
    $line1 .= $line2;
    $line1 =~ s/\n/ /;
    print "$line1 \n";
}

التعليمات البرمجية 2:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
my @file1 = <$file1>;

open my $file2,'<','c:/file2.txt';
my @file2 =<$file2>;

for (my $n=0; $n<=$#file1; $n++) {
    $file1[$n] .=$file2[$n];
    $file1[$n]=~s/\n/ /;
    print $file1[$n];
}

رمز 3:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';

my %hash;

while(defined(my $line1 = <$file1>)
      and defined(my $line2 = <$file2>)) {
  chomp $line1;
  chomp $line2;
  my ($key, $val) = ($line1,$line2);
  $hash{$key} = $val;
}
print map { "$_ $hash{$_}\n" } sort keys %hash;

كود 4:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';

while(defined(my $line1 = <$file1>)
      and defined(my $line2 = <$file2>)) {
  $line1 =~ s/(.+)/$1 $line2/;
  print $line1;
}

كود 5:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
my @file1 =<$file1>;

open my $file2,'<','c:/file2.txt';
my @file2 =<$file2>;

while ((@file1) && (@file2)){ 
    my $m = shift (@file1);
    chomp($m);

    my $n = shift (@file2);
    chomp($n);

    $m .=" ".$n;
    print "$m \n";
}

لقد حاولت شيئا من هذا القبيل:

foreach $file1 (@file2) && foreach $file2 (@file2) {...}

ولكن بيرل أعطاني النحوية تحذير خطأ.لقد كنت محبطا.ولكن يمكننا تشغيل اثنين foreach الحلقات في وقت واحد ؟

شكرا دائما عن أي تعليقات أو اقتراحات و بالطبع السخي كود مشاركة :)

Answer 1

وهذا يعمل على أي عدد من الملفات:

use strict;
use warnings;
use autodie;

my @handles = map { open my $h, '<', $_; $h } @ARGV;

while (@handles){
    @handles = grep { ! eof $_ } @handles;
    my @lines = map { my $v = <$_>; chomp $v; $v } @handles;
    print join(' ', @lines), "\n";
}

close $_ for @handles;

Answer 2

والطريقة الأكثر أناقة لا تنطوي perl على الإطلاق:

paste -d' ' file1 file2

Answer 3

إذا كنت الغولف رجل يمكنني كتابة @FM الجواب كما:

($,,$\)=(' ',"\n");@_=@ARGV;open $_,$_ for @_;print
map{chomp($a=<$_>);$a} @_=grep{!eof $_} @_ while @_

والتي قد تكون قادرة على أن تتحول إلى بطانة واحدة ولكن هذا هو مجرد الشر.;-)

ها هو تحت 100 الشخصيات:

C:\Temp> perl -le "$,=' ';@_=@ARGV;open $_,$_ for @_;print map{chomp($a =<$_>);$a} @_=grep{!eof $_ }@_ while @_" file1 file2

إذا كان على ما يرام إلى ملتهم (و لماذا لا هيك نحن هي تبحث عن طرق مختلفة) ، أعتقد أنني قد اكتشفت مسار الجنون:

@_=@ARGV;chomp($x[$.-1]{$ARGV}=$_) && eof
and $.=0 while<>;print "@$_{@_}\n" for @x

C:\Temp> perl -e "@_=@ARGV;chomp($x[$.-1]{$ARGV}=$_) && eof and $.=0 while<>;print qq{@$_{@_}\n} for @x" file1 file2

الإخراج:

bye bye chao
hello hola
thank you gracias

Answer 4

أسهل البديل الخاص بك كود 5 والذي يسمح للحصول على عدد التعسفي من خطوط و لا يهتم إن كانت الملفات تحتوي على أرقام مختلفة من الخطوط (قبعة تلميح @FM):

#!/usr/bin/perl

use strict; use warnings;

use File::Slurp;
use List::AllUtils qw( each_arrayref );

my @lines = map [ read_file $_ ], @ARGV;

my $it = each_arrayref @lines;

while ( my @lines = grep { defined and chomp and length } $it->() ) {
    print join(' ', @lines), "\n";
}

و دون استخدام أي وحدات الخارجية:

#!perl
use autodie; use warnings; use strict;

my ($file1, $file2) = @ARGV;

open my $file1_h,'<', $file1;
my @file1 = grep { chomp; length } <$file1_h>;

open my $file2_h,'<', $file2;
my @file2 =  grep { chomp; length } <$file2_h>;

my $n_lines = @file1 > @file2 ? @file1 : @file2;

for my $i (0 .. $n_lines - 1) {
    my ($line1, $line2) = map {
        defined $_ ? $_ : ''
    } $file1[$i], $file2[$i];
    print $line1, ' ', $line2, "\n";
}

إذا كنت تريد لسلسلة فقط الخطوط التي تظهر في كل الملفات:

#!perl
use autodie; use warnings; use strict;

my ($file1, $file2) = @ARGV;

open my $file1_h,'<', $file1;
my @file1 = grep { chomp; length } <$file1_h>;

open my $file2_h,'<', $file2;
my @file2 =  grep { chomp; length } <$file2_h>;

my $n_lines = @file1 < @file2 ? @file1 : @file2;

for my $i (0 .. $n_lines - 1) {
    print $file1[$i], ' ', $file2[$i], "\n";
}

Answer 5

وسيلة سهلة واحدة مع الحد الأدنى من التحقق من الخطأ:

#!/usr/bin/perl -w

use strict;

open FILE1, '<file1.txt';
open FILE2, '<file2.txt';

while (defined(my $one = <FILE1>) or defined(my $twotemp = <FILE2>)){
    my $two = $twotemp ? $twotemp : <FILE2>;
    chomp $one if ($one);
    chomp $two if ($two);
    print ''.($one ? "$one " : '').($two ? $two : '')."\n";
}

ولا، لا يمكنك تشغيل اثنين من الحلقات في وقت واحد في نفس الموضوع، وكنت قد لfork، ولكن ذلك لن تكون مضمونة لتشغيل بشكل متزامن.