镜面照明出现在物体的面向眼睛的两侧和后侧

Question

我正在编写一个 Phong 着色的小测试，并且正在用头撞砖墙，试图让镜面组件正常工作。它似乎工作正常，除了镜面光应用于对象的前部和后部。（对象本身是透明的，其面在 CPU 端手动排序。）

请注意，漫反射组件工作完美（仅显示在面向光源的一侧）——我认为这似乎排除了到达片段着色器的法线的问题。

据我了解，镜面反射分量与眼睛矢量和反射光矢量之间的角度的余弦成正比。

为了让事情变得非常简单，我的测试代码尝试在世界空间中执行此操作。相机位置和光矢量被硬编码（抱歉）为 (0,0,4) 和 (-0.707, 0, -0.707) 分别。因此眼睛向量是 (0,0,4) - fragPosition.

由于模型矩阵仅执行旋转，因此顶点着色器只需通过模型矩阵变换顶点法线即可。（笔记： 这不是一个好的做法，因为许多类型的变换不能保持正常的正交性。一般对于正规矩阵， 你应该使用 模型矩阵左上角 3x3 的逆转置。）为了简单起见，片段着色器在单个浮点颜色通道上运行，并跳过镜面指数（/使用指数 1）。

顶点着色器：

#version 140

uniform mat4 mvpMtx;
uniform mat4 modelMtx;

in vec3 inVPos;
in vec3 inVNormal;

out vec3 normal_world;
out vec3 fragpos_world;

void main(void) {
  gl_Position = mvpMtx * vec4(inVPos, 1.0);
  normal_world = vec3(modelMtx * vec4(inVNormal, 0.0));
  fragpos_world = vec3(modelMtx * vec4(inVPos, 1.0)); 
}

片段着色器：

#version 140

uniform float
    uLightS,
    uLightD,
    uLightA;

uniform float uObjOpacity;

in vec3 normal_world, fragpos_world;
out vec4 fragOutColour;

void main(void) {

    vec3 vN = normalize(normal_world);
    vec3 vL = vec3(-0.707, 0, -0.707);

    // Diffuse:
    // refl in all directions is proportional to cos(angle between -light vector & normal)
    // i.e. proportional to -l.n
    float df = max(dot(-vL, vN), 0.0);

    // Specular:
    // refl toward eye is proportional to cos(angle between eye & reflected light vectors)
    // i.e. proportional to r.e
    vec3 vE = normalize(vec3(0, 0, 4) - fragpos_world);
    vec3 vR = reflect(vL, vN);
    float sf = max(dot(vR, vE), 0.0);

    float col = uLightA + df*uLightD + sf*uLightS;

    fragOutColour = vec4(col, col, col, uObjOpacity);

}

我在这里找不到错误；谁能解释为什么镜面反射分量出现在物体的背面以及面向光的一侧？

非常感谢。

Answer 1

实际上，正面和背面的镜面反射贡献是相同的，因为 GLSL reflect 对法线的符号不敏感。从 这个参考:

reflect(I, N) = I - 2.0 * dot(N, I) * N

因此翻转 N 的符号会引入两个抵消的减号。用言语来说，什么 reflect 所做的就是反转分量的符号 I 它沿着与 N. 。这并不取决于哪种方式 N 面临。

如果您想从背面去除镜面反射分量，我认为您需要明确检查您的 dot(vE,vN).

Answer 2

尝试更改

fragpos_world = vec3(modelMtx * vec4(inVPos, 0.0)); 

.

fragpos_world = vec3(modelMtx * vec4(inVPos, 1.0)); 

.

因为 http：//www.opengl -turtorial。ORG /初学者 - 教程/教程-3矩阵/＃同主题_COORDINATE