在pascalcase中转换文本
-
10-10-2019 - |
题
是否可以仅使用适当的SQL代码将文本从SQL Server中的表列转换为Pascalcase?
TABLE DEFINITION
----------------------
ID int
CITTA varchar(50)
PROV varchar(50)
CAP varchar(50)
COD varchar(50)
包含要转换文本的字段是 CITTA
. 。它包含所有大写值,例如“ Abano Terme”,“ Roma”等。单词是由空间界定的。
编辑
我忘了提到有些单词中有一个强调字符 '
. 。可以在单词的末尾或中间找到此字符。
编辑2:
在结果上发现了一些怪癖:
- 如果我有一个名字,例如“ Isela balba”,则将此名称翻译成“ Iselabalba”(正确的情况,但错过了空间)
- 如果我的名字像“ Isela d'Asti”之类
您能给我一些关于这个小问题的建议吗?
解决方案
DECLARE @T TABLE
(
ID INT PRIMARY KEY,
CITTA VARCHAR(50)
)
INSERT INTO @T
SELECT 1, 'ABANO TERME' UNION ALL SELECT 2, 'ROMA' UNION ALL SELECT 3, 'ISOLA D''ASTI';
IF OBJECT_ID('tempdb..#HolderTable') IS NOT NULL
DROP TABLE #HolderTable
CREATE TABLE #HolderTable
(
Idx INT IDENTITY(1,1) PRIMARY KEY,
ID INT,
Word VARCHAR(50)
)
CREATE NONCLUSTERED INDEX ix ON #HolderTable(ID)
;
WITH T1 AS
(
SELECT ID, CAST(N'<root><r>' + REPLACE(REPLACE(CITTA, '''', '''</r><r>'), ' ', ' </r><r>') + '</r></root>' AS XML) AS xl
FROM @T
)
INSERT INTO #HolderTable
SELECT ID,
r.value('.','NVARCHAR(MAX)') AS Item
FROM T1
CROSS APPLY
xl.nodes('//root/r') AS RECORDS(r)
SELECT
ID,
(SELECT STUFF(LOWER(Word),1,1,UPPER(LEFT(Word,1))) FROM #HolderTable WHERE [@T].ID = #HolderTable.ID ORDER BY Idx FOR XML PATH('') )
FROM @T [@T]
其他提示
我鼓励您尝试不久前在博客中发布的代码。我怀疑它将很好地满足您的要求,并且比其他许多方法都更好。
CREATE FUNCTION dbo.Proper(@DATA VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
DECLARE @Position INT
SELECT @DATA = STUFF(LOWER(@DATA), 1, 1, UPPER(LEFT(@DATA, 1))),
@Position = PATINDEX('%[^a-zA-Z][a-z]%', @DATA COLLATE Latin1_General_Bin)
WHILE @Position > 0
SELECT @DATA = STUFF(@DATA, @Position, 2, UPPER(SUBSTRING(@DATA, @Position, 2))),
@Position = PATINDEX('%[^a-zA-Z][a-z]%', @DATA COLLATE Latin1_General_Bin)
RETURN @DATA
END
此功能比大多数人要快一点,因为它仅适用于需要大写字母的每个单词一次。
尝试以下功能(适当调整字符串类型)。只是不要在Where子句中使用它 - 并考虑其他地方的性能分析。 12345678只是您可能想替换为更合适的东西的任意大价值!
CREATE FUNCTION dbo.ufn_PascalCase(@str AS VARCHAR(MAX)) RETURNS VARCHAR(MAX)
BEGIN
SET @str = LOWER(@str)
DECLARE @result VARCHAR(MAX) = ''
DECLARE @spaceIndex INTEGER = CHARINDEX(' ', @str)
WHILE @spaceIndex > 0
BEGIN
SET @result += UPPER(SUBSTRING(@str, 1, 1)) + SUBSTRING(@str, 2, @spaceIndex - 2)
SET @str = SUBSTRING(@str, @spaceIndex + 1, 12345678)
SET @spaceIndex = CHARINDEX(' ', @str)
END
SET @result += UPPER(SUBSTRING(@str, 1, 1)) + SUBSTRING(@str, 2, 12345678)
RETURN @result
END
不隶属于 StackOverflow