Delphi-在OSX上获取完整的堆栈跟踪

Question

我有一个应用程序可以记录一个stacktrace，以后可以用于调试。

在Windows上，我通过使用JEDI项目提供的优秀JCLDebug单元来获得。

现在我的应用程序在OSX上运行，我遇到了一点麻烦-当发生异常时，我不知道如何获得正确的stacktrace。

我已经掌握了基本知识 -

1）我可以使用'backtrace'（在libSystem中找到）获得stacktrace。dylib）

2）产生的回溯可以转换成使用行号。Delphi的链接器提供的map文件

我留下的问题是-我不知道从哪里回电话。我知道Delphi使用Mach异常（在一个单独的线程上），并且我不能使用posix信号，但这就是我设法解决的所有问题。

我可以在"尝试"中得到一个倒退。..除了'块，但不幸的是，到那时堆栈已经结束。

如何安装一个正确的异常记录器，它将在异常发生后立即运行？

更新资料:

根据Honza R的建议，我已经看了一下"GetExceptionStackInfoProc"程序。

这个函数确实让我进入了异常处理过程，但不幸的是，我留下了一些我以前遇到的相同问题。

首先-在桌面平台上，这个函数'GetExceptionStackInfoProc'只是一个函数指针，你可以 使用您自己的异常信息处理程序分配.所以开箱即用，Delphi不提供任何堆栈信息提供程序。

如果我将一个函数分配给'GetExceptionStackInfoProc'，然后在其中运行一个'backtrace'，我会收到一个stacktrace，但该跟踪是相对于异常处理程序的，而不是导致异常的线程。

"GetExceptionStackInfoProc"确实包含一个指向"Textceptionrecord"的指针，但可用的文档非常有限。

我可能会超出我的深度，但我怎样才能从正确的线程中获得stacktrace？我是否有可能将我自己的'backtrace'函数注入异常处理程序，然后从那里返回到标准异常处理程序？

更新2

一些更多的细节。有一点需要澄清-这个问题是关于由MACH消息处理的异常，而不是完全在RTL内处理的软件异常。

Embarcadero已经列出了一些评论以及这些功能 -

    System.Internal.MachExceptions.pas -> catch_exception_raise_state_identity

    {
     Now we set up the thread state for the faulting thread so that when we
     return, control will be passed to the exception dispatcher on that thread,
     and this POSIX thread will continue watching for Mach exception messages.
     See the documentation at <code>DispatchMachException()</code> for more
     detail on the parameters loaded in EAX, EDX, and ECX.
    }

    System.Internal.ExcUtils.pas -> SignalConverter

    {
      Here's the tricky part.  We arrived here directly by virtue of our
      signal handler tweaking the execution context with our address.  That
      means there's no return address on the stack.  The unwinder needs to
      have a return address so that it can unwind past this function when
      we raise the Delphi exception.  We will use the faulting instruction
      pointer as a fake return address.  Because of the fencepost conditions
      in the Delphi unwinder, we need to have an address that is strictly
      greater than the actual faulting instruction, so we increment that
      address by one.  This may be in the middle of an instruction, but we
      don't care, because we will never be returning to that address.
      Finally, the way that we get this address onto the stack is important.
      The compiler will generate unwind information for SignalConverter that
      will attempt to undo any stack modifications that are made by this
      function when unwinding past it.  In this particular case, we don't want
      that to happen, so we use some assembly language tricks to get around
      the compiler noticing the stack modification.
    }

这似乎是我遇到的问题的原因。

当我在这个异常系统将控制权交给RTL之后执行stacktrace时，它看起来像这样-（记住，堆栈展开器已被backtrace例程取代。后退将控制权移交给退卷机，一旦完成）

0: MyExceptionBacktracer
1: initunwinder in System.pas
2: RaiseSignalException in System.Internal.ExcUtils.pas 

自 RaiseSignalException 被调用 SignalConverter, ，我相信 backtrace libc提供的函数与对堆栈所做的修改不兼容。因此，它无法读取超出该点的堆栈，但堆栈仍然存在于下面。

有谁知道该怎么做（或者我的假设是否正确）？

更新3

我终于设法在OSX上获得了适当的stacktraces。非常感谢Honza和Sebastian。通过结合他们的两种技术，我发现了一些有效的方法。

对于任何其他可以从中受益的人，这里是基本的来源。请记住，我不太确定它是否100％正确，如果您可以提出改进建议，请继续。这种技术在Delphi解开错误线程上的堆栈之前挂接到异常，并补偿可能事先发生的任何堆栈帧损坏。

unit MyExceptionHandler;

interface

implementation

uses
  SysUtils;

var
  PrevRaiseException: function(Exc: Pointer): LongBool; cdecl;

function backtrace2(base : NativeUInt; buffer : PPointer; size : Integer) : Integer;
var SPMin   : NativeUInt;
begin
  SPMin:=base;
  Result:=0;
  while (size > 0) and (base >= SPMin) and (base <> 0) do begin

    buffer^:=PPointer(base + 4)^;
    base:=PNativeInt(base)^;

    //uncomment to test stacktrace
    //WriteLn(inttohex(NativeUInt(buffer^), 8));

    Inc(Result);
    Inc(buffer);
    Dec(size);

  end;
  if (size > 0) then buffer^:=nil;
end;

procedure UnInstallExceptionHandler; forward;

var
  InRaiseException: Boolean;

function RaiseException(Exc: Pointer): LongBool; cdecl;
var b : NativeUInt;
    c : Integer;
    buff : array[0..7] of Pointer;
begin
  InRaiseException := True;

  asm
    mov b, ebp
  end;

  c:=backtrace2(b - $4 {this is the compiler dependent value}, @buff, Length(buff));
  //... do whatever you want to do with the stacktrace

  Result := PrevRaiseException(Exc);
  InRaiseException := False;
end;

procedure InstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  Assert(Assigned(U.RaiseException));
  PrevRaiseException := U.RaiseException;
  U.RaiseException := RaiseException;
  SetUnwinder(U);
end;

procedure UnInstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  U.RaiseException := PrevRaiseException;
  SetUnwinder(U);
end;

initialization
  InstallExceptionHandler;
end.

Answer 1

您可以使用 GetExceptionStackInfoProc, CleanUpStackInfoProc 和 GetStackInfoStringProc 在 Exception 需要保存堆栈跟踪的类 GetExceptionStackInfoProc 然后用 GetStackInfoStringProc 如果您使用RTL，它将被调用 StackTrace 的财产 Exception.也许你也可以看看 https://bitbucket.org/shadow_cs/delphi-arm-backtrace 这在Android上展示了这一点。

要在Macosx上正确地做到这一点， libc backtrace 函数不能使用，因为Delphi在调用 GetExceptionStackInfoProc 从 Exception.RaisingException.必须使用自己的实现，能够从不同的基址行走堆栈，可以手工纠正。

你的 GetExceptionStackInfoProc 然后看起来像这样（我在这个例子中使用了XE5，添加到EBPBELLOW的值可能会根据您使用的编译器而有所不同，并且这个例子只在Macosx上测试过，Windows的实现可能会有所不同，也可能不会有所不同）:

var b : NativeUInt;
    c : Integer;
    buff : array[0..7] of Pointer;
begin
  asm
    mov b, ebp
  end;
  c:=backtrace2(b - $14 {this is the compiler dependent value}, @buff, Length(buff));
  //... do whatever you want to do with the stacktrace
end;

而 backtrace2 函数看起来像这样（请注意，实现中缺少停止条件和其他验证，以确保在堆栈行走期间不会引起AVs）:

function backtrace2(base : NativeUInt; buffer : PPointer; size : Integer) : Integer;
var SPMin   : NativeUInt;
begin
  SPMin:=base;
  Result:=0;
  while (size > 0) and (base >= SPMin) and (base <> 0) do begin
    buffer^:=PPointer(base + 4)^;
    base:=PNativeInt(base)^;
    Inc(Result);

    Inc(buffer);
    Dec(size);
  end;
  if (size > 0) then buffer^:=nil;
end;

Answer 2

你可以将自己挂钩到异常之外。然后，您可以调用异常发生的回溯。这是一个例子。单位sbmapfiles是我用于读取mapfiles的用途。不需要获取异常呼叫堆栈。

unit MyExceptionHandler;

interface

implementation

uses
  Posix.Base, SysUtils, SBMapFiles;

function backtrace(result: PNativeUInt; size: Integer): Integer; cdecl; external libc name '_backtrace';
function _NSGetExecutablePath(buf: PAnsiChar; BufSize: PCardinal): Integer; cdecl; external libc name '__NSGetExecutablePath';

var
  PrevRaiseException: function(Exc: Pointer): LongBool; cdecl;
  MapFile: TSBMapFile;

const
  MaxDepth = 20;
  SkipFrames = 3;

procedure ShowCurrentStack;
var
  StackLog: PNativeUInt; //array[0..10] of Pointer;
  Cnt: Integer;
  I: Integer;
begin
  {$POINTERMATH ON}
  GetMem(StackLog, SizeOf(Pointer) * MaxDepth);
  try
    Cnt := backtrace(StackLog, MaxDepth);

    for I := SkipFrames to Cnt - 1 do
    begin
      if StackLog[I] = $BE00EF00 then
      begin
        WriteLn('---');
        Break;
      end;
      WriteLn(IntToHex(StackLog[I], 8), ' ', MapFile.GetFunctionName(StackLog[I]));
    end;

   finally
    FreeMem(StackLog);
   end;
  {$POINTERMATH OFF}
end;

procedure InstallExceptionHandler; forward;
procedure UnInstallExceptionHandler; forward;

var
  InRaiseException: Boolean;

function RaiseException(Exc: Pointer): LongBool; cdecl;
begin
  InRaiseException := True;
  ShowCurrentStack;

  Result := PrevRaiseException(Exc);
  InRaiseException := False;
end;

procedure InstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  Assert(Assigned(U.RaiseException));
  PrevRaiseException := U.RaiseException;
  U.RaiseException := RaiseException;
  SetUnwinder(U);
end;

procedure UnInstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  U.RaiseException := PrevRaiseException;
  SetUnwinder(U);
end;

procedure LoadMapFile;
var
  FileName: array[0..255] of AnsiChar;
  Len: Integer;
begin
  if MapFile = nil then
  begin
    MapFile := TSBMapFile.Create;
    Len := Length(FileName);
    _NSGetExecutablePath(@FileName[0], @Len);
    if FileExists(ChangeFileExt(FileName, '.map')) then
      MapFile.LoadFromFile(ChangeFileExt(FileName, '.map'));
  end;
end;

initialization
  LoadMapFile;
  InstallExceptionHandler;
end.

.