合并 Mnesia 记录

Question

我正在尝试重构一些用于收集呼叫队列中代理当前状态的软件代码。目前，对于我监听的大约 6 个事件中的每一个，我都会检查 Mnesia 表中是否存在代理，并根据事件更改行中的某些值，或者如果代理不存在，则将其添加为新值。目前我在每个事件中都有这个 Mnesia 事务，当然这是一堆用于检查代理是否存在等的重复代码。

我正在尝试更改它，以便有一个类似的功能 变更代理/2 我从为我处理这个问题的事件中调用它。

我的问题当然是记录......我找不到动态创建它们或将其中两个合并在一起或任何东西的方法。最好有一个我可以调用的函数，例如：

change_agent("001", #agent(id = "001", name = "Steve")).
change_agent("001", #agent(id = "001", paused = 0, talking_to = "None")).

Answer 1

我不久前编写了一些合并两条记录的代码。不完全是动态的，但是通过宏，您可以轻松地将它用于多个记录。

它的工作原理如下：merge/2 函数接受两条记录，并将它们与空记录一起转换为列表以供参考（记录类型是在编译时定义的，并且必须是。这是“非动态”部分）。然后，它们通过通用函数 merge/4 运行，该函数与列表一起使用，如果已定义，则从 A 中获取元素，如果已定义，则从 B 中获取元素，最后从 Default（始终已定义）中获取元素。

这是代码（请原谅 StackOverflow 糟糕的 Erlang 语法突出显示）：

%%%----------------------------------------------------------------------------
%%% @spec merge(RecordA, RecordB) -> #my_record{}
%%%     RecordA = #my_record{}
%%%     RecordB = #my_record{}
%%%
%%% @doc Merges two #my_record{} instances. The first takes precedence.
%%% @end
%%%----------------------------------------------------------------------------
merge(RecordA, RecordB) when is_record(RecordA, my_record),
                             is_record(RecordB, my_record) ->
    list_to_tuple(
        lists:append([my_record],
                     merge(tl(tuple_to_list(RecordA)),
                           tl(tuple_to_list(RecordB)),
                           tl(tuple_to_list(#my_record{})),
                           []))).

%%%----------------------------------------------------------------------------
%%% @spec merge(A, B, Default, []) -> [term()]
%%%     A = [term()]
%%%     B = [term()]
%%%     Default = [term()]
%%%
%%% @doc Merges the lists `A' and `B' into to a new list taking
%%% default values from `Default'.
%%%
%%% Each element of `A' and `B' are compared against the elements in
%%% `Default'. If they match the default, the default is used. If one
%%% of them differs from the other and the default value, that element is
%%% chosen. If both differs, the element from `A' is chosen.
%%% @end
%%%----------------------------------------------------------------------------
merge([D|ATail], [D|BTail], [D|DTail], To) ->
    merge(ATail, BTail, DTail, [D|To]); % If default, take from D
merge([D|ATail], [B|BTail], [D|DTail], To) ->
    merge(ATail, BTail, DTail, [B|To]); % If only A default, take from B
merge([A|ATail], [_|BTail], [_|DTail], To) ->
    merge(ATail, BTail, DTail, [A|To]); % Otherwise take from A
merge([],        [],        [],        To) ->
    lists:reverse(To).

您可以随意以任何您想要的方式使用它。

Answer 2

为记录编写通用访问函数很困难。解决此问题的一种方法是 '表达' 库，它将为低级记录访问功能生成代码。

您需要做的是将以下行添加到模块：

-compile({parse_transform, exprecs}).
-export_records([...]).  % name the records that you want to 'export'

访问函数的命名约定可能看起来很奇怪，但其灵感来自于 Richard O'Keefe 的提议。它至少是一致的，并且不太可能与现有功能发生冲突。（：