怎么做我检测，如果一个Windows服务器可用之后重新启动？

StackOverflow https://stackoverflow.com/questions/56644

  •  09-06-2019
  •  | 
  •  

题

我想自动Windows2000服务器重新启动过程中使用的任务的调度程序或类似工具，以重新启动远程服务器，并等待它回来了。我能问题 shutdown 或 psshutdown 远程重新启动，但我想要的东西比 sleep 等待它回来。我需要确认这是重新在线内 n 几分钟或抛出一个错误。

通过回上，我想验证超过只是它可以ping，但也许其RFC服务的响应或其他一些确定的重要标志。

我会更喜欢一个NT脚本的办法，但我不能排除编写定制的工具这样做。

任何想法？

有帮助吗？

解决方案

你的远程重新启动脚本可以打开服务器，等待n分钟，然后查询RFC服务。你可以还有一个脚本本地服务器上的做同样的事情。

其他提示

之后工作上的这一段时间，我想到了以下VBScript。随意发表评论/提高。

'
' Remotely reboot a server and
' wait for server to come back up.
'
' Usage:  cscript /nologo /E:VBScript RebootWait.vbs <Server Name>
'
' Shawn Poulson, 2008.09.11
'

'
' Get server name from command line
'
If WScript.Arguments.Count <> 1 Then
   ShowUsage()
   WScript.Quit(1)
End If

ServerName = WScript.Arguments(0)

'
' Verify server is currently up
'
WScript.StdOut.WriteLine Now & ": Verify server '" & ServerName & "' is currently up..."
If Not IsAvailable(ServerName) Then
   WScript.StdOut.WriteLine "Error: Server is down.  Reboot aborted!"
   WScript.Quit(1)
End If
WScript.StdOut.WriteLine Now & ": Server is up."

'
' Reboot server
'
WScript.StdOut.WriteLine Now & ": Rebooting server '" & ServerName & "'..."
RebootStatus = RebootServer(ServerName)
If RebootStatus < 0 Then
   WScript.StdOut.WriteLine "Error: Reboot returned error " & RebootStatus
   WScript.Quit(1)
End If
WScript.StdOut.WriteLine Now & ": Reboot command was successful"

'
' Wait for server to come down
'
WScript.StdOut.Write Now & ": Waiting for server '" & ServerName & "' to go down..."
WaitCount = 0
Do While IsAvailable(ServerName)
   WaitCount = WaitCount + 1
   If WaitCount > 60 Then ' 5 min timeout
      WScript.StdOut.WriteLine "Error: Timeout waiting for server to come down!"
      WScript.Quit(1)
   End If
   WScript.StdOut.Write(".")
   WScript.Sleep(5000)
Loop
WScript.StdOut.WriteLine "Success!"
WScript.StdOut.WriteLine Now & ": Server is down."

'
' Wait for server to come back up
'
WScript.StdOut.Write Now & ": Waiting for server '" & ServerName & "' to come back up..."
WaitCount = 0
Do While Not IsAvailable(ServerName)
   WaitCount = WaitCount + 1
   If WaitCount > 240 Then ' 20 min timeout
      WScript.StdOut.WriteLine "Error: Timeout waiting for server to come back up!"
      WScript.Quit(1)
   End If
   WScript.StdOut.Write(".")
   WScript.Sleep(5000)
Loop
WScript.StdOut.WriteLine "Success!"
WScript.StdOut.WriteLine Now & ": Server is back up after reboot."

'
' Success!
'
WScript.Quit(0)


Sub ShowUsage()
   WScript.Echo "Usage: " & WScript.ScriptName & " <Server name>"
End Sub

' Returns:
' 1 = Successfully issued reboot command
' -2 = Could not reach server
' -3 = Reboot command failed
Function RebootServer(ServerName)
   Dim OpSystem
   On Error Resume Next
   For Each OpSystem in GetObject("winmgmts:{(Shutdown)}!\\" & ServerName & "\root\CIMV2").ExecQuery("select * from Win32_OperatingSystem where Primary=true")
      On Error GoTo 0

      If IsObject(OpSystem) Then
         ' Invoke forced reboot
         If OpSystem.Win32Shutdown(6, 0) = 0 Then
            ' Success
            RebootServer = 1
         Else
            ' Command failed
            RebootServer = -3
         End If

      Else
         RebootServer = -2

      End If
   Next
End Function

' Return True if available
Function IsAvailable(ServerName)
   ' Use Windows RPC service state as vital sign
   IsAvailable = (GetServiceState(ServerName, "RpcSs") = "Running")
End Function

' Return one of:
'  Stopped, Start Pending, Stop Pending,
'  Running, Continue Pending, Pause Pending,
'  Paused, Unknown
Function GetServiceState(ServerName, ServiceName)
   Dim Service
   On Error Resume Next
   Set Service = GetObject("winmgmts:\\" & ServerName & "\root\CIMV2:Win32_Service='" & ServiceName & "'")
   On Error GoTo 0
   If IsObject(Service) Then GetServiceState = Service.State
End Function

你可以用 psservice 查询地位的RFC或打印机程序的服务。该程序通常是一个最后的服务，以启动。你可以使用的语法，如：

psservice \\someothermachine query spooler

这将返回这样的事情一旦业务运行。

SERVICE_NAME: Spooler                                                                             
DISPLAY_NAME: Print Spooler                                                                       
Manages all local and network print queues and controls all printing jobs. If this service is stop
ped, printing on the local machine will be unavailable. If this service is disabled, any services 
that explicitly depend on it will fail to start.                                                  
        GROUP             : SpoolerGroup                                                          
        TYPE              : 110 WIN32_OWN_PROCESS INTERACTIVE_PROCESS                             
        STATE             : 4  RUNNING                                                            
                               (STOPPABLE,NOT_PAUSABLE,ACCEPTS_SHUTDOWN)                          
        WIN32_EXIT_CODE   : 0  (0x0)                                                              
        SERVICE_EXIT_CODE : 0  (0x0)                                                              
        CHECKPOINT        : 0x0                                                                   
        WAIT_HINT         : 0x0

如果其他机是不是准备好了，你会喜欢的东西

Unable to connect to \\someothermachine:                                                                  
The RPC server is unavailable.

与VBScript(WSH)你可以检查它。国家财产。这个脚本，显示了，财产被使用在不同的应用程序，但应该有助于说明这样的想法：

http://www.robvanderwoude.com/vbstech_proc_service.html

使用 常 获得一个名单开放服务机和分析结果确定你需要的是活动的。它也有用，以确保事情你 不不 需要的是 不 活跃。

你可以调查某些核心服务，看它是否已经开始：

sc "\\server_name" query EventSystem

这里的关键是，我需要剧本这一点。是有一个更清洁的方式提取服务的状态 psservice/sc query?我能够管它 findstr "RUNNING", 但我们有了一个更好的办法。

许可以下： CC-BY-SA 和 归因
不隶属于 StackOverflow
scroll top