模块消息拦截器VS消息拦截器

Question

我正在使用Cairngorm模块库和欧芹在Flex中开发应用程序。

欧芹文档第5章说：“当您想要决定消息是否应传递给处理程序时，拦截器可能会派上友好。

使用ModuleMessageInterceptor时，上面的不是真的。这意味着我的MessageHandler在MessageInterceptor之前接收消息。

有谁知道周围的工作？

问候，

fadi

Answer 1

解决此问题的解决方案正在扩展ModuleMessageInterceptor类，如下所示：

package fr.core.patch.cairngorm
{
    import com.adobe.cairngorm.module.ModuleIdMetadata;
    import com.adobe.cairngorm.module.ModuleMessageDispatcher;
    import com.adobe.cairngorm.module.ModuleMessageInterceptor;
    import com.adobe.cairngorm.module.ParsleyModuleMessage;

    import flash.system.ApplicationDomain;

    import org.spicefactory.lib.reflect.ClassInfo;
    import org.spicefactory.lib.reflect.Property;
    import org.spicefactory.parsley.core.registry.ObjectDefinitionRegistry;
    import org.spicefactory.parsley.core.registry.RootObjectDefinition;
    import org.spicefactory.parsley.tag.messaging.MessageHandlerDecorator;
    import org.spicefactory.parsley.tag.messaging.MessageInterceptorDecorator;

    public class ATPModuleMessageInterceptor extends ModuleMessageInterceptor
    {
        public function ATPModuleMessageInterceptor()
        {
            super();
        }

        public var order:int;

        private var target:Property;

        override public function process(registry:ObjectDefinitionRegistry):void
        {
            target=getModuleIdTargetProperty(registry.domain);

            var interceptor:MessageInterceptorDecorator=new MessageInterceptorDecorator();
            interceptor.type=type;
            interceptor.selector=selector;
            interceptor.method="interceptModuleMessage";
            interceptor.order = order;

            var messageHandler:MessageHandlerDecorator=new MessageHandlerDecorator();
            messageHandler.type=ParsleyModuleMessage;
            messageHandler.method="parsleyModuleMessageHandler";

            var definition:RootObjectDefinition=registry.builders.forRootDefinition(ModuleMessageDispatcher).decorators([interceptor, messageHandler]).buildAndRegister();

            definition.constructorArgs.addValue(target);

            if (moduleRef)
            {
                definition.constructorArgs.addIdReference(moduleRef);
            }
        }

        private function getModuleIdTargetProperty(domain:ApplicationDomain):Property
        {
            var props:Array=ClassInfo.forClass(type, domain).getProperties();

            for each (var prop:Property in props)
            {
                if (prop.hasMetadata(ModuleIdMetadata))
                {
                    return prop;
                }
            }

            return null;
        }
    }
}

.

通过执行上面，我们将订单属性添加到ModuleMessageInterctiveor，该Interceptor解决了我所拥有的问题。

问候，

Fadi Mansour

Answer 2

在荷兰娱乐2.4中，Message Interceptors已被剥夺：

和modulemessageinterceptor不是欧芹的东西，这是一个尖锐风暴的东西。就个人而言，由于我的经验，我会留在Cairngorm。在网上看，我看到了其他人有类似的问题。你最好的选择是在同一论坛上发布，希望有人帮助。