¿De cuántas maneras diferentes hay para concatenar dos archivos línea por línea usando Perl?

Question

Suponga que el archivo1 se ve así:

bye bye
hello
thank you

Y file2 se ve así:

chao
hola
gracias

El resultado deseado es este:

bye bye chao
hello hola
thank you gracias

Yo mismo ya he ideado cinco enfoques diferentes para resolver este problema. Pero creo que debe haber más formas, probablemente formas más concisas y elegantes, y espero poder aprender más cosas interesantes :)

Lo siguiente es lo que he intentado hasta ahora, basado en lo que he aprendido de las muchas soluciones de mis problemas anteriores. Además, estoy tratando de digerir o internalizar el conocimiento que adquirí del libro Llama.

Código 1:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';

while(defined(my $line1 = <$file1>)
        and defined(my $line2 = <$file2>)){
    die "Files are different sizes!\n" unless eof(file1) == eof(file2);
    $line1 .= $line2;
    $line1 =~ s/\n/ /;
    print "$line1 \n";
}

Código 2:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
my @file1 = <$file1>;

open my $file2,'<','c:/file2.txt';
my @file2 =<$file2>;

for (my $n=0; $n<=$#file1; $n++) {
    $file1[$n] .=$file2[$n];
    $file1[$n]=~s/\n/ /;
    print $file1[$n];
}

Código 3:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';

my %hash;

while(defined(my $line1 = <$file1>)
      and defined(my $line2 = <$file2>)) {
  chomp $line1;
  chomp $line2;
  my ($key, $val) = ($line1,$line2);
  $hash{$key} = $val;
}
print map { "$_ $hash{$_}\n" } sort keys %hash;

Código 4:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';

while(defined(my $line1 = <$file1>)
      and defined(my $line2 = <$file2>)) {
  $line1 =~ s/(.+)/$1 $line2/;
  print $line1;
}

Código 5:

#!perl
use autodie;
use warnings;
use strict;

open my $file1,'<','c:/file1.txt';
my @file1 =<$file1>;

open my $file2,'<','c:/file2.txt';
my @file2 =<$file2>;

while ((@file1) && (@file2)){ 
    my $m = shift (@file1);
    chomp($m);

    my $n = shift (@file2);
    chomp($n);

    $m .=" ".$n;
    print "$m \n";
}

He intentado algo como esto:

foreach $file1 (@file2) && foreach $file2 (@file2) {...}

Pero Perl me dio una advertencia de error sintáctico. Estaba frustrado ¿Pero podemos ejecutar dos foreach bucles simultáneamente?

Gracias, como siempre, por cualquier comentario, sugerencia y, por supuesto, el generoso intercambio de código :)

Answer 1

Esto funciona para cualquier número de archivos:

use strict;
use warnings;
use autodie;

my @handles = map { open my $h, '<', $_; $h } @ARGV;

while (@handles){
    @handles = grep { ! eof $_ } @handles;
    my @lines = map { my $v = <$_>; chomp $v; $v } @handles;
    print join(' ', @lines), "\n";
}

close $_ for @handles;

Answer 2

La forma más elegante no implica perl en absoluto:

paste -d' ' file1 file2

Answer 3

Si fuera un jugador de golf, podría volver a escribir Respuesta de @ FM como:

($,,$\)=(' ',"\n");@_=@ARGV;open $_,$_ for @_;print
map{chomp($a=<$_>);$a} @_=grep{!eof $_} @_ while @_

que puede ser capaz de convertir en una sola línea, pero eso es simplemente malvado. ;-)

Bueno, aquí está, con menos de 100 caracteres:

C:\Temp> perl -le "$,=' ';@_=@ARGV;open $_,$_ for @_;print map{chomp($a =<$_>);$a} @_=grep{!eof $_ }@_ while @_" file1 file2

Si está bien sorber (y ¿por qué diablos no & # 8212; nosotros somos buscando diferentes formas), creo que he descubierto el camino la locura:

@_=@ARGV;chomp($x[$.-1]{$ARGV}=$_) && eof
and $.=0 while<>;print "@$_{@_}\n" for @x

C:\Temp> perl -e "@_=@ARGV;chomp($x[$.-1]{$ARGV}=$_) && eof and $.=0 while<>;print qq{@$_{@_}\n} for @x" file1 file2

Salida:

bye bye chao
hello hola
thank you gracias

Answer 4

Una alternativa más fácil a su Código 5 que permite un número arbitrario de líneas y no le importa si los archivos tienen un número diferente de líneas (hat tip @FM):

#!/usr/bin/perl

use strict; use warnings;

use File::Slurp;
use List::AllUtils qw( each_arrayref );

my @lines = map [ read_file $_ ], @ARGV;

my $it = each_arrayref @lines;

while ( my @lines = grep { defined and chomp and length } $it->() ) {
    print join(' ', @lines), "\n";
}

Y, sin usar ningún módulo externo:

#!perl
use autodie; use warnings; use strict;

my ($file1, $file2) = @ARGV;

open my $file1_h,'<', $file1;
my @file1 = grep { chomp; length } <$file1_h>;

open my $file2_h,'<', $file2;
my @file2 =  grep { chomp; length } <$file2_h>;

my $n_lines = @file1 > @file2 ? @file1 : @file2;

for my $i (0 .. $n_lines - 1) {
    my ($line1, $line2) = map {
        defined $_ ? $_ : ''
    } $file1[$i], $file2[$i];
    print $line1, ' ', $line2, "\n";
}

Si desea concatenar solo las líneas que aparecen en ambos archivos:

#!perl
use autodie; use warnings; use strict;

my ($file1, $file2) = @ARGV;

open my $file1_h,'<', $file1;
my @file1 = grep { chomp; length } <$file1_h>;

open my $file2_h,'<', $file2;
my @file2 =  grep { chomp; length } <$file2_h>;

my $n_lines = @file1 < @file2 ? @file1 : @file2;

for my $i (0 .. $n_lines - 1) {
    print $file1[$i], ' ', $file2[$i], "\n";
}

Answer 5

Fácil con una mínima verificación de errores:

#!/usr/bin/perl -w

use strict;

open FILE1, '<file1.txt';
open FILE2, '<file2.txt';

while (defined(my $one = <FILE1>) or defined(my $twotemp = <FILE2>)){
    my $two = $twotemp ? $twotemp : <FILE2>;
    chomp $one if ($one);
    chomp $two if ($two);
    print ''.($one ? "$one " : '').($two ? $two : '')."\n";
}

Y no, no puede ejecutar dos bucles simultáneamente dentro del mismo hilo, tendría que fork, pero no se garantizaría que se ejecute sincrónicamente.